汇编语言程序设计——打印水仙花数

最新推荐文章于 2023-08-20 10:56:38 发布
最新推荐文章于 2023-08-20 10:56:38 发布
阅读量2.1k 收藏 21
点赞数 2
分类专栏： 汇编语言 文章标签： 王爽汇编 ms-dos 杨季文 《80x86汇编语言程序设计教程》 汇编 8086 汇编语言 王爽 汇编语言 王爽汇编语言 汇编入门
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/WZZ_2363173126/article/details/107207738
版权

实验目的

       在对80x86系列编程结构和指令系统有了较深入的理解、已掌握了汇编语言程序设计的基本方法和技巧、熟悉了汇编语言程序的设计环境并掌握了汇编语言程序的调试方法的基础上，进一步理解和掌握较复杂程序的设计方法，掌握子程序结构、宏指令的设计和友好用户界面的设计。

实验任务

       采用DOSBox模拟Intel 8086（16位）处理器，使用汇编语言编写16位程序，完成以下实验程序设计任务及要求：

  • 使用键盘输入一个整数n（100≤n≤999）；
  • 将小于等于n的水仙花数打印出来；

水仙花数（Narcissistic number）也被称为超完全数字不变数（pluperfect digital invariant, PPDI）、自恋数、自幂数、阿姆斯壮数或阿姆斯特朗数（Armstrong number）。水仙花数是指一个 3 位数，它的每个位上的数字的 3次幂之和等于它本身。

  • 程序采用子程序结构或宏指令，结构清晰；
  • 友好清晰的用户界面，能识别输入错误并控制错误的修改。

程序设计说明与描述

功能简述

       启动程序，用户可以输入一个三位数，若输入有误则提示错误，并提示重新输入；若输入正确，系统将显示出所有大于等于100，并且小于等于该输入数字的水仙花数。
       此后，程序提示是否继续。若用户输入’y’或’Y’，则系统回到最开始的状态；若输入’n’或’N’,则退出系统；若输入其他则提示错误，并提示重新输入。

程序流程图

程序流程图

数据段设计

       设计了BUFFER_TRANSFORM、OUTPUT1~ OUTPUT7、BUFFER数据段、RESULT共计11个数据段。这些数据段存储的数据的含义如下：

  • BUFF_TRANSFORM：存储数字的每一位的ASCII码（存储数字转换成的字符串）。在判断是否是水仙花数时，用于临时存储该数字的每一位数字的ASCII码；在输出水仙花数时，用于临时存储该数字的每一位数字的ASCII码。
  • OUTPUT1：存储输入数字的提示。
  • OUTPUT2：存储输入错误的提示。
  • OUTPUT3：存储是否继续的提示。
  • OUTPUT4：存储输出水仙花数（Narcissistic Number）的提示。
  • OUTPUT5：存储未找到水仙花数的提示。
  • OUTPUT6：存储程序结束的提示。
  • OUTPUT7：存储空格。
  • OUTPUT8：存储回车换行符。
  • BUFFER：设置输入字符串长度为4，存储输入的字符串长度，存储输入信息。
  • RESULT：存储计算结果。
DATA	SEGMENT
	;存储数字的每一位的ASCII码（存储数字转换成的字符串）
	BUFFER_TRANSFORM	DB 0,0,0,'$'
	OUTPUT1	DB	"Please input a number (100<=number<=999):",'$'		;存储输入数字的提示
	OUTPUT2	DB	"Input error , please input again ! ",0AH,0DH,'$'	;存储输入错误的提示
	OUTPUT3	DB	"Do you want to continue (y/n) ? ",'$'				;存储是否继续的提示
	OUTPUT4 DB	"Narcissistic Number: ",'$'							;存储输出水仙花数（Narcissistic Number）的提示
	OUTPUT5 DB	"Not Found!",'$'									;存储未找到水仙花数的提示
	OUTPUT6	DB	"Press any key to continue ! ",0AH,0DH,'$'			;存储程序结束的提示
	OUTPUT7	DB	' ','$'				;存储空格
	OUTPUT8	DB	0AH,0DH,'$'			;存储回车换行符
	BUFFER	DB	4,0,4 DUP (0)		;设置输入字符串长度为4，存储输入的字符串长度，存储输入信息
	RESULT	DW	4 DUP (0)			;存储计算结果
