noi 2008 假面舞会 （bzoj 1064）

Description

一年一度的假面舞会又开始了，栋栋也兴致勃勃的参加了今年的舞会。今年的面具都是主办方特别定制的。每个参加舞会的人都可以在入场时选择一 个自己喜欢的面具。每个面具都有一个编号，主办方会把此编号告诉拿该面具的人。为了使舞会更有神秘感，主办方把面具分为k (k≥3)类，并使用特殊的技术将每个面具的编号标在了面具上，只有戴第i 类面具的人才能看到戴第i+1 类面具的人的编号，戴第k 类面具的人能看到戴第1 类面具的人的编号。 参加舞会的人并不知道有多少类面具，但是栋栋对此却特别好奇，他想自己算出有多少类面具，于是他开始在人群中收集信息。 栋栋收集的信息都是戴第几号面具的人看到了第几号面具的编号。如戴第2号面具的人看到了第5 号面具的编号。栋栋自己也会看到一些编号，他也会根据自己的面具编号把信息补充进去。由于并不是每个人都能记住自己所看到的全部编号，因此，栋栋收集的信 息不能保证其完整性。现在请你计算，按照栋栋目前得到的信息，至多和至少有多少类面具。由于主办方已经声明了k≥3，所以你必须将这条信息也考虑进去。

Input

第一行包含两个整数n, m，用一个空格分隔，n 表示主办方总共准备了多少个面具，m 表示栋栋收集了多少条信息。接下来m 行，每行为两个用空格分开的整数a, b，表示戴第a 号面具的人看到了第b 号面具的编号。相同的数对a, b 在输入文件中可能出现多次。

Output

包含两个数，第一个数为最大可能的面具类数，第二个数为最小可能的面具类数。如果无法将所有的面具分为至少3 类，使得这些信息都满足，则认为栋栋收集的信息有错误，输出两个-1。

Sample Input

【输入样例一】

6 5
1 2
2 3
3 4
4 1
3 5

【输入样例二】

3 3
1 2
2 1
2 3

Sample Output

【输出样例一】

4 4

【输出样例二】

-1 -1
【数据规模和约定】

50%的数据，满足n ≤ 300, m ≤ 1000；
100%的数据，满足n ≤ 100000, m ≤ 1000000。

根据加入的边可以建立一个有向图。

考虑三种情况：

1.环。

2.有相同起止点的两条同向链。

3.树。

 

首先。我把最小值放在最后求了。主要找出最大可行值，枚举约数找最小值。

第一种情况用环大小的最大公约数更新最大值，第二种用两条链的长度差更新最大值，第三种对当前k值无影响。

如果是一个有向图，在我看来这处理地略蛋疼。。可是给边加上边权，正向为1反向为-1建成无向图就容易多了。

就是不断dfs，给每个点打上时间戳，找到已经找过的点就更新值（这样一二种情况就可以同样做了），因为是无向图，一次dfs可以搞掉一个连通快，而不同的连通快之间是没有影响的。

 

一开始WA了是没有考虑第三种情况。。。每次dfs以后要记录深度（时间戳的极大极小值的差），如果最后是很多棵树，就把所有深度加起来就是最大值，最小值不用求约数，直接是3。

还有一种比较简洁的并查集做法，不过本人较弱，还未看懂。。

http://hi.baidu.com/coolinging/blog/item/58438b9b0fe67fafc8eaf40b.html

 

AC CODE

 

{$M 10000000}
program noi_2008_day1_party;
var line,next,g:array[1..2000000] of longint;
    en,f:array[1..100000] of longint;
    p:array[1..100000] of boolean;
    k,n,len,min,max,tot:longint;
//============================================================================
procedure ins(x,y,z:longint);
begin
  inc(tot); line[tot]:=y; g[tot]:=z;
  next[tot]:=en[x]; en[x]:=tot;
end;
//============================================================================
procedure init;
var m,x,y,i:longint;
begin
  readln(n,m);
  for i:=1 to m do
  begin
    readln(x,y);
    ins(x,y,1); ins(y,x,-1);
  end;
end;
//============================================================================
function gcd(x,y:longint):longint;
begin
  if y=0 then exit(x);
  gcd:=gcd(y,x mod y);
end;
//============================================================================
procedure deal(x:longint);
var tmp:longint;
begin
  if x=0 then exit;
  if x<3 then
  begin
    writeln('-1 -1');
    close(input); close(output);
    halt;
  end;
  if k=0 then
  begin
    k:=x;
    exit;
  end;
  tmp:=gcd(k,x);
  if tmp>=3 then k:=tmp else
  begin
    writeln('-1 -1');
    close(input); close(output);
    halt;
  end;
end;
//============================================================================
procedure dfs(u,len:longint);
var v,i:longint;
begin
  if not(p[u]) then
  begin
    f[u]:=len; p[u]:=true;
    if len>max then max:=len;
    if len<min then min:=len;
    i:=en[u];
    while i<>0 do
    begin
      v:=line[i];
      dfs(v,len+g[i]);
      i:=next[i];
    end;
  end else
    deal(abs(f[u]-len));    //加入负权边后就可以用时间戳的差直接求gcd更新了。
end;
//============================================================================
procedure main;
var i,tmp:longint;
begin
  fillchar(p,sizeof(p),0);
  tmp:=0;
  for i:=1 to n do
    if not(p[i]) then
    begin
      min:=maxlongint; max:=0;
      dfs(i,0);
      tmp:=tmp+max-min+1;
    end;
  if k=0 then
  begin
    if tmp<3 then
      writeln('-1 -1') else
        writeln(tmp,' 3');
  end else
    for i:=3 to k do
      if k mod i=0 then
      begin
        writeln(k,' ',i);
        break;
      end;
  close(input); close(output);
end;
//============================================================================
begin
  assign(input,'party.in');
  assign(output,'party.out');
  reset(input); rewrite(output);
  init;
  main;
end.