nGrinder实现多接口性能测试

       如果要对多接口进行性能测试，每个接口都需要监控指标，就需要针对每个接口建立测试场景，即@Test注解。

       下文的示例是在Cookie指定的情况下，完成发送feed（类似微博的一种卡片信息）和在feed下回复。发feed生成了feedID，根据feedID去回复。一些敏感信息使用了XXXXX来代替，可以自行修改。

import static net.grinder.script.Grinder.grinder
import static org.junit.Assert.*
import static org.hamcrest.Matchers.*
import net.grinder.plugin.http.HTTPRequest
import net.grinder.plugin.http.HTTPPluginControl
import net.grinder.script.GTest
import net.grinder.script.Grinder
import net.grinder.scriptengine.groovy.junit.GrinderRunner
import net.grinder.scriptengine.groovy.junit.annotation.BeforeProcess
import net.grinder.scriptengine.groovy.junit.annotation.BeforeThread
import org.junit.Before
import org.junit.BeforeClass
import org.junit.Test
import org.junit.runner.RunWith
import java.util.Date
import java.util.List
import java.util.ArrayList
import HTTPClient.Cookie
import HTTPClient.CookieModule
import HTTPClient.HTTPResponse
import HTTPClient.NVPair
import groovy.json.JsonSlurper
import groovy.json.JsonOutput
import org.apache.commons.lang.RandomStringUtils
import net.grinder.scriptengine.groovy.junit.annotation.RunRate

/**
  单用户发feed并回复，写死cookie
  @author anfs2020
 */
@RunWith(GrinderRunner)
class TestRunner {
	public static GTest test1
	public static GTest test2
	public static HTTPRequest request
	public static NVPair[] headers = []
	public static NVPair[] params = []
	public static Cookie[] cookies = []
	public static String fsToken = ''
	public static String feedID,randomNumber

	@BeforeProcess
	public static void beforeProcess() {
		HTTPPluginControl.getConnectionDefaults().timeout = 6000
		//多场景需要定义多个GTest
		test1 = new GTest(1, "sendFeedShare")
		test2 = new GTest(2, "sendFeedReply")
		request = new HTTPRequest()
		//设置header
		List<NVPair> headerList = new ArrayList<>()
		headerList.add(new NVPair("Content-Type", "application/json"))
		headers = headerList.toArray()
		
		//设置cookie
		List<Cookie> cookieList = new ArrayList<>()
		def cookieDate = new Date(32503647599000L)
		def cookieDomain = '.xxx.com'
		def fsAuth = 'xxx'
		fsToken = 'xxx'
		cookieList.add(new Cookie("FSAuthX", fsAuth, cookieDomain, "", cookieDate, false))
		cookieList.add(new Cookie("FSAuthXC", fsAuth, cookieDomain, "", cookieDate, false))
		cookies = cookieList.toArray()
	}

	@BeforeThread 
	public void beforeThread() {
		//注册事件，启动Test，注意参数需要与@Test的方法名一致
		test1.record(this, "test1")
		test2.record(this, "test2")
		grinder.statistics.delayReports=true;
	}

	
	@Before
	public void before() {
		request.setHeaders(headers)
		cookies.each { CookieModule.addCookie(it, HTTPPluginControl.getThreadHTTPClientContext()) }
		randomNumber = RandomStringUtils.randomNumeric(10)
	}
	
	@RunRate(50)
	@Test
	public void test1(){
		//发feed
		sendFeedShare()
	}
	
	@RunRate(50)
	@Test
	public void test2(){
		//回复feed
		sendFeedReply()
	}
	
	public void sendFeedShare(){
		def url = 'https://www.xxx.com/H/Feed/SendFeed' + '?_fs_token=' + fsToken
		def requestString = '{"content":"","circleIDs":[],"employeeIDs":[1002],"isSendReceipt":false,"smsCircleIDs":[],"smsEmployeeIDs":[],"fileInfos":[],"exfileInfos":[],"meeting":null,"isSendSms":false,"vote":null,"flies":[],"contactIDs":[],"ncontactIDs":[],"customerIDs":[],"ncustomerIDs":[],"externalResources":"[]","urlInfo":null,"workOrders":[]}'
		//把String转为json，做参数化
		def parser = new JsonSlurper()
		def requestJson = parser.parseText(requestString)
		//将必要的字段（分享的正文）参数化
		requestJson.content = 'testFeedShare_' + randomNumber
		//把json转为string
		requestString = JsonOutput.toJson(requestJson)
		
		//向服务器发请求
		byte[] body = requestString.getBytes()
		HTTPResponse result = request.POST(url, body, params)
		grinder.logger.info("Request Body is:{}", requestString)
		def response = parser.parseText(result.getText())
		grinder.logger.info("Response is:{}", JsonOutput.toJson(response))
		//获取feedID
		feedID = response.value
		grinder.logger.info("feedID is:{}", feedID)
	}
	
	public void sendFeedReply(){
		def url = 'https://www.xxx.com/FHH/EM1HFEED/Reply/postReply' + '?_fs_token=' + fsToken
		def requestString = '{"feedId":10302,"content":"222","attachments":[],"source":1}'
		//把String转为json，做参数化
		def parser = new JsonSlurper()
		def requestJson = parser.parseText(requestString)
		//将必要的字段参数化
		requestJson.feedId = feedID
		requestJson.content = 'testFeedReply_' + randomNumber
		//把json转为string
		requestString = JsonOutput.toJson(requestJson)
		
		//向服务器发请求
		byte[] body = requestString.getBytes()
		HTTPResponse result = request.POST(url, body, params)
		grinder.logger.info("Request Body is:{}", requestString)
		def response = parser.parseText(result.getText())
		grinder.logger.info("Response is:{}", JsonOutput.toJson(response))
	}
}

    最终运行后的界面如下图：