前言
看到一个apktools脚本, 学习整理一下.
学习了bat脚本里处理文件后缀名,设置标题,处理条件判断块, 转义字符.
记录
@echo off
rem filename : apktool_cli_start.bat
path %~dp0;%path%
cls
rem ------------------------------------------------------------
rem set title
rem ------------------------------------------------------------
title %0
echo.
echo apktool version 2.2.2
echo.
rem ------------------------------------------------------------
rem note
rem
rem apktool-cli.jar location : apktools source code after build on \Apktool\brut.apktool\apktool-cli\build\libs
rem
rem "%1" is "%~1"
rem "%~x1" means postfix by dot
rem ^> means ^>
rem neq means not equ
rem ------------------------------------------------------------
rem ------------------------------------------------------------
rem show command line
rem ------------------------------------------------------------
echo.
echo cmdline ==^>^> "%0" "%1"
echo.
rem ------------------------------------------------------------
rem Apk to Smali
rem ------------------------------------------------------------
if /i "%~x1" equ ".apk" (
echo.
echo Apk to Smali ...
echo.
java -jar "%~dp0apktool-cli.jar" d -f "%~1" -o "%~1.re"
goto END
)
rem ------------------------------------------------------------
rem Smali to Apk
rem ------------------------------------------------------------
if /i "%~x1" equ ".re" (
echo.
echo Smali to Apk ...
echo.
java -jar "%~dp0apktool-cli.jar" b -f "%~1" -o "%~1.apk"
goto END
)
rem ------------------------------------------------------------
rem error process
rem ------------------------------------------------------------
echo.
echo error : "%1" is not .re or .apk
echo.
rem show apktools help
java -jar "%~dp0apktool-cli.jar"
goto END
rem ------------------------------------------------------------
rem END
rem ------------------------------------------------------------
:END
echo.
echo.END
echo.
pause
apk to smali
apktool version 2.2.2
cmdline ==>> "apktool_cli_start.bat" "Study1226.apk"
Apk to Smali ...
I: Using Apktool 2.2.2-58ab04-SNAPSHOT on Study1226.apk
I: Loading resource table...
I: Decoding AndroidManifest.xml with resources...
I: Loading resource table from file: C:\Users\LostSpeed\AppData\Local\apktool\framework\1.apk
I: Regular manifest package...
I: Decoding file-resources...
I: Decoding values */* XMLs...
I: Baksmaling classes.dex...
I: Copying assets and libs...
I: Copying unknown files...
I: Copying original files...
END
请按任意键继续. . .
smali to apk
apktool version 2.2.2
cmdline ==>> "apktool_cli_start.bat" "Study1226.apk.re"
Smali to Apk ...
I: Using Apktool 2.2.2-58ab04-SNAPSHOT
I: Smaling smali folder into classes.dex...
I: Building resources...
I: Building apk file...
I: Copying unknown files/dir...
END
请按任意键继续. . .