编辑距离（动规例题）

题目描述：

现有字符串A,B，要使得A=b，有如下三种操作：

将A删除1个字符；

将A插入1个字符；

将A中的一个字符改为另一个字符；

样例输入：

SFDQXBW

GFDGW

样例输出：

4

解释：

SFDQXBW->GFDQXBW->GFDXBW->GFDBW->GFDGW，四步。

这道题因为只能操作A，就能有效避免动态规划的无后效性，就是A的操作并不会影响接下来的操作，但如果可以操作B则就会影响A的操作了。

我们可以按i,j的长度来划分阶段，状态只要稍微想一想都知道是设f[i,j]表达a1..i~b1..j的最优编辑距离。

同样这道题的边界也极为重要，f[0,i]以及f[i,0]的值都为i（1<=i<=lena,lenb）

那方程又是什么呢？

其实，操作的三种情况都对应了三个不同的决策——

当i,j不相同时，有如下三种操作

第一种操作：f[i-1,j]+1

第二种操作：f[i,j-1]+1

第三种操作：f[i-1,j-1]+1

而当相同时则f[i,j]直接等于f[i-1,j-1]。

代码：

var
        i,j,k,m,n:Longint;
        s1,s2:ansistring;
        f:array[0..2000,0..2000] of Longint;
function min(x,y:Longint):Longint;
begin
        if x<y then exit(x) else exit(y);
end;

begin
        readln(s1);
        readln(s2);
        m:=length(s1);
        n:=length(s2);
        for i:=1 to m do
                f[i,0]:=i;
        for i:=1 to n do
                f[0,i]:=i;
        for i:=1 to m do
                for j:=1 to n do
                        if s1[i]=s2[j] then
                                f[i,j]:=f[i-1,j-1]
                        else
                                f[i,j]:=min(min(f[i-1,j],f[i,j-1]),f[i-1,j-1])+1;
        writeln(f[m,n]);
end.