Lisp.定义函数

多数人通过defun来学习怎样定义函数。下面的表达式定义了一个叫做double的函数，这个函数返回它参数的两倍。

[1]> (defun double (x) (* x 2))
DOUBLE

将这些传递给Lisp之后，我们可以在其它函数中调用double，或者直接在最高层调用：

[2]> (double 1)
2

一个Lisp代码文件通常是由这样的defun来组成的，非常像C或者Pascal中的过程定义文件。但是一些非常不同的事情正在发生。那些defun不仅仅是过程定义，它们是Lisp调用。当我们探究defun内部发生的事情时，这个不同会变得明朗起来。

函数本身就是对象。defun真正做的就是将它存储在作为第一个参数传递过来的函数名下。所以我们既能够调用double，我们也可以获得实现它的函数。通常我们通过使用#'操作符来做这事。这个操作符可以被理解为将名字映射到真正的函数对象。通过将它放到double的前面

[2]> #'double 
#<FUNCTION DOUBLE (X) (DECLARE (SYSTEM::IN-DEFUN DOUBLE))
  (BLOCK DOUBLE (* X 2))>
[3]> 

我们获得了上面定义的真实的对象。这个的打印输出可能由于不同的实现而不同，一个common lisp函数是一级对象，它和熟悉的像是数字、字符串有相同的特征。所以我们可以将这个函数作为参数，返回它，将它存储在数据结构里等等。

[4]> (eq #'double (car (list #'double )))
T

我们甚至可以不用defun来定义函数。像是多数的Lisp对象，我们可以从字面上引用它们。当我们想要引用一个整形数，我就使用证书自身。要表示一个字符串，我们使用双引号包含着的一系列字符。要表示一个函数，我们使用叫做lambda表达式的东西。一个lambda表达式是个由三个部分组成的列表：符号lambda，一个参数列表，0个或者多个表达式。下面的这个lambda表达式和double是等价的：

[5]> (lambda (x) (* x 2))
#<FUNCTION :LAMBDA (X) (* X 2)>

它描述了一个接受参数x并返回2x的函数。

一个lambda表达式也可以被看作是函数的名字。通过将井号单引号防盗lambda表达式之前，我们得到对应的函数：

[6]> #'(lambda (x) (* x 2))
#<FUNCTION :LAMBDA (X) (* X 2)>

这个函数的行为和double是一样的，但是是两个不同的对象。

在一个函数调用中，函数的名称首先出现，然后是参数们：

[7]> (double 3)
6

既然lambda表达式也是函数的名字，那么它们也能够在函数调用中首先出现：

[8]> ((lambda (x) (* x 2)) 3)
6

在common lisp中，我们可以同时拥有函数double和变量double。

[9]> (setq double 2)
2
[10]> (double double)
4

当一个名字出现在函数调用第一个时，或者是前面有井号单引号时，它被看作是引用一个函数。否则的话，它就被当作变量名对待。

也就是说，common lisp中对于变量名和函数有不同的名字空间。我们可以有一个叫做foo的变量，和一个叫做foo的函数，不用标明它们。这种情况可能会引起混乱，并且导致大量丑陋的代码，但是这也是common lisp程序员必须适应的东西。

如果需要的话，common lisp提供了两个函数，将符号映射到它们所代表的值或者函数。函数symbol-value接受一个符号并返回对应变量的值：

[11]> (symbol-value 'double)
2

而symbol-function对于全局定义的函数做了同样工作：

[12]> (symbol-function 'double)
#<FUNCTION DOUBLE (X) (DECLARE (SYSTEM::IN-DEFUN DOUBLE))
  (BLOCK DOUBLE (* X 2))>

注意，既然函数是普通的数据对象，一个变量也可以用函数作为它的值：

[13]> (setq x #'append)
#<SYSTEM-FUNCTION APPEND>
[14]> (eq (symbol-value 'x) (symbol-function 'append))
T

表象之下，defun做的是将它第一个参数的symbol-function设置到剩余部分所组成的一个函数上。下面两个表达式做了同样的事情：

[15]> (defun double (x) (* x 2))
DOUBLE
[16]> (setf (symbol-function 'double) #'(lambda (x) (* x 2)))
#<FUNCTION :LAMBDA (X) (* X 2)>
[17]> 

所以defun和其它语言中的过程定义有一样的效果——将名字和一段代码关联起来。但是底层的机制是不同的。我们不需要defun来定义函数，函数也不一定要作为值存储在某些符号下面。defun的内部，类似于任何其它语言的过程定义，是一个更加泛化的机制：创建一个函数，将它与某个名字关联起来是两个独立的操作。当我们不需要Lisp的函数概念的完整的泛性时，defun使得函数定义像在其它更加严格的语言中一样简单。