食物链

【NOI2001】食物链(normal)

Time Limit:10000MS  Memory Limit:65536K
Total Submit:119 Accepted:45

Description

动物王国中有三类动物A,B,C，这三类动物的食物链构成了有趣的环形。A吃B， B吃C，C吃A。
现有N个动物，以1－N编号。每个动物都是A,B,C中的一种，但是我们并不知道它到底是哪一种。
有人用两种说法对这N个动物所构成的食物链关系进行描述：
第一种说法是“1 X Y”，表示X和Y是同类。
第二种说法是“2 X Y”，表示X吃Y。
此人对N个动物，用上述两种说法，一句接一句地说出K句话，这K句话有的是真的，有的是假的。当一句话满足下列三条之一时，这句话就是假话，否则就是真话。
1) 当前的话与前面的某些真的话冲突，就是假话；
2) 当前的话中X或Y比N大，就是假话；
3) 当前的话表示X吃X，就是假话。
你的任务是根据给定的N（1<=N<=50,000）和K句话（0<=K<=100,000），输出假话的总数。

Input

第一行是两个整数N和K，以一个空格分隔。
以下K行每行是三个正整数 D，X，Y，两数之间用一个空格隔开，其中D表示说法的种类。
若D=1，则表示X和Y是同类。
若D=2，则表示X吃Y。

Output

只有一个整数，表示假话的数目。

Sample Input

输入文件	对7句话的分析
100 7	
1 101 1   	假话
2 1 2     	真话
2 2 3     	真话
2 3 3     	假话
1 1 3     	假话
2 3 1     	真话
1 5 5     	真话

Sample Output

3

【解析】

这道题目考查的数据结构是并查集。
用father[n],path[n]数组分别记录当前结点的祖先和到祖先的距离，这里规定距离为0时为同类，为1时表示被祖先吃，为2时表示吃祖先。初始时每个元素的祖先是自己，距离为0.
对于每一句话，首先判断是x,y是否大于n，是否出现自己吃自己的情况，满足时讨论如下两种情况。

1. 如果d=1，表示读入的x和y是同类，这时分别找到x,y和祖先fx,fy，如果fx=fy，说明他们是同一祖先。这时判断x和y到祖先的距离是否相等，显然，不相等证明这是一句假话。如果fx<>fy，说明x和y不在同一集合中，此时将这两个集合合并。合并时可以通过一个简单的向量关系算出fx->fy的距离，即path[fx]=path[y]-path[x].
2. 如果d=2，表示x吃y，同样的找到它们的祖先，若fx=fy，则根据向量关系判断它们的距离是否矛盾，即检查path[x]-path[y]-2是否为0。若fx<>fy，则类似地根据已有的向量关系算出fx->fy的距离，即 path[fx]=path[y]-path[x]+2;

注意的地方是，因为path在运算过程可能出现负数，为避免这一情况且保证path的性质，可以在每次对path运算后加三再对三取模。
path数组在维护时要注意，建立新关系时，直接把fx指向fy，相应地修改path值即可，对儿子结点的维护放在getfather函数中进行。

程序如下。

var
	father,path:array[1..50001] of longint;
	ans,n,k,d,x,y:longint;
	
function getfather(x:longint):longint;
var
	t:longint;
begin
	if father[x]=x then exit(x);
	t:=father[x];
	father[x]:=getfather(father[x]);
	path[x]:=(path[t]+path[x]) mod 3;
	exit(father[x]);
end;

procedure init;
var
	i,j,fx,fy:longint;
begin
	readln(n,k);
	ans:=0;
	for i:=1 to n do
		begin
			path[i]:=0;
			father[i]:=i;
		end;
	for i:=1 to k do
		begin	
			readln(d,x,y);
			if (x>n) or (y>n) then
				begin
					inc(ans);
					continue;
				end;
			fx:=getfather(x);
			fy:=getfather(y);
			if d=1 then
				begin
					if fx=fy then
						begin
							if path[x]<>path[y] then inc(ans);
							continue;
						end;
					father[fx]:=fy;
					path[fx]:=(path[y]-path[x]+3) mod 3;
				end;
			if d=2 then
				begin
					if x=y then
						begin
							inc(ans);
							continue;
						end;
					if fx=fy then
						begin
							if (2-path[x]+path[y]) mod 3<>0 then
								inc(ans);
							continue;
						end;
					father[fx]:=fy;
					path[fx]:=(path[y]-path[x]+2) mod 3;
				end;
		end;
	writeln(ans);
end;

begin
	init;
end.