1.规则文件构成
在使用Drools时非常重要的一个工作就是编写规则文件，通常规则文件的后缀为.drl。
drl是Drools Rule Language的缩写。在规则文件中编写具体的规则内容。
一套完整的规则文件内容构成如下
| 关键字 | 描述 |
|---|---|
| package | 包名，只限于逻辑上的管理，同一个包名下的查询或者函数可以直接调用 |
| import | 用于导入类或者静态方法 |
| global | 全局变量 |
| function | 自定义函数 |
| query | 查询 |
| rule end | 规则体 |
说明：
- package可以不用跟drl文件所在的目录一致，如果是需要导入的很多类都在一个包下，可以直接将包名写成和这个包一样，这样就不用一个个导入了。
- Drools支持的规则文件，除了drl形式，还有Excel文件类型的。
2.规则体语法结构
规则体是规则文件内容中的重要组成部分，是进行业务规则判断、处理业务结果的部分。
规则体语法结构如下：
rule "ruleName"
attributes
when
LHS
then
RHS
end
rule： 关键字，表示规则开始，参数为规则的唯一名称。
attributes：规则属性，是rule与when之间的参数，为可选项。
when：关键字，后面跟规则的条件部分。
LHS(Left Hand Side)：是规则的条件部分的通用名称。它由零个或多个条件元素组成。如果LHS为空，则它将被视为始终为true的条件元素。
then：关键字，后面跟规则的结果部分。
RHS(Right Hand Side)：是规则的后果或行动部分的通用名称。
end：关键字，表示一个规则结束。
3.规则体语法结构
在drl形式的规则文件中使用注释和Java类中使用注释一致，分为单行注释和多行注释。
单行注释用"//“进行标记，多行注释以”/“开始，以”/"结束。如下示例：
//规则rule1的注释，这是一个单行注释
rule "rule1"
when
then
System.out.println("rule1触发");
end
/*
规则rule2的注释，
这是一个多行注释
*/
rule "rule2"
when
then
System.out.println("rule2触发");
end
4.Pattern模式匹配
Drools中的匹配器可以将Rule Base中的所有规则与Working Memory中的Fact对象进行模式匹配，那么我们就需要在规则体的LHS部分定义规则并进行模式匹配。LHS部分由一个或者多个条件组成，条件又称为pattern。
pattern的语法结构为：绑定变量名:Object(Field约束)
其中绑定变量名可以省略，通常绑定变量名的命名一般建议以$开始。如果定义了绑定变量名，就可以在规则体的RHS部分使用此绑定变量名来操作相应的Fact对象。Field约束部分是需要返回true或者false的0个或多个表达式。
入门案例中
//规则二：所购图书总价在100到200元的优惠20元
rule "book_discount_2"
when
//Order为类型约束，originalPrice为属性约束
$order:Order(originalPrice < 200 && originalPrice >= 100)
then
$order.setRealPrice($order.getOriginalPrice() - 20);
System.out.println("成功匹配到规则二：所购图书总价在100到200元的优惠20元");
end
4.1 匹配的条件为：
- 工作内存中必须存在Applicant这种类型的Fact对象-----类型约束
- Fact对象的valid属性值必须小于18------属性约束
以上条件必须同时满足当前规则才有可能被激活。
4.2 绑定变量既可以用在对象上，也可以用在对象的属性上。
例如上面的例子可以改为：
//规则二：所购图书总价在100到200元的优惠20元
rule "book_discount_2"
when
$order:Order($op:originalPrice < 200 && originalPrice >= 100)
then
System.out.println("$op=" + $op);
$order.setRealPrice($order.getOriginalPrice() - 20);
System.out.println("成功匹配到规则二：所购图书总价在100到200元的优惠20元");
end
4.3 LHS部分还可以定义多个pattern，多个pattern之间可以使用and或者or进行连接，也可以不写，默认连接为and。
//规则二：所购图书总价在100到200元的优惠20元
rule "book_discount_2"
when
$order:Order($op:originalPrice < 200 && originalPrice >= 100) and
$customer:Customer(age > 20 && gender=='male')
then
System.out.println("$op=" + $op);
$order.setRealPrice($order.getOriginalPrice() - 20);
System.out.println("成功匹配到规则二：所购图书总价在100到200元的优惠20元");
end
5.比较操作符
Drools提供的比较操作符，如下表：
| 符号 | 说明 |
|---|---|
| > | 大于 |
| < | 小于 |
| >= | 大于等于 |
| <= | 小于等于 |
| == | 等于 |
| != | 不等于 |
| contains | 检查一个Fact对象的某个属性值是否包含一个指定的对象值 |
| not contains | 检查一个Fact对象的某个属性值是否不包含一个指定的对象值 |
| memberOf | 判断一个Fact对象的某个属性是否在一个或多个集合中 |
| not memberOf | 判断一个Fact对象的某个属性是否不在一个或多个集合中 |
| matches | 判断一个Fact对象的属性是否与提供的标准的Java正则表达式进行匹配 |
| not matches | 判断一个Fact对象的属性是否不与提供的标准的Java正则表达式进行匹配 |
前6个比较操作符和Java中的完全相同，下面我们重点了解后6个比较操作符。
5.1 语法
-
contains | not contains语法结构
Object(Field[Collection/Array] contains value)
Object(Field[Collection/Array] not contains value) -
memberOf | not memberOf语法结构
Object(field memberOf value[Collection/Array])
Object(field not memberOf value[Collection/Array]) -
matches | not matches语法结构
Object(field matches “正则表达式”)
Object(field not matches “正则表达式”)
5.2 操作步骤
第一步：创建实体类，用于测试比较操作符
/**
* 实体类
* 用于测试比较操作符
*/
public class ComparisonOperatorEntity {
private String names;
private List<String> list;
public String getNames() {
return names;
}
public void setNames(String names) {
this.names = names;
}
public List<String> getList() {
return list;
}
public void setList(List<String> list) {
this.list = list;
}
}
第二步：在/resources/rules下创建规则文件comparisonOperator.drl
package rules;
import drools.entity.ComparisonOperatorEntity
dialect "mvel"
/*
当前规则文件用于测试Drools提供的比较操作符
*/
//测试比较操作符contains
rule "rule_comparison_contains"
when
ComparisonOperatorEntity(names contains "张三")
ComparisonOperatorEntity(list contains names)
then
System.out.println("规则rule_comparison_contains触发");
end
rule "rule_comparison_notContains"
when
ComparisonOperatorEntity(names not contains "张三")
ComparisonOperatorEntity(list not contains names)
then
System.out.println("rule_comparison_notContains");
end
//测试比较操作符memberOf
rule "rule_comparison_memberOf"
when
ComparisonOperatorEntity(names memberOf list)
then
System.out.println("规则rule_comparison_memberOf触发");
end
//测试比较操作符not memberOf
rule "rule_comparison_notMemberOf"
when
ComparisonOperatorEntity(names not memberOf list)
then
System.out.println("规则rule_comparison_notMemberOf触发");
end
//测试比较操作符matches
rule "rule_comparison_matches"
when
ComparisonOperatorEntity(names matches "张.*")
then
System.out.println("规则rule_comparison_matches触发");
end
//测试比较操作符not matches
rule "rule_comparison_notMatches"
when
ComparisonOperatorEntity(names not matches "张.*")
then
System.out.println("规则rule_comparison_notMatches触发");
end
第三步：编写单元测试
@Test
public void test2(){
KieServices kieServices = KieServices.Factory.get();
KieContainer kieClasspathContainer = kieServices.getKieClasspathContainer();
KieSession kieSession = kieClasspathContainer.newKieSession();
ComparisonOperatorEntity comparisonOperatorEntity = new ComparisonOperatorEntity();
comparisonOperatorEntity.setNames("李四");
List<String> list = new ArrayList<String>();
list.add("张三");
list.add("李四");
comparisonOperatorEntity.setList(list);
//将数据提供给规则引擎，规则引擎会根据提供的数据进行规则匹配，如果规则匹配成功则执行规则
kieSession.insert(comparisonOperatorEntity);
int i = kieSession.fireAllRules();
System.out.println("规则执行条数："+i);
kieSession.dispose();
}
6 执行指定规则
Drools给我们提供的方式是通过规则过滤器来实现执行指定规则。对于规则文件不用做任何修改，只需要修改Java代码即可，如下
//执行指定规则
@Test
public void test3(){
KieServices kieServices = KieServices.Factory.get();
KieContainer kieClasspathContainer = kieServices.getKieClasspathContainer();
KieSession kieSession = kieClasspathContainer.newKieSession();
ComparisonOperatorEntity comparisonOperatorEntity = new ComparisonOperatorEntity();
comparisonOperatorEntity.setNames("李四");
List<String> list = new ArrayList<String>();
list.add("张三");
list.add("李四");
comparisonOperatorEntity.setList(list);
//将数据提供给规则引擎，规则引擎会根据提供的数据进行规则匹配，如果规则匹配成功则执行规则
kieSession.insert(comparisonOperatorEntity);
// int i = kieSession.fireAllRules();
// int i = kieSession.fireAllRules(new RuleNameEqualsAgendaFilter("rule_comparison_notMatches"));
// int i = kieSession.fireAllRules(new RuleNameEndsWithAgendaFilter("Matches"));
// int i = kieSession.fireAllRules(new RuleNameStartsWithAgendaFilter("rule_comparison"));
int i = kieSession.fireAllRules(new RuleNameMatchesAgendaFilter("rule_comparison.*"));
System.out.println("规则执行条数："+i);
kieSession.dispose();
}
Drools可以按照多种方式指定一个或者多个规则执行，以规则名称、前缀、后缀、正则…很多形式，非常灵活。可传入AgendaFilter接口的实现类如下：
7.关键字
Drools的关键字分为：硬关键字(Hard keywords)和软关键字(Soft keywords)。
硬关键字是我们在规则文件中定义包名或者规则名时明确不能使用的，否则程序会报错。软关键字虽然可以使用，但是不建议使用。
硬关键字包括：true false null
软关键字包括：lock-on-active date-effective date-expires no-loop auto-focus activation-group agenda-group ruleflow-group entry-point duration package import dialect salience enabled attributes rule extend when then template query declare function global eval not in or and exists forall accumulate collect from action reverse result end over init
8.Drools内置方法
规则文件的RHS部分的主要作用是通过插入，删除或修改工作内存中的Fact数据，来达到控制规则引擎执行的目的。Drools提供了一些方法可以用来操作工作内存中的数据，操作完成后规则引擎会重新进行相关规则的匹配，原来没有匹配成功的规则在我们修改数据完成后有可能就会匹配成功了。
8.1 update
update方法的作用是更新工作内存中的数据，并让相关的规则重新匹配。(会重新触发规则执行)
第一步：编写规则文件/resources/rules/student.drl，文件内容如下
package rules;
import drools.entity.Student
dialect "mvel"
/*
当前规则文件用于测试Drools提供的内置方法
*/
rule "rule_student_age小于10岁"
when
$a:Student(age<10)
then
$a.setAge(15);
update($a)//更新数据，导致相关的规则会重新匹配
System.out.println("规则rule_student_age小于10岁触发...");
end
rule "rule_student_age小于20岁同时大于10岁"
when
$s:Student(age < 20 && age >= 10)
then
$s.setAge(25);
update($s);//更新数据，导致相关的规则会重新匹配
System.out.println("规则rule_student_age小于20岁同时大于10岁触发...");
end
rule "rule_student_age大于20岁"
when
$s:Student(age >= 20 )
then
System.out.println("规则rule_student_age大于20岁触发...");
end
@Test
public void test4(){
KieServices kieServices = KieServices.Factory.get();
KieContainer kieClasspathContainer = kieServices.getKieClasspathContainer();
KieSession kieSession = kieClasspathContainer.newKieSession();
Student fact=new Student();
fact.setAge(5);
fact.setName("张三");
System.out.println(fact);
kieSession.insert(fact);
int count = kieSession.fireAllRules();
System.out.println("条数："+count);
System.out.println(fact);
}
结果打印
通过控制台的输出可以看到规则文件中定义的三个规则都触发了。
在更新数据时需要注意防止发生死循环。
8.2 insert
insert方法的作用是向工作内存中插入数据，并让相关的规则重新匹配。
第一步：修改student.drl文件内容如下
package rules;
import drools.entity.Student
dialect "mvel"
/*
当前规则文件用于测试Drools提供的内置方法
*/
rule "rule_student_age小于10岁"
when
$a:Student(age<10)
then
$a.setAge(15);
update($a)//更新数据，导致相关的规则会重新匹配
System.out.println("规则rule_student_age小于10岁触发...");
end
rule "rule_student_age小于20岁同时大于10岁"
when
$s:Student(age < 20 && age > 10)
then
$s.setAge(25);
update($s);//更新数据，导致相关的规则会重新匹配
System.out.println("规则rule_student_age小于20岁同时大于10岁触发...");
end
rule "rule_student_age大于20岁"
when
$s:Student(age >= 20 )
then
System.out.println("规则rule_student_age大于20岁触发...");
end
rule "rule_student_age等于10岁"
when
$s:Student(age == 10)
then
Student student = new Student();
student.setAge(5);
insert(student);//插入数据，导致相关的规则会重新匹配
System.out.println("规则rule_student_age等于10岁触发");
end
第二步：编写单元测试
@Test
public void test4(){
KieServices kieServices = KieServices.Factory.get();
KieContainer kieClasspathContainer = kieServices.getKieClasspathContainer();
KieSession kieSession = kieClasspathContainer.newKieSession();
Student fact=new Student();
fact.setAge(10);
fact.setName("张三");
System.out.println(fact);
kieSession.insert(fact);
int count = kieSession.fireAllRules();
System.out.println("条数："+count);
System.out.println(fact);
}
结果打印
说明：
- 通过控制台输出可以发现，四个规则都触发了，这是因为首先进行规则匹配时只有第一个规则可以匹配成功，但是在第一个规则中向工作内存中插入了一个数据导致重新进行规则匹配，此时第二个规则可以匹配成功。在第二个规则中进行了数据修改导致第三个规则也可以匹配成功，以此类推最终四个规则都匹配成功并执行了。
- insert的确是触发了其他规则的执行，但是是插入的对象触发的，并不是传入的fact对象，所以，最终student的age属性并没有发生变化。
8.3 retract
retract方法的作用是删除工作内存中的数据，并让相关的规则重新匹配。
第一步：修改student.drl文件内容如下
package rules;
import drools.entity.Student
dialect "mvel"
/*
当前规则文件用于测试Drools提供的内置方法
*/
rule "rule_student_age小于10岁"
when
$a:Student(age<10)
then
$a.setAge(15);
update($a)//更新数据，导致相关的规则会重新匹配
System.out.println("规则rule_student_age小于10岁触发...");
end
rule "rule_student_age小于20岁同时大于10岁"
when
$s:Student(age < 20 && age > 10)
then
$s.setAge(25);
update($s);//更新数据，导致相关的规则会重新匹配
System.out.println("规则rule_student_age小于20岁同时大于10岁触发...");
end
rule "rule_student_age大于20岁"
when
$s:Student($age:age >= 20 )
then
System.out.println("规则rule_student_age大于20岁触发...");
// System.out.println("规则rule_student_age大于20岁触发...："+ $age);
end
rule "rule_student_age等于10岁"
when
$s:Student(age == 10)
then
Student student = new Student();
student.setAge(5);
insert(student);//插入数据，导致相关的规则会重新匹配
System.out.println("规则rule_student_age等于10岁触发");
end
rule "rule_student_age等于10岁用于删除"
salience 10 //权重，保重该规则先执行
when
$s:Student(age == 10)
then
retract($s);//删除内存中的对象
System.out.println("规则rule_student_age等于10岁触发用于删除");
end
第二步：编写单元测试
@Test
public void test4(){
KieServices kieServices = KieServices.Factory.get();
KieContainer kieClasspathContainer = kieServices.getKieClasspathContainer();
KieSession kieSession = kieClasspathContainer.newKieSession();
Student fact=new Student();
fact.setAge(10);
fact.setName("张三");
System.out.println(fact);
kieSession.insert(fact);
int count = kieSession.fireAllRules();
System.out.println("条数："+count);
System.out.println(fact);
}
结果打印
说明：
内存中的Student被删除了，后边的规则无法触发。
扫一扫
3317
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