DATA	ENDS

子程序设计与描述

  • 子程序名称：CHANGE_LINE
    子程序功能：输出回车换行。
    子程序参数：无。
  • 子程序名称：OUTPUT_ERROR_INFO
    子程序功能：输出错误提示。
    子程序参数：无。
  • 子程序名称：DTOC
    子程序功能：将数字转化为十进制字符串。
    子程序参数：获取AX每一位的值，转换成ASSCII码，存入BUFFER_TRANSFORM。
  • 子程序名称：CHECK_Narcissistic_Number
    子程序功能：判断数字是否为水仙花数。
    子程序参数：判断AX是否为水仙花数。若该数是水仙花数，CX=0；若该数不是水仙花数，CX≠0。
  • 子程序名称：WRITE
    子程序功能：将水仙花数写入RESULT区。
    子程序参数：将水仙花数AX写入RESULT区，DI加二。

源程序代码

ASSUME	CS:CODE,DS:DATA,SS:STACK
DATA	SEGMENT
	;存储数字的每一位的ASCII码（存储数字转换成的字符串）
	BUFFER_TRANSFORM	DB 0,0,0,'$'
	OUTPUT1	DB	"Please input a number (100<=number<=999):",'$'		;存储输入数字的提示
	OUTPUT2	DB	"Input error , please input again ! ",0AH,0DH,'$'	;存储输入错误的提示
	OUTPUT3	DB	"Do you want to continue (y/n) ? ",'$'				;存储是否继续的提示
	OUTPUT4 DB	"Narcissistic Number: ",'$'							;存储输出水仙花数（Narcissistic Number）的提示
	OUTPUT5 DB	"Not Found!",'$'									;存储未找到水仙花数的提示
	OUTPUT6	DB	"Press any key to continue ! ",0AH,0DH,'$'			;存储程序结束的提示
	OUTPUT7	DB	' ','$'				;存储空格
	OUTPUT8	DB	0AH,0DH,'$'			;存储回车换行符
	BUFFER	DB	4,0,4 DUP (0)		;设置输入字符串长度为4，存储输入的字符串长度，存储输入信息
	RESULT	DW	4 DUP (0)			;存储计算结果
DATA	ENDS

STACK	SEGMENT
	DW	8	DUP	(0)
STACK	ENDS

CODE	SEGMENT

START:
	MOV	AX,DATA						;初始化
	MOV	DS,AX
	
	MOV	AX,STACK					;建栈
	MOV	SS,AX
	MOV	SP,16
	
	MOV DI,0
	MOV CX,4
CLEAR_RESULT:						;清除由上一个输入计算出来的水仙花数
	MOV	WORD PTR [RESULT+DI],0
	ADD DI,2
	LOOP CLEAR_RESULT
	
INPUT:								;输入数字
	MOV	AH,09H						;显示提示
	MOV	DX,OFFSET OUTPUT1
	INT	21H
	
	MOV	AH,0AH						;获取输入的字符串
	MOV	DX,OFFSET BUFFER
	INT	21H
	CALL CHANGE_LINE
	
	MOV	AL,[BUFFER+1]				;检查字符串长度
	MOV	AH,0
	CMP	AX,3
	JE	CHECK_NUM					;若长度为3，检查每一个字符是否在范围内
	
INPUT_ERROR_1:						;输入错误
	CALL OUTPUT_ERROR_INFO			;输出输入错误提示
	JMP	INPUT						;返回，重新输入
	
