异常（以页面异常和除零错误为例）

在了解了中断的工作原理之后，你会发现，异常的处理是如此简单！

与中断相比，异常的处理无非多了对出错码的处理：

ENTRY(page_fault)
	RING0_EC_FRAME
	pushl_cfi $do_page_fault
	ALIGN
error_code:
	/* the function address is in %gs's slot on the stack */
	pushl_cfi %fs
	/*CFI_REL_OFFSET fs, 0*/
	pushl_cfi %es
	/*CFI_REL_OFFSET es, 0*/
	pushl_cfi %ds
	/*CFI_REL_OFFSET ds, 0*/
	pushl_cfi %eax
	CFI_REL_OFFSET eax, 0
	pushl_cfi %ebp
	CFI_REL_OFFSET ebp, 0
	pushl_cfi %edi
	CFI_REL_OFFSET edi, 0
	pushl_cfi %esi
	CFI_REL_OFFSET esi, 0
	pushl_cfi %edx
	CFI_REL_OFFSET edx, 0
	pushl_cfi %ecx
	CFI_REL_OFFSET ecx, 0
	pushl_cfi %ebx
	CFI_REL_OFFSET ebx, 0          

#行至此处，系统栈内的情况如下：
#（栈底）SS-ESP-EFLAGS-CS-EIP-出错码-do_page_fault-FS-ES-DS-EAX-EBP-EDI-ESI-EDX-ECX-EBX（栈顶）
#其中，出错码并不是每个异常都会产生的，如果没有产生出错码，那么此处会是0，可以参考除零异常的处理。可以通过出错码来识别发生异常的原因。
#do_page_fault则指向具体的服务程序
#

	cld      #确保调用字符串处理指令时会自动增加edi和esi
	movl $(__KERNEL_PERCPU), %ecx
	movl %ecx, %fs
	UNWIND_ESPFIX_STACK
	GS_TO_REG %ecx
	movl PT_GS(%esp), %edi		# get the function address
	movl PT_ORIG_EAX(%esp), %edx	# get the error code （调用do_page_fault时的第二个参数）
	movl $-1, PT_ORIG_EAX(%esp)	# no syscall to restart
	REG_TO_PTGS %ecx
	SET_KERNEL_GS %ecx
	movl $(__USER_DS), %ecx
	movl %ecx, %ds
	movl %ecx, %es
	TRACE_IRQS_OFF
	movl %esp,%eax			# pt_regs pointer (调用do_page_fault时的第一个参数)
	call *%edi
	jmp ret_from_exception
	CFI_ENDPROC
END(page_fault)

在系统调用的时候，一般用寄存器传参，eax作为第一个参数，edx作为第二个参数。