sas的方差分析

/*主要参数*/
/*class：在模型model中出现的分类变量，例如：sex,treatment,race,group，需要在class中定义，且出现在model语句之前*/
/*model：自定义模型，只能有一个model语句*/
/*model语句中的选项：*/
/*solution：生成参数估计*/
/*产生的置信区间*/
/*alpha:定义可信度*/
/*cli:各个预测值的置信区间*/
/*clm:平均值的置信区间*/
/*clparam：参数的置信区间*/

/*means语句和lsmeans语句的区别：*/
/*means语句的比较只比较主效应，不考虑交互效应，涉及到交互效应，选择lsmeans语句*/
/*means语句计算的是不调整的算术平均值，如果需要调整，则选择lsmeans语句*/

/*如果模型中涉及的y变量不止一个，则可以用manova*/

/*random:如果考虑随机效应，则需要使用*/

****平衡数据的完全随机区组设计的方差分析******;
data plants;
   input Type $ @;
   do Block = 1 to 3;
      input StemLength @;
      output;
   end;
   datalines;
Clarion  32.7 32.3 31.5
Clinton  32.1 29.7 29.1
Knox     35.7 35.9 33.1
O'Neill  36.0 34.2 31.2
Compost  31.8 28.0 29.2
Wabash   38.2 37.8 31.9
Webster  32.5 31.1 29.7
;
run;
proc glm order=data;
   class Block Type;
   model StemLength = Block Type / solution;
   lsmeans Type / adjust=tukey;
run;

****不平衡数据的two-way anova*****;

data a;
   input drug disease @;
   do i=1 to 6;
      input y @;
      output;
   end;
   datalines;
1 1 42 44 36 13 19 22
1 2 33  . 26  . 33 21
1 3 31 -3  . 25 25 24
2 1 28  . 23 34 42 13
2 2  . 34 33 31  . 36
2 3  3 26 28 32  4 16
3 1  .  .  1 29  . 19
3 2  . 11  9  7  1 -6
3 3 21  1  .  9  3  .
4 1 24  .  9 22 -2 15
4 2 27 12 12 -5 16 15
4 3 22  7 25  5 12  .
;
proc glm;
   class drug disease;
   model y=drug disease drug*disease / ss1 ss2 ss3 ss4;
   lsmeans drug / pdiff=all adjust=tukey;
run;

**输出图**;
ods graphics on;
proc glm plot=meanplot(cl);
   class drug disease;
   model y=drug disease drug*disease;
   lsmeans drug / pdiff=all adjust=tukey;
run;
ods graphics off;