汇编：实现日历星期数查询工具

最新推荐文章于 2024-05-27 17:48:36 发布
最新推荐文章于 2024-05-27 17:48:36 发布
阅读量1.2k 收藏 24
点赞数 1
分类专栏： # 汇编
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/T_T233333333/article/details/106216830
版权

编制一个简单日历查询工具，输入年、月、日，能够判断当日的星期数，并进行输出，数据的输入和结果的输出要有必要的提示，且提示独占一行。

查阅资料

​ 经过查阅资料，发现有两个相关的算法可以解决这个问题：

  1. 蔡勒公式
    W = [ C / 4 ] − 2 C + Y + [ Y / 4 ] + [ 13 ∗ ( M + 1 ) / 5 ] + D − 1 W=[C/4]-2C+Y+[Y/4]+[13*(M+1)/5]+D-1 W=[C/4]−2C+Y+[Y/4]+[13∗(M+1)/5]+D−1
    公式中的符号含义如下：

    • W：星期； W对7取模得：0-星期日，1-星期一，2-星期二，3-星期三，4-星期四，5-星期五，6-星期六，需要注意的是对负数的处理
    • C：世纪-1（前两位数）
    • Y：年（后两位数）
    • M：月（M大于等于3，小于等于14，即在蔡勒公式中，某年的1、2月要看作上一年的13、14月来计算，比如2003年1月1日要看作2002年的13月1日来计算）
    • D：日
    • [ ]代表取整，即只要整数部分。

  2. 基姆拉尔森计算公式
    W e e k = ( d + 2 ∗ m + 3 ∗ ( m + 1 ) / 5 + y + y / 4 − y / 100 + y / 400 + 1 ) m o d 7 Week = (d+2*m+3*(m+1)/5+y+y/4-y/100+y/400+1) mod 7 Week=(d+2∗m+3∗(m+1)/5+y+y/4−y/100+y/400+1)mod7
    公式中的符号含义如下：

    • y : 年份（四位数）
    • m: 月份（m大于等于3，小于等于14，某年的1、2月要看作上一年的13、14月来计算，比如2003年1月1日要看作2002年的13月1日来计算）
    • d : 日期
    • 当 W e e k = = 0 Week==0 Week==0的时候为周日
设计构思

​ 基姆拉尔森计算公式的输入更加友好，因此我决定使用基姆拉尔森计算公式解决问题。

​ 公式主要涉及加减乘除四则运算，输入主要是年月日三个数字。输出为星期数。

​ 因此主要的工作有：

  • 提示用户输入年月日，并进行错误检查（检查是否是数字，位数是否错误）
  • 检查月份是否在正确的范围内（0~12)
  • 检查日期是否在正确的范围内
    • 是否小于1
    • 是否大于该月的最大日期
    • 是否是闰月，如果是闰月需要特别对待
  • 使用基姆拉尔森计算公式计算星期数
  • 输出结果，并询问是否再次输入
流程图

在这里插入图片描述

实现代码
ASSUME cs:CODE, ds:DATA, ss:STACK 

DATA SEGMENT
	S_Year 	db 	5,0,5 dup(0)
	S_Month db	3,0,3 dup(0)
	S_Day 	db	3,0,3 dup(0)
	YearIn	db	'please input year(eg:2020):$'
	MonthIn	db	'please	input month(eg:05):$'
	DayIn	db	'please input day(eg:01):$'
	WrongInfo db 'your input is illegal,please input again!$'
	ReaptInfo db 'Would you like to check again?(Y/n)	$'
	year 	dw	0
	month 	db	0
	day 	db	0
	Max_Day db	0,31,28,31,30,31,30,31,31,30,31,30,31
	tmp		dw	0
	week1	db	'Monday$'
	week2	db	'Tuesday$'
	week3	db	'Wednesday$'
	week4	db	'Thursday$'
	week5	db	'Friday$'
	week6	db	'Saturday$'
	week7	db	'Sunday$'
	hint	db	' is $'

DATA ENDS