CHECK_NUM:							;检查输入的每一位字符的ASCII码是否符合要求（是否是符合要求的数字）
	CMP	BYTE PTR [BUFFER+2],'0'		;检查第一位字符
	JBE	INPUT_ERROR_1				;小于等于'0'，输入错误
	CMP	BYTE PTR [BUFFER+2],'9'
	JA	INPUT_ERROR_1				;大于'9'，输入错误
	
	CMP	BYTE PTR [BUFFER+3],'0'		;检查第二位字符
	JB	INPUT_ERROR_1				;小于'0'，输入错误
	CMP	BYTE PTR [BUFFER+3],'9'
	JA	INPUT_ERROR_1				;大于'9'，输入错误
	
	CMP	BYTE PTR [BUFFER+4],'0'		;检查第三位字符
	JB	INPUT_ERROR_1				;小于'0'，输入错误
	CMP	BYTE PTR [BUFFER+4],'9'
	JA	INPUT_ERROR_1				;大于'9'，输入错误
	
	;将输入的数计算出来，放入DX
	MOV	AL,[BUFFER+2]
	SUB	AL,30H						;计算出百位上的数字
	MOV	BL,100
	MUL	BL							;乘以100
	
	MOV	DX,AX						;百位乘以100的结果存储到DX
	
	MOV	AL,[BUFFER+3]
	SUB	AL,30H						;计算出百位上的数字
	MOV	BL,10
	MUL	BL							;乘以10
	
	ADD DX,AX						;DX加上十位乘以10的结果
	
	MOV	AL,[BUFFER+4]				;计算出百位上的数字
	SUB	AL,30H
	MOV	AH,0
	
	ADD	DX,AX						;DX加上个位，得到输入的数
	MOV	AX,DX						;将输入的数据存储到AX
	
	MOV	DI,0
LOOP_CHECK_Narcissistic_Number:
	CALL CHECK_Narcissistic_Number	;检查AX是否为水仙花数
	CMP CX,0
	JNE	NEXT						;若CX≠0，则该数不是水仙花数，检查AX-1是否为水仙花数
	CALL WRITE						;若CX=0，则该数是水仙花数，记下该水仙花数
NEXT:
	DEC	AX							;AX自减
	
	CMP	AX,100						;若AX>=100，继续循环
	JAE	LOOP_CHECK_Narcissistic_Number
	
	MOV	AH,09H						;输出水仙花数提示
	MOV	DX,OFFSET OUTPUT4
	INT	21H
	
	CMP WORD PTR [RESULT],0
	JNE FOUND						;若第一个结果不等于0，则找到了水仙花数
	
	MOV	AH,09H						;输出未找到水仙花数的提示
	MOV	DX,OFFSET OUTPUT5
	INT	21H

	
FOUND:
	MOV	CX,4
	MOV	DI,0						;DI：输出寻址控制
SHOW_NUM:							;将记下水仙花数输出
	MOV	AX,[RESULT+DI]
	ADD	DI,2
	CMP	AX,0
	JE	END_SHOW_NUM				;若该数为0，结束输出
	CALL DTOC						;将水仙花数的每一位变成ASCII码放入BUFFER_TRANSFORM
	
	MOV	AH,09H						;输出该水仙花数（ASCII码）
	MOV	DX,OFFSET BUFFER_TRANSFORM
	INT	21H
	
	MOV	AH,09H						;输出空格
	MOV	DX,OFFSET OUTPUT7
	INT	21H
	
	LOOP SHOW_NUM					;循环输出
	
END_SHOW_NUM:
	CALL CHANGE_LINE
	
