关于bootasm.s理解

#include "asm.h"
#include "memlayout.h"
#include "mmu.h"

#操作系统加载到内存中的第一个程序入口

#BIOS程序将该段程序加载到内存的0x7c00处
#
# Start the first CPU: switch to 32-bit protected mode, jump into C.
# The BIOS loads this code from the first sector of the hard disk into
# memory at physical address 0x7c00 and starts executing in real mode
# with %cs=0 %ip=7c00.由此处可以知道程序运行的CS段的值是0x0

.code16                       # Assemble for 16-bit mode
.globl start
start:
  cli                         # BIOS enabled interrupts; disable

  # Zero data segment registers DS, ES, and SS.
  xorw    %ax,%ax             # Set %ax to zero
  movw    %ax,%ds             # -> Data Segment
  movw    %ax,%es             # -> Extra Segment
  movw    %ax,%ss             # -> Stack Segment

  # Physical address line A20 is tied to zero so that the first PCs 
  # with 2 MB would run software that assumed 1 MB.  Undo that.

  # 打开A20，准备进入保护模式
seta20.1:
  inb     $0x64,%al               # Wait for not busy
  testb   $0x2,%al
  jnz     seta20.1

  movb    $0xd1,%al               # 0xd1 -> port 0x64
  outb    %al,$0x64

seta20.2:
  inb     $0x64,%al               # Wait for not busy
  testb   $0x2,%al
  jnz     seta20.2

  movb    $0xdf,%al               # 0xdf -> port 0x60
  outb    %al,$0x60

  # Switch from real to protected mode.  Use a bootstrap GDT that makes
  # virtual addresses map directly to physical addresses so that the
  # effective memory map doesn't change during the transition.
  #进入保护模式以后不能按照cs:ip去算取指令的地址或者说是跳转的地址计算方法变了

  #例如下边的 ljmp    $(SEG_KCODE<<3), $start32调整指令

  #在实模式下：跳到$(SEG_KCODE<<3)×16+$start32的地址去运行

  #在保护模式下：要根据gdtdesc表去找到第$(SEG_KCODE<<3)个48位的段基址然后去该地址运行。

  lgdt    gdtdesc

  movl    %cr0, %eax
  orl     $CR0_PE, %eax   
  movl    %eax, %cr0

  #PAGEBREAK!
  # Complete transition to 32-bit protected mode by using long jmp
  # to reload %cs and %eip.  The segment descriptors are set up with no
  # translation, so that the mapping is still the identity mapping.<pre name="code" class="cpp"> 

  # 前面描述了一下这条指令的意思，同时这条指令也是真正的从实模式转变到保护模式。

<pre name="code" class="cpp">  ljmp    $(SEG_KCODE<<3), $start32

.code32  # Tell assembler to generate 32-bit code now.
start32:
  # Set up the protected-mode data segment registers
  movw    $(SEG_KDATA<<3), %ax    # Our data segment selector
  movw    %ax, %ds                # -> DS: Data Segment
  movw    %ax, %es                # -> ES: Extra Segment
  movw    %ax, %ss                # -> SS: Stack Segment
  movw    $0, %ax                 # Zero segments not ready for use
  movw    %ax, %fs                # -> FS
  movw    %ax, %gs                # -> GS

  # Set up the stack pointer and call into C.
  movl    $start, %esp
  call    bootmain

  # If bootmain returns (it shouldn't), trigger a Bochs
  # breakpoint if running under Bochs, then loop.
  movw    $0x8a00, %ax            # 0x8a00 -> port 0x8a00
  movw    %ax, %dx
  outw    %ax, %dx
  movw    $0x8ae0, %ax            # 0x8ae0 -> port 0x8a00
  outw    %ax, %dx
spin:
  jmp     spin

#这里就是前面的全局段描述表，这里只有3个，第0项都是0x000000000000,后边还有第1项，第2项。

<pre name="code" class="cpp"># Bootstrap GDT
.p2align 2                                # force 4 byte alignment
gdt:
  SEG_NULLASM                             # null seg
  SEG_ASM(STA_X|STA_R, 0x0, 0xffffffff)   # code seg
  SEG_ASM(STA_W, 0x0, 0xffffffff)         # data seg
               #0x2
gdtdesc:
  .word   (gdtdesc - gdt - 1)             # sizeof(gdt) - 1
  .long   gdt                             # address gdt

          似乎X86相关的BIOS都是把软盘里边的第0磁面0磁道1扇区的512B程序加载到0x7c00处，使用INT 0x19中断可以实现将第0磁面0磁道1扇区的512B程序加载到0x7c00处。