STACK SEGMENT
	db 256	dup(0)
STACK ENDS

CODE SEGMENT

NEXTLINE PROC NEAR	;输出换行
	mov ah, 02H
	mov	dl, 0DH
	int 21H
	mov dl, 0AH
	int 21H
	ret
NEXTLINE ENDP

MAIN PROC
START:
	mov ax,DATA
	mov ds,ax	;初始化
INPUTYEAR:
	call NEXTLINE
	lea dx, YearIn	;提示输入year
	mov ah, 09H
	int 21H
	lea dx, S_Year 	;读入year
	mov ah, 0AH
	int 21H

	call NEXTLINE	;换行
	;检查Year是否合法
	mov cl, S_Year+1	;将实际长度保存到cx中
	mov ch, 0
	cmp cx, 4		;检查长度，同时计算year的值
	jnz WRONGYEAR
	mov year, 0
	mov si, 2
CHECKYEAR:
	;判断是否是数字
	mov dl, S_Year[si]
	cmp dl, '0'
	jl	WRONGYEAR
	cmp dl, '9'
	jg	WRONGYEAR
	;是数字，计算year
	mov ax, year
	mov bx, 10
	mul bx
	mov dl, S_Year[si]
	sub dl, '0'
	mov dh, 0
	add ax, dx
	mov year, ax
	inc si
	loop CHECKYEAR
	;year计算完毕
	jp	INPUTMONTH

WRONGYEAR:
	lea dx, WrongInfo	;输出错误信息
	mov ah, 09H
	int 21H
	call NEXTLINE		;换行
	jp	INPUTYEAR		;重新输入

INPUTMONTH:
	lea dx, MonthIn		;提示输入month
	mov ah, 09H
	int 21H
	lea dx, S_Month 	;读入month
	mov ah, 0AH
	int 21H

	call NEXTLINE		;换行
	;检查Month是否合法
	mov cl, S_Month+1	;将实际长度保存到cx中
	mov ch, 0
	cmp cx, 2			;检查长度，同时计算month的值
	jnz WRONGMONTH
	mov month, 0
	mov si, 2
CHECKMONTH:
	;判断是否是数字
	mov dl, S_Month[si]
	cmp dl, '0'
	jl	WRONGMONTH
	cmp dl, '9'
	jg	WRONGMONTH
	;是数字，计算month
	mov al, month
	mov bl, 10
	mul bl
	sub dl, '0'
	add al, dl
	mov month, al
	inc si
	loop CHECKMONTH
	;month计算完毕
	;判断month是否在合法范围内
	mov dl, month
	cmp dl, 1
	jl	WRONGMONTH
	cmp dl, 12
	jg	WRONGMONTH
	jmp INPUTDAY

WRONGMONTH:
	lea dx, WrongInfo	;输出错误信息
	mov ah, 09H
	int 21H
	call NEXTLINE		;换行
	jmp	INPUTMONTH		;重新输入

INPUTDAY:
	lea dx, DayIn	;提示输入day
	mov ah, 09H
	int 21H
	lea dx, S_Day 	;读入day
	mov ah, 0AH
	int 21H

	call NEXTLINE	;换行
	;检查day是否合法
	mov cl, S_Day+1	;将实际长度保存到cx中
	mov ch, 0
	cmp cx, 2		;检查长度，同时计算day的值
	jnz WRONGDAY_TMP
	mov si, 2
	mov day, 0
CHECKDAY:
	
	;判断是否是数字
	mov dl, S_Day[si]
	cmp dl, '0'
	jl	WRONGDAY_TMP
	cmp dl, '9'
	jg	WRONGDAY_TMP
	;是数字，计算day
	mov al, day
	mov bl, 10
	mul bl
	sub dl, '0'
	add al, dl
	mov day, al
	inc si
	loop CHECKDAY
	;day计算完毕
	;检查day是否在合法范围内

	mov dl, day
	cmp dl, 1
	jl	WRONGDAY
	mov cl, month
	mov ch, 0
	mov si, cx
	cmp dl, Max_Day[si]	;检查有没有该月份最大的一天
	jg	CHECKLEAP		;检查是不是闰月

	jmp	INPUTEND		;输入结束