AGAIN:
	MOV	AH,09H						;输出是否继续提示
	MOV	DX,OFFSET OUTPUT3
	INT	21H
	
	MOV	AH,1						;获取输入的字符
	INT	21H
	CALL CHANGE_LINE
	
	CMP	AL,'n'
	JE	END_PROGRAM					;输入'n'，程序结束
	CMP	AL,'N'
	JE	END_PROGRAM					;输入'N'，程序结束
	CMP	AL,'y'
	JE	BACK						;输入'y'，程序继续
	CMP	AL,'Y'						;输入'y'，程序继续
	JNE	INPUT_ERROR_2
	
BACK:								;返回程序开始部分，程序继续
	JMP	FAR	PTR	START				;跳转回（JMP FAR）程序开始部分

INPUT_ERROR_2:						;输入错误
	CALL OUTPUT_ERROR_INFO			;输出输入错误提示
	JMP	AGAIN						;返回，重新输入
	
END_PROGRAM:
	MOV	AH,09H						;输出程序结束提示
	MOV	DX,OFFSET OUTPUT6
	INT	21H
	
	MOV	AX,4C00H
	INT	21H

;名称：CHANGE_LINE
;功能：输出回车换行
;参数：无
CHANGE_LINE:
	MOV	AH,09H
	MOV	DX,OFFSET OUTPUT8
	INT	21H
	RET

;名称：OUTPUT_ERROR_INFO
;功能：输出错误提示
;参数：无
OUTPUT_ERROR_INFO:
	MOV	AH,09H
	MOV	DX,OFFSET OUTPUT2
	INT	21H
	RET

;名称：DTOC
;功能：将数字转化为十进制字符串
;参数：获取AX每一位的值，转换成ASSCII码，存入BUFFER_TRANSFORM
DTOC:
	MOV	SI,2
	MOV	CX,3
	MOV	BL,10
GET_NUM:							;获取该数每一位的值，转换成ASSCII码，存入BUFFER_TRANSFORM
	DIV	BL	
	ADD	AH,30H
	MOV	[BUFFER_TRANSFORM+SI],AH
	MOV	AH,0
	DEC	SI
	LOOP GET_NUM
	
	RET

;名称：CHECK_Narcissistic_Number
;功能：判断数字是否为水仙花数
;参数：判断AX是否为水仙花数
;返回：若该数是水仙花数，返回CX≠0；若该数不是水仙花数，返回CX=0
CHECK_Narcissistic_Number:
	PUSH AX							;保护数据
	CALL DTOC						;计算AX每一位的数字
	
	MOV	CX,3
	MOV	DX,0
	MOV	SI,0
ADD_NUM:							;计算每一位的立方和
	MOV	AL,[BUFFER_TRANSFORM+SI]
	SUB AL,30H
	MOV	AH,0
	MOV	BL,AL
	MUL	BL
	MUL	BL
	ADD DX,AX
	INC	SI
	LOOP ADD_NUM
	
	POP	AX							;恢复数据
	MOV	CX,AX
	SUB CX,DX						;原数与计算结果相减，若该数是水仙花数，CX=0；若该数不是水仙花数，CX≠0
	RET

;名称：WRITE
;功能：将水仙花数写入RESULT区
;参数：将水仙花数AX写入RESULT区，DI加二
WRITE:
	MOV	[RESULT+DI],AX
	ADD	DI,2
	RET

CODE	ENDS
	END	START

文章推荐

博客：汇编语言程序设计（第三版，王爽著）实验

参考文献

[1]王爽.汇编语言程序设计（第三版）, 北京：清华大学出版社,2013.
[2]钱晓捷.汇编语言程序设计（第五版），北京：电子工业出版社，2018
[3]王元珍，曹忠升，韩宗芬.80x86汇编语言程序设计，湖北：华中科技大学出版社，2005

