SqlServer中的多种分页方法

 /*
以下包含SqlServer中的多种分页方法
*/

--1.利用ROW_NUMBER() OVER(order by 字段名) 分页方式
select * from
(
select ROW_NUMBER() OVER (ORDER BY pkid) AS RowNumberpkid,*
from et_order
)
as myResults
where RowNumberpkid between 1 and 10

--2.利用Not In和SELECT TOP 分页方式
select top 10 * from et_order where pkid not in
(select top 0 pkid from  et_order order by pkid)
order by pkid

--3.利用ID大于多少和SELECT TOP 分页方式
SELECT TOP 10 *
 FROM et_order
 WHERE (pkid >
           (SELECT MAX(pkid)
          FROM (SELECT TOP 10 pkid
                  FROM et_order
                  order by pkid ) AS T))
 order by pkid

--4.利用SQL的游标存储过程 分页方式
create  procedure SqlPager
 @sqlstr nvarchar(4000), --查询字符串
 @currentpage int, --第N页
 @pagesize int --每页行数
 as
 set nocount on
 declare @P1 int, --P1是游标的id
  @rowcount int
 exec sp_cursoropen @P1 output,@sqlstr,@scrollopt=1,@ccopt=1,@rowcount=@rowcount output
 select ceiling(1.0*@rowcount/@pagesize) as 总页数--,@rowcount as 总行数,@currentpage as 当前页
 set @currentpage=(@currentpage-1)*@pagesize+1
 exec sp_cursorfetch @P1,16,@currentpage,@pagesize
 exec sp_cursorclose @P1
 set nocount off

exec SqlPager 'select * from et_order',1,10
drop procedure SqlPager

--5.利用临时表 分页方式
declare
@PageIndex  int,   --当前是第几页
@PageSize  int,   --每页显示的多少条数据
@PageLowerBound int, --临时表中取数据开始位置
@PageUpperBound int --临时表中取数据结束位置
set @PageIndex=1
set @PageSize=10
set @PageLowerBound = @PageSize * (@PageIndex-1)
set @PageUpperBound = @PageLowerBound + @PageSize + 1
print @PageLowerBound
print @PageUpperBound
create table #result
(
 indexId int identity(1,1) not null,
    rpkid int
)
insert into #result (rpkid) select  pkid from et_order order by pkid

select et.* from et_order et
inner join #result re
on et.pkid = re.rpkid
where
     indexId > @PageLowerBound
and  indexId < @PageUpperBound
--delete  #result
drop table #result