#-------------------------------------------------
#
# Project created by QtCreator 2019-12-02T09:30:06
#
#-------------------------------------------------
#QT 指定Qt工程所要使用的Qt模块
QT += core gui
#如果QT主版本大于4,则需要添加widgets模块。相对于 QT4, QT5 的一个主要的基础架构修改,是将 widget 从 QtGui 模块剥离开来,
#新增 QtWidgets 模块,头文件包含“ QtWidgets ”
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
#TARGET 指定可执行文件或库的基本文件名,默认为当前目录名
TARGET = study_20191202 #study_20191202.exe
#TEMPLATE 模板变量指定模板类型,告诉qmake为这个应用程序生成哪种makefile
TEMPLATE = app #app - 建立一个应用程序的makefile
#lib - 建立一个库的makefile
#vcapp - 建立一个应用程序的Visual Studio项目文件
#vclib - 建立一个库的Visual Studio项目文件
#subdirs - 这是一个特殊的模板,它可以创建一个能够进入特定目录并且为一个项目文件生成makefile
#并且为它调用make的makefile
#SOURCES 指定c++ CPP文件
SOURCES += main.cpp\
mymain.cpp
#HEADERS 指定C++头文件
HEADERS += mymain.h
#FORMS 指定需要UIC处理的UI文件
FORMS += mymain.ui
#根据debug或是release编译版本 将生成的可执行文件放置不同的目录下
CONFIG(debug, debug|release) {
#CONFIG 指定工程配置和编译参数
CONFIG += console
#DESTDIR 指定可执行文件放置目录
DESTDIR = $$PWD/../bin/win64_vc12_debug
}
else{
DESTDIR = $$PWD/../bin/win64_vc12_release
}
#支持分支 或是重新判断
#CONFIG(release, debug|release) {
#DESTDIR = $$PWD/../bin/win64_vc12_release
#}
#指定分支结构指出lib库所在路径
#-L 表示指定文件路径, -l 表示指定文件
CONFIG(debug, debug|release){
#Qt在pro文件中加入带空格的路径,使用$$quote关键字解决
#win32:LIBS += -L$$quote(C:\Program Files (x86)\Microsoft\Exchange) -linfrad
win32:LIBS += -L$$PWD/../lib/win64_vc12_debug/ -linfrad
}else{
win32:LIBS +=-L$$PWD/../lib/win64_vc12_release/ -linfra
}
#拷贝文件到指定目录
defineTest(copyToDestdir) {
files = $$1
dir = $$2
win32:dir ~= s,/,\\,g
for(FILE, files) {
win32:FILE ~= s,/,\\,g
QMAKE_POST_LINK += $$QMAKE_COPY $$quote($$FILE) $$quote($$dir) $$escape_expand(\\n\\t)
}
export(QMAKE_POST_LINK)
}
CONFIG(debug, debug|release){
copyToDestdir($$PWD/../bin/win64_vc12_debug/study_20191202.exe, $$PWD/../bin/debug)
}else{
copyToDestdir($$PWD/../bin/win64_vc12_release/study_20191202.exe, $$PWD/../bin/release)
}
#LEXSOURCES - 应用程序中的所有lex源文件的列表。
#YACCSOURCES - 应用程序中的所有yacc源文件的列表。
#DEFINES - 应用程序所需的额外的预处理程序定义的列表。
#INCLUDEPATH - 应用程序所需的额外的包含路径的列表。
#DEPENDPATH - 应用程序所依赖的搜索路径。
#VPATH - 寻找补充文件的搜索路径。
#DEF_FILE - 只有Windows需要:应用程序所要连接的.def文件。
#RC_FILE - 只有Windows需要:应用程序的资源文件。
#RES_FILE - 只有Windows需要:应用程序所要连接的资源文件。
temp="linxi"
message($$PWD)
!build_pass:message($$temp)
#$$temp与$${temp}等价,需要隔开后面的字符时使用$${temp}
!build_pass:message($${temp} is good body)
!buid_pass{
UNAME = $$system(net time)
message($$UNAMW)
}
#error(this is a error!)