Dennis F
关注
  • 2
    点赞
  • 踩
  • 21
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
汇编水仙花数
01-13
进一步理解和掌握较复杂程序的设计方法，掌握子程序结构的设计和友好用户界面的 设计。具体的设计任务及要求： 1） 输入一个大整数 n； 2） 将小于 n 的水仙花数打印出来（各位数字的立方和等于该数本身）； 3） 程序采用子程序结构，结构清晰； 4） 友好清晰的用户界面，能识别输入错误并控制错误的修改。 在完成设计任务后，按要求撰写课程设计说明书；对课程设计说明书的具体要求请见 课程设计指导书。 阅读资料： 1）《IBM—PC 汇编语言程序设计实验教程》实验 2.4 2）《IBM—PC 汇编语言程序设计（第 2 版）》例 6.11
打印“水仙花数”
weixin_44906102的博客
01-05 263
打印1~100000的水仙花数
打印出所有“水仙花数”
weixin_62757251的博客
05-05 6818
要求： 编写程序，打印出所有“水仙花数”。所谓“水仙花数”是指一个三位数，其各位数字的立方之和正好等于该数本身。例如：153是一个“水仙花数”，因为153=13+53+33。 代码 #include<stdio.h> int main() { int z=0,x=0,c=0,i; for(i=100;i<1000;++i) { z=i/100; x=i%100/10; c=i
【C语言学习————打印水仙花数】
2302_76390850的博客
05-17 1248
水仙花数（Narcissistic number）是指一个n位数 (n≥3)，它的每个位上的数字的n次幂之和等于它本身。例如153就是一个水仙花数，因为153=1^3+5^3+3^3。水仙花数是自恋数（Self number）的一种，是数字计算中的一种有趣现象。一、二、
【C语言】打印所有的“水仙花数”
clumsy01的博客
12-21 1977
水仙花数（Narcissistic number）也被称为超完全数字不变数（pluperfect digital invariant, PPDI）、自恋数、自幂数、阿姆斯壮数或阿姆斯特朗数（Armstrong number），水仙花数是指一个 3 位数，它的每个位上的数字的 3次幂之和等于它本身。 代码如下 #include<stdio.h> #include<math.h> int judge(int x) { int n1,n2,n3,sum...
汇编语言课程实验（水仙花数）
06-01
这个“汇编语言课程实验（水仙花数）”很可能是华中科技大学一门课程的教学实践项目，旨在让学生通过编写汇编语言程序来理解和计算水仙花数，从而深入学习汇编语言的基础知识和实际应用。 在实验中，学生可能会学到...
华科汇编语言水仙花数.doc
06-27
本资源是华中科技大学《汇编语言程序设计》课程设计的一部分，要求学生设计一个程序，输入一个三位整数 n，打印出小于 n 的水仙花数，并且设计一个友好用户界面，能识别输入错误并控制错误的修改。 华科网安汇编...
水仙花数c语言程序.docx
最新发布
10-31
本程序是用 C 语言编写，用于寻找并打印出 100 到 999 范围内的所有水仙花数。 首先，程序包含了 `<stdio.h>` 头文件，这是 C 语言标准输入输出库，提供了 `printf` 和 `scanf` 等基本的输入输出函数。 `main` ...
Python语言生成水仙花数代码示例
01-20
本文将通过Python代码实现打印水仙花数，具体如下： #水仙花数 #narcissistic number #水仙花数是指一个 n 位数 ( n≥3 )，它的每个位上的数字的 n 次幂之和等于它本身。 #（例如：1^3 + 5^3+ 3^3 = 153） import ...
tf2_ros::buffer.transform
qq_34160473的博客
05-19 2691
不见源码navigation-stack里面的tf_.transform(robot_pose, global_pose, costmap->getGlobalFrameID());很容易让人误解。 实际上这是一个模版类，类中是这样的tf2::doTransform(in, out, lookupTransform(target_frame, tf2::getFrameId(in), tf2::getTimestamp(in), timeout)); 即tf_.transform只是拿到了robot_
C语言打印所有“水仙花数”
大白兔奶糖
11-06 7499
C语言打印所有“水仙花数”
基于汇编语言的打印水仙花数
毕业作品网站
09-09 554
进一步理解和掌握较复杂程序的设计方法，掌握子程序结构的设计和友好用户界面的设计。具体的设计任务及要求：输入一个三位整数n；将小于n的水仙花数打印出来（各位数字的立方和等于该数本身）；程序要有子程序结构或宏指令，结构清晰；友好清晰的用户界面，能识别输入错误并控制错误的修改。两种方法实现：计算法、查表法。
【C语言编程】打印所有的“水仙花数”
热门推荐
大舟舟的博客
08-14 5万+
打印所有“水仙花数” 所谓“水仙花数”，是指一个三位数，其各位数字立方和等于该数本身。 例如，153是一个水仙花数，因为153=1的立方+ 5的立方+ 3的立方。 方法一：使用do…while语句 #include <stdio.h> #include <math.h> int main(int argc,char **argv) { int num=100,a,b,c; do { //首先将三位数的各位提取出来// a=num/100; //百
【C语言】--打印出所有的“水仙花数”
小人物，大梦想！
08-20 3014
程序分析：判断一个三位数是不是水仙花数，只需要把其百位，十位和个位的数字分离出来，然后判断其各位数字立方和是否等于该数本身。本题关键是把百位，十位和个位的数字分离，然后利用循环语句和条件判断语句进行查找和判断即可。
JAVA语言：打印出 所有”水仙花数“。
yun_blog的博客
09-09 3764
public class test2 { public static void main(String[] args) { int sum,a,b,c; int m=100; while(m<1000){ a=m/100;//取出个位上的值 b=m%100/10;//取出十位数的值 c= m %10;//取出百位数的值 sum=a*a*a+b*b*b+c*c*c;
汇编实现寻找水仙花数，并保存在存储器中（分布实现版）
x land的博客
03-06 1077
观前提醒，以下内容基于Cortex M4的STM32F407进行 代码使用keil进行仿真实现 任务：寻找1000以内的水仙花数，保存在存储器中 首先我们需要知道水仙花数是怎样计算出来的，先写出高级代码，然后转换成相应的汇编。 水仙花数是指一个 3 位数，它的每个位上的数字的 3次幂之和等于它本身。例如：1^3 + 5^3+ 3^3 = 153。 那么c语言层面如何进行实现，以下为实现代码： void is_Narcissistic(int a){ int sum = 0; //依次获取各位数 .
汇编求水仙花数
qq_43622870的博客
02-21 667
汇编求水仙花数 显示所有3位数的水仙花数（各位数字的立方和等于自身）。对于每一个水仙花数占一行输出。 include io.inc .model small .stack .data A_100 db 0;百位数 A_10 db 0;十位数 A_1 db 0;个位数 B_100 dw 0;百位数立方 B_10 dw 0;十位数立方 B_1 dw 0;个位数立方 .code .startup mov cx,100 next1:
8086 汇编 寻找并输出水仙花数
天天开心
12-30 2681
注：水仙花数指的是每一个十进制位的立方加起来等于他自身的三位数，水仙花数本身就是三位数- -范围100-999，可以遍历来做 之前想的是每一位的数在1-9之间选，再通过每位分别乘以100,10,1转化再与自身比较，如果可以循环多但是代码少效率高，可是不太会写， 下面是遍历100-999的数，看是否满足水仙花数条件，输出水仙花数 注意循环嵌套时一些变量初始值的改变，如这里
80X86汇编语言课程设计报告-打印水仙花数（含代码）
野心家-Andy的博客
02-07 2852
课程设计任务书学生姓名：           专业班级：             指导教师：           工作单位：             题目: 打印水仙花数初始条件：理论：完成了《汇编语言程序设计》课程，对80X86系列编程结构和指令系统有了较深入的理解，已掌握了汇编语言程序设计的基本方法和技巧。实践：完成了《汇编语言程序设计》的基本实验，熟悉了汇编语言程序的设计环境并掌握了汇编语言...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值