WRONGDAY_TMP:
	jmp WRONGDAY

CHECKLEAP:
	mov dh, month
	cmp dh, 2
	jne WRONGDAY		;如果不是2月就肯定不对
	;判断是不是闰年if(year%4==0 && year%100!=0 || year%400==0) 是闰年
	mov ax, year
	mov dx, 0
	mov bx, 400
	div bx
	cmp dx, 0
	je	ISLEAP 			;可以被400整除说明是闰月
	mov ax, year
	mov dx, 0
	mov bx, 4
	div bx
	cmp dx, 0
	jne ISNOTLEAP		;不能被4整除说明不是闰月
	mov ax, year
	mov dx, 0
	mov bx, 100
	div bx
	cmp dx, 0
	je 	ISNOTLEAP		;能被100整除说明不是闰月
ISLEAP:
	mov dl, day
	cmp dl, 29			
	jg	WRONGDAY		;比29还大
	jmp	INPUTEND		;输入结束

ISNOTLEAP:
WRONGDAY:
	lea dx, WrongInfo	;输出错误信息
	mov ah, 09H
	int 21H
	call NEXTLINE		;换行
	jmp	INPUTDAY		;重新输入

INPUTEND:				;输入合法，开始使用基姆拉尔森公式计算答案
	mov dl, month
	cmp dl, 1
	je	ADDMONTH
	cmp	dl, 2
	je 	ADDMONTH
	jmp CALCULATE

ADDMONTH:
	mov al, month
	add al, 12
	mov month, al
	mov ax, year
	sub ax, 1
	mov year, ax

CALCULATE:

	mov bl, day
	mov bh, 0			;bx := day
	add bl, month
	add bl, month 		;bx += 2*month

	mov al, month
	add al, 1
	mov ah, al
	add al, ah 
	add al, ah 			;al := 3*(month+1)

	mov ah, 0
	mov cl, 5
	div cl
	mov ah, 0			;ax := al/5
	add bx, ax			;bx += ax

	add bx, year 		;bx += year
	mov ax, year
	mov dx, 0
	mov cx, 4
	div cx
	add bx, ax			;bx += year/4
	mov ax, year
	mov dx, 0
	mov cx, 100
	div cx
	sub bx, ax			;bx -= year/100
	mov ax, year
	mov dx, 0
	mov cx, 400
	div cx
	add bx, ax			;bx += year/400

	add bx, 1			;bx += 1
	mov ax, bx
	mov dx, 0
	mov cx, 7
	div cx				;bx %= 7
	mov bx, dx

	;基姆拉尔森公式计算完毕

OUTPUT:
	call NEXTLINE
	mov al, S_Year+1
	add al, 2
	mov ah, 0
	mov si, ax	
	mov S_Year[si], '$'	;加上字符串终结符$
	lea dx, S_Year+2	;输出年份
	mov ah, 09H
	int 21H

	mov dl, '\'
	mov ah, 02H
	int 21H

	mov al, S_Month+1
	add al, 2
	mov ah, 0
	mov si, ax	
	mov S_Month[si], '$'
	lea dx, S_Month+2
	mov ah, 09H
	int 21H

	mov dl, '\'
	mov ah, 02H
	int 21H

	mov al, S_Day+1
	add al, 2
	mov ah, 0
	mov si, ax	
	mov S_Day[si], '$'
	lea dx, S_Day+2
	mov ah, 09H
	int 21H

	lea	dx,	hint
	mov ah,	09H
	int 21H

	mov al, bl
	cmp al, 0
	jnz D1
	lea dx, week7
	mov ah, 09H
	int 21H
	jmp	D7

INPUTYEAR_TMP1:
	call NEXTLINE
	jmp INPUTYEAR

D1:	
	cmp al, 1
	jnz D2
	lea dx, week1
	mov ah, 09H
	int 21H
	jmp	 D7
