【洛谷】2580 于是他错误的点名开始了

题目链接：https://www.luogu.org/problemnew/show/2580

Description

校长任命你为特派探员，每天记录他的点名。校长会提供化学竞赛学生的人数和名单，而你需要告诉校长他有没有点错名。

Input

第一行一个整数 n，表示班上人数。接下来 n 行，每行一个字符串表示其名字（互不相同，且只含小写字母，长度不超过 50）。第 n+2 行一个整数 m，表示教练报的名字。接下来 m 行，每行一个字符串表示教练报的名字（只含小写字母，且长度不超过 50）。

Output

对于每个教练报的名字，输出一行。如果该名字正确且是第一次出现，输出“OK”，如果该名字错误，输出“WRONG”，如果该名字正确但不是第一次出现，输出“REPEAT”。（均不加引号）

Analysis

字典树的入门模板题，在一个字符串的尾节点上进行标记，如果当前的节点没有接下来的孩子，那么说明没有这个字符串没有出现在这个名单中输出WRONG。
如果当前已经访问到了最后一个节点，进行一个判断。如果当前访问的尾节点已经被还没被访问过，那么就输出OK，再标记当前节点已经访问。
如果已访问，那么就输出REPEAT。

Code

var
  tr:array[1..500000,1..26]of longint;//字典树数组
  s:string;
  sum,i,n,m:longint;
  vis:array[1..500000]of boolean;//标记当前尾节点是否访问

procedure build(s:string);//建树模板
var
  i,k,p:longint;
begin
  k:=1;
  for i:=1 to length(s) do 
    begin
      p:=ord(s[i])-ord('a')+1;//以防有0的出现
      if tr[k][p]=0 then//如果没有p这个儿子，那么就建一个节点
        begin
          inc(sum);
          tr[k][p]:=sum;
        end;
      k:=tr[k][p];//向下走
    end;
end;

procedure find(s:string);//查找当前字符串是否出现在树中
var
  k,p,i:longint;
begin
  k:=1;
  for i:=1 to length(s)do//枚举每一个点
    begin
      p:=ord(s[i])-ord('a')+1;
      if tr[k][p]=0 then //如果当前的节点没有p这个儿子，那么就说明没有这个字符串，那么输出WRONG
        begin 
          writeln('WRONG'); 
          exit;
        end;
      k:=tr[k][p];
    end;
  if vis[k] then begin writeln('OK'); vis[k]:=false; end
    else writeln('REPEAT');//判断当前是否访问，访问就输出REPEAT，否则输出OK
end;

begin
  fillchar(vis,sizeof(vis),true);//初始化，全部都没有访问过
  sum:=1;
  readln(n);
  for i:=1 to n do 
    begin
      readln(s);
      build(s);
    end;
  readln(m);
  for i:=1 to m do 
    begin
      readln(s);
      find(s);
    end;
end.