瑞士轮 pascal

题目背景

在双人对决的竞技性比赛，如乒乓球、羽毛球、国际象棋中，最常见的赛制是淘汰赛和循环赛。前者的特点是比赛场数少，每场都紧张刺激，但偶然性较高。后者的特点是较为公平，偶然性较低，但比赛过程往往十分冗长。

本题中介绍的瑞士轮赛制，因最早使用于1895年在瑞士举办的国际象棋比赛而得名。它可以看作是淘汰赛与循环赛的折衷，既保证了比赛的稳定性，又能使赛程不至于过长。

题目描述

2*N 名编号为 1~2N 的选手共进行R 轮比赛。每轮比赛开始前，以及所有比赛结束后，都会按照总分从高到低对选手进行一次排名。选手的总分为第一轮开始前的初始分数加上已参加过的所有比赛的得分和。总分相同的，约定编号较小的选手排名靠前。

每轮比赛的对阵安排与该轮比赛开始前的排名有关：第1 名和第2 名、第 3 名和第 4名、……、第2K – 1 名和第 2K名、…… 、第2N – 1 名和第2N名，各进行一场比赛。每场比赛胜者得1 分，负者得 0 分。也就是说除了首轮以外，其它轮比赛的安排均不能事先确定，而是要取决于选手在之前比赛中的表现。

现给定每个选手的初始分数及其实力值，试计算在R 轮比赛过后，排名第 Q 的选手编号是多少。我们假设选手的实力值两两不同，且每场比赛中实力值较高的总能获胜。

输入输出格式

输入格式：

输入文件名为swiss.in 。

输入的第一行是三个正整数N、R 、Q，每两个数之间用一个空格隔开，表示有 2*N 名选手、R 轮比赛，以及我们关心的名次 Q。

第二行是2*N 个非负整数s1, s2, …, s2N，每两个数之间用一个空格隔开，其中 si 表示编号为i 的选手的初始分数。 第三行是2*N 个正整数w1 , w2 , …, w2N，每两个数之间用一个空格隔开，其中 wi 表示编号为i 的选手的实力值。

输出格式：

输出文件名为swiss.out。

输出只有一行，包含一个整数，即R 轮比赛结束后，排名第 Q 的选手的编号。

输入输出样例

输入样例#1：

2 4 2 
7 6 6 7 
10 5 20 15 

输出样例#1：

1

说明

【样例解释】

【数据范围】

对于30% 的数据，1 ≤ N ≤ 100；

对于50% 的数据，1 ≤ N ≤ 10,000 ；

对于100%的数据，1 ≤ N ≤ 100,000，1 ≤ R ≤ 50，1 ≤ Q ≤ 2N，0 ≤ s1, s2, …, s2N≤10^8，1 ≤w1, w2 , …, w2N≤ 10^8。

noip2011普及组第3题。

• var
    a:array[0..200000,1..3] of longint;
    b,c:array[0..100000,1..3] of longint;
    n:longint; 
  
  procedure qsort(l,r:longint);
  var
    i,j,k,s:longint;
  begin
    if l>=r then exit;
    i:=l;
    j:=r;
    k:=a[(i+j) div 2,1];
    s:=a[(i+j) div 2,3];
    repeat
      while (a[i,1]>k)or(a[i,1]=k)and(a[i,3]<s) do inc(i);
      while (a[j,1]<k)or(a[j,1]=k)and(a[j,3]>s) do dec(j);
      if i<=j then
      begin
        a[0]:=a[i];a[i]:=a[j];a[j]:=a[0];
        inc(i);dec(j);
      end;
    until i>j;
    qsort(i,r);
    qsort(l,j);
  end;
  
  procedure gb;
  var
    p,q,a1,i:longint;
  begin
    p:=1;
    q:=1;
    a1:=0;
    while (p<=n)and(q<=n) do
      if (b[p,1]>c[q,1])or(b[p,1]=c[q,1])and(b[p,3]<c[q,3])
        then begin
               inc(a1);
               a[a1]:=b[p];
               inc(p)
             end
        else begin
               inc(a1);
               a[a1]:=c[q];
               inc(q);
             end;
    for i:=p to n do
    begin
      inc(a1);
      a[a1]:=b[i];
    end;
    for i:=q to n do
    begin
      inc(a1);
      a[a1]:=c[i];
    end;
  end;
  
  procedure main;
  var
    r,q,i,j:longint;
  begin
    readln(n,r,q);
    for i:=1 to n*2 do
      read(a[i,1]);
    readln;
    for i:=1 to n*2 do
    begin
      read(a[i,2]);
      a[i,3]:=i;
    end;
    qsort(1,n*2);
    for i:=1 to r do
    begin
      for j:=1 to n do
        if a[j*2-1,2]>a[j*2,2]
        then begin
               inc(a[j*2-1,1]);
               b[j]:=a[j*2-1];
               c[j]:=a[j*2];
             end
        else begin
               inc(a[j*2,1]);
               b[j]:=a[j*2];
               c[j]:=a[j*2-1];
             end;
      gb;
    end;
    writeln(a[q,3]);
  end;
  
  begin
    main;
  
  end.