D2:
	cmp al, 2
	jnz D3
	lea dx, week2
	mov ah, 09H
	int 21H
	jmp	D7 
D3:
	cmp al, 3
	jnz D4
	lea dx, week3
	mov ah, 09H
	int 21H
	jmp	D7 
D4:
	cmp al, 4
	jnz D5
	lea dx, week4
	mov ah, 09H
	int 21H
	jmp	D7 
D5:
	cmp al, 5
	jnz D6
	lea dx, week5
	mov ah, 09H
	int 21H
	jmp	D7 
D6:
	cmp al, 6
	jnz D7
	lea dx, week6
	mov ah, 09H
	int 21H
D7:
	call NEXTLINE
	call NEXTLINE

	lea dx, ReaptInfo	;输出重复查询信息
	mov ah, 09H
	int 21H

	mov ah, 01H			;输入字符
	int 21H

	cmp al, 'Y'
	jz INPUTYEAR_TMP1	;跳转到中继点1
	cmp al, 'y'
	jz INPUTYEAR_TMP1 	;跳转到中继点1

	mov ax, 4C00H		;程序结束
	int 21H
MAIN ENDP

CODE ENDS
END START
运行结果

我将自己运行结果的视频上传在CSDN上啦：传送门

王江奎
关注
  • 1
    点赞
  • 踩
  • 24
    收藏
    觉得还不错? 一键收藏
  • 1
    评论
专栏目录
【RISC-V操作系统】从零开始写一个操作系统（八）RISCV汇编语言编程
m0_54138660的博客
04-08 1758
这一节来讲条件分支，跳转等等还有一些杂项。
win10电脑日历怎么显示第几周？
xitongzhijianet的博客
01-04 7783
win10自带日历，不过日历默认是只能显示日期和年份的，那么win10日历怎么显示周数呢，其实只需要打开日历中的设置，在其中就可以开启周数了。下面就来看看详细的操作。第六步：回到日历，点击右上角“周”，就可以看到周数了。第一步：在左下角搜索框中输入“日历”。第五步：在其中打开周数并选择一个周数。第四步：点击设置右边栏“日历设置”。win10电脑日历怎么显示第几周？第二步：打开搜索结果中的“日历”。第三步：打开左下角“齿轮”设置。
汇编：比较&跳转
最新发布
WolvenSec的博客
05-27 1144
在16位汇编语言（如x86汇编）中，比较指令用于比较两个操作数的大小，通常用于条件跳转、循环控制等逻辑操作，比较指令（如CMP）会根据操作数的比较结果设置标志寄存器中的相关标志位。
汇编语言指令
m0_61567378的博客
10-31 2994
lable就是要跳转到的地方,RD就是label地址处理完之后返回的地址。从RS里面取出数据，把里面的数据计算，得出的结果放在rd里面。这里的RD，就是为了跳转回来爱能执行子过程，后面的函数。auipc就是把一个数左移12位，后再加上pc值。少了一个寄存器，占12个bit位，用一个立即数。如果条件成立就跳转到最后一个最后一个地址上。是不返回的跳转，J/JR就是一个伪指令。常用于加载一个函数或者变量的地址。jr跳转到x5里面，就是死循环。bne最后一个就是要跳转的地址。跳转到x5+0的位置，x0保存。
汇编跳转指令包括条件跳转指令和无条件跳转指令，以下是一些常见的小写形式及其实例和解析：
2301_81654001的博客
12-12 2181
条件跳转和无条件跳转实例、解析
汇编语言——跳转指令: JMP、JECXZ、JA、JB、JG、JL、JE、JZ、JS、JC、JO、JP
热门推荐
wyyy2088511的博客
03-25 4万+
一、无条件跳转: JMP; 二、根据 CX、ECX 寄存器的值跳转: JCXZ(CX 为 0 则跳转)、JECXZ(ECX 为 0 则跳转); 根据标志位跳转的指令: JE ;等于则跳转 JNE ;不等于则跳转 JZ ;为 0 则跳转 JNZ ;不为 0 则跳转 JS ;为负则跳转 JNS ;不为负则跳转 JC ;进位则跳转 JNC ;不进位则跳转 JO ;溢出则跳转 JNO ;不溢出则跳转 JA ;无符号大于则跳转 JNA ;无符号不大于则跳转 JAE ...
通过定时器在液晶上实现日历表
04-12
5. **编程语言与开发环境**：通常使用C或汇编语言编写单片机程序，开发环境可能包括Keil、IAR等，这些工具提供编译、调试等功能，帮助开发者编写、测试和优化代码。 6. **中断系统**：定时器中断是实现日历表自动...
数字日历计算机硬件课程设计
05-22
本课程设计的主要任务是构建一个能够显示日期、星期，并具备日期调整、节假日提示以及日期查询功能的数字日历。 ### 1. 设计内容和要求 1. **数码管显示**：数字日历应能在数码管上清晰地显示当前的年、月、日以及...
单片机课程设计电子日历.doc
07-17
【单片机课程设计电子日历】是一个关于嵌入式系统设计的实践项目，主要目标是使用AT89C51单片机为核心，结合DS1302电子日历芯片和LCD液晶显示屏，构建一个能够显示时间、日期、星期，并具备设定时间功能的电子日历。...
基于DS1302的日历时钟.rar
02-02
在这个项目中，“基于DS1302的日历时钟”是一个利用51系列单片机实现的时间显示和管理装置。51单片机是经典的8位处理器，因其易用性和广泛的资源支持，成为初学者和工程师的首选。 DS1302是一款实时时钟芯片，由...
少儿英语学习主题汇编.pdf
11-20
8. **月份** (Month) 和 **星期** (Week)：虽然这部分没有列出具体词汇，但学习月份和星期对于认识日历和时间管理非常重要，是日常生活中的基本概念。 9. **动物** (Animals)：如Monkey、Neck、Policeman、Grape、...
5（星期判断程序）汇编程序设计.asm
04-30
星期判断程序。输入年、月、日,能够判断当日的星期数,并进行输出。(可设某年的1 月1 日为起点,根据相差的天数与7 的关系进行判断) 星期判断程序。输入年、月、日,能够判断当日的星期数,并进行输出。(可设某年的1 月1 日为起点,根据相差的天数与7 的关系进行判断) 星期判断程序。输入年、月、日,能够判断当日的星期数,并进行输出。(可设某年的1 月1 日为起点,根据相差的天数与7 的关系进行判断)
一个用汇编实现输入一个时间显示是星期几的程序
04-16
一个用汇编实现输入一个时间显示是星期几的程序，是我们的课程设计作业
星期判断汇编课程设计
12-19
星期判断 内有详细 说明 代码 的 作用
汇编语言星期转换程序
12-25
汇编语言的星期转换小程序 大学汇编程序的一道作业题
汇编万年历
01-22
用汇编语言写的万年历，可输出1582年之后的年历。
sql查看当前周数
weixin_30888707的博客
04-09 1139
select datepart(wk,cast(getdate() as datetime)) 转载于:https://www.cnblogs.com/chlf/p/4408984.html
汇编--条件跳转指令
飘零过客
08-22 4672
条件跳转指令很多，支持根据有符号、无符号整数的比较以及对CPU状态标志的检查进行跳转的一系列指令。
【ARMv7-A】——子程呼叫与无条件跳转指令B、BL、BX和BLX
tyustli
03-16 5237
1、B：无条件转移 B指令是最简单的跳转指令。一旦遇到一个B指令，ARM处理器将立即跳转到给定的目标地址，从那里继续执行。注意，存储在跳转指令中的实际值是相对当前PC值的一个偏移量，而不是绝对地址，它的值由汇编器来计算。 例：B Label ;程序无条件跳转到标号Label处执行 2、BL：转移并连接，用于呼叫一个子程序，返回地址被存储在LR中 BL指令是带连接的跳转，在跳转之前，会在寄存...
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值