在上一篇文章中，我们只是将kernel加载到了内存，并没有转到kernel执行。由于，我们后面的kernel是在linux下编译和连接的，是elf文件格式。有关elf文件格式的内容请参考elf文件格式。我们需要先像加载loader一样把kernel加载到内存，然后根据elf文件格式，把kernel中的相应的段加载到内存中的相应的位置，然后，跳到kernel执行。
下面给出loader.asm 和 kernel.asm 的源代码 代码参照了《自己动手写操作系统》
loader.asm
org 0100h
;================================================================================================
BaseOfStack equ 0100h
BaseOfKernelFile equ 08000h ; KERNEL.BIN 被加载到的位置 ---- 段地址
OffsetOfKernelFile equ 0h ; KERNEL.BIN 被加载到的位置 ---- 偏移地址
BaseOfLoader equ 09000h ; LOADER.BIN 被加载到的位置
BaseOfLoaderPhyAddr equ BaseOfLoader * 10h ; LOADER.BIN 被加载到的位置 ---- 物理地址 (= BaseOfLoader * 10h)
BaseOfKernelFilePhyAddr equ BaseOfKernelFile * 10h ;kernel.bin存放的物理地址
;================================================================================================
KernelEntryPointPhyAddr equ 030400h
;kernel的入口地址，即我们要从loader跳往的地址，跳往后，
;控制权便交给kernel了。
;在跳往前我们要将kernel中的段按照elf头的描述复制到内存中的
;相应位置
;注意入口地址030400h是我们在连接时指定的.
;ld -s -Ttext 0x30400 -o kernel.bin kernel.o
jmp LABEL_START ; Start
; FAT12 磁盘的头
; ----------------------------------------------------------------------
BS_OEMName DB 'ForrestY' ; OEM String, 必须 8 个字节
BPB_BytsPerSec DW 512 ; 每扇区字节数
BPB_SecPerClus DB 1 ; 每簇多少扇区
BPB_RsvdSecCnt DW 1 ; Boot 记录占用多少扇区
BPB_NumFATs DB 2 ; 共有多少 FAT 表
BPB_RootEntCnt DW 224 ; 根目录文件数最大值
BPB_TotSec16 DW 2880 ; 逻辑扇区总数
BPB_Media DB 0xF0 ; 媒体描述符
BPB_FATSz16 DW 9 ; 每FAT扇区数
BPB_SecPerTrk DW 18 ; 每磁道扇区数
BPB_NumHeads DW 2 ; 磁头数(面数)
BPB_HiddSec DD 0 ; 隐藏扇区数
BPB_TotSec32 DD 0 ; 如果 wTotalSectorCount 是 0 由这个值记录扇区数
BS_DrvNum DB 0 ; 中断 13 的驱动器号
BS_Reserved1 DB 0 ; 未使用
BS_BootSig DB 29h ; 扩展引导标记 (29h)
BS_VolID DD 0 ; 卷序列号
BS_VolLab DB 'Tinix0.01 '; 卷标, 必须 11 个字节
BS_FileSysType DB 'FAT12 ' ; 文件系统类型, 必须 8个字节
;------------------------------------------------------------------------
; -------------------------------------------------------------------------
; 基于 FAT12 头的一些常量定义，如果头信息改变，下面的常量可能也要做相应改变
; -------------------------------------------------------------------------
FATSz equ 9 ; BPB_FATSz16
RootDirSectors equ 14 ; 根目录占用空间: RootDirSectors = ((BPB_RootEntCnt * 32) + (BPB_BytsPerSec – 1)) / BPB_BytsPerSec; 但如果按照此公式代码过长
SectorNoOfRootDirectory equ 19 ; Root Directory 的第一个扇区号 = BPB_RsvdSecCnt + (BPB_NumFATs * FATSz)
SectorNoOfFAT1 equ 1 ; FAT1 的第一个扇区号 = BPB_RsvdSecCnt
DeltaSectorNo equ 17 ; DeltaSectorNo = BPB_RsvdSecCnt + (BPB_NumFATs * FATSz) - 2
; 文件的开始Sector号 = DirEntry中的开始Sector号 + 根目录占用Sector数目 + DeltaSectorNo
;进入保护模式所需要的
%macro Descriptor 3 ;定义Descriptor结构体宏
dw %2 & 0FFFFh ; 段界限 1 (2 字节)
dw %1 & 0FFFFh ; 段基址 1 (2 字节)
db (%1 >> 16) & 0FFh ; 段基址 2 (1 字节)
dw ((%2 >> 8) & 0F00h) | (%3 & 0F0FFh) ; 属性 1 + 段界限 2 + 属性 2 (2 字节)
db (%1 >> 24) & 0FFh ; 段基址 3 (1 字节)
%endmacro ; 共 8 字节
DA_C EQU 98h ; 只读代码段的属性值
DA_CR EQU 9Ah ; 存在的可执行可读代码段属性值
DA_DRW EQU 92h ; 允许读写的数据段的属性值
DA_32 EQU 4000h ;32位段的属性值
DA_LIMIT_4K EQU 8000h ; 段界限粒度为 4K 字节
PG_P EQU 1 ; 页存在属性位
PG_RWR EQU 0 ; R/W 属性位值, 读/执行
PG_RWW EQU 2 ; R/W 属性位值, 读/写/执行
PG_USS EQU 0 ; U/S 属性位值, 系统级
PG_USU EQU 4 ; U/S 属性位值, 用户级
DA_DPL3 EQU 60h ; DPL = 3
SA_RPL3 EQU 3
CatalogPageTableBase equ 200000h ; 页目录表的基址：2M
PageTableBase equ 201000h ;页表的基址 ：2M+4k
;现在进行第一步：建立GDT表
[SECTION .gdt] ;用于放GDT表的段
;GDT
LABEL_GDT: Descriptor 0,0,0 ;空描述符，当一个任务没有LDT时，会把LDTR清空，这时，LDTR便指向空描述符。
LABEL_DESC_FLAT_C: Descriptor 0, 0fffffh, DA_CR | DA_32 | DA_LIMIT_4K ; 0 ~ 4G
LABEL_DESC_FLAT_RW: Descriptor 0, 0fffffh, DA_DRW | DA_32 | DA_LIMIT_4K ; 0 ~ 4G
LABEL_VIDEO: Descriptor 0B8000h,0ffffh,DA_DRW | DA_DPL3 ;显存的描述符，0b8000h是显存的首地址
;GDT 结束
GdtLenth equ $ - LABEL_GDT ;计算GDT表的长度
GdtPtr dw GdtLenth - 1 ; 准备存入GDTR的信息
dd 0 ; 用于存放GDT表的物理地址，后面会计算
;GDT选择子
SelectorFlatC equ LABEL_DESC_FLAT_C - LABEL_GDT
SelectorFlatRW equ LABEL_DESC_FLAT_RW - LABEL_GDT
SelectorVideo equ LABEL_VIDEO - LABEL_GDT | SA_RPL3 ;显存所在段的选择子
;[SECTION .gdt]结束
LABEL_START: ; <--- 从这里开始 *************
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, BaseOfStack
mov dh, 0 ; "Loading "
call DispStr ; 显示字符串
; 下面在 A 盘的根目录寻找 KERNEL.BIN
mov word [wSectorNo], SectorNoOfRootDirectory
xor ah, ah ; ┓
xor dl, dl ; ┣ 软驱复位
int 13h ; ┛
LABEL_SEARCH_IN_ROOT_DIR_BEGIN:
cmp word [wRootDirSizeForLoop], 0 ; ┓
jz LABEL_NO_KERNELBIN ; ┣ 判断根目录区是不是已经读完, 如果读完表示没有找到 KERNEL.BIN
dec word [wRootDirSizeForLoop] ; ┛
mov ax, BaseOfKernelFile
mov es, ax ; es <- BaseOfKernelFile
mov bx, OffsetOfKernelFile ; bx <- OffsetOfKernelFile 于是, es:bx = BaseOfKernelFile:OffsetOfKernelFile = BaseOfKernelFile * 10h + OffsetOfKernelFile
mov ax, [wSectorNo] ; ax <- Root Directory 中的某 Sector 号
mov cl, 1
call ReadSector
mov si, KernelFileName ; ds:si -> "KERNEL BIN"
mov di, OffsetOfKernelFile ; es:di -> BaseOfKernelFile:???? = BaseOfKernelFile*10h+????
cld
mov dx, 10h
LABEL_SEARCH_FOR_KERNELBIN:
cmp dx, 0 ; ┓
jz LABEL_GOTO_NEXT_SECTOR_IN_ROOT_DIR ; ┣ 循环次数控制, 如果已经读完了一个 Sector, 就跳到下一个 Sector
dec dx ; ┛
mov cx, 11
LABEL_CMP_FILENAME:
cmp cx, 0 ; ┓
jz LABEL_FILENAME_FOUND ; ┣ 循环次数控制, 如果比较了 11 个字符都相等, 表示找到
dec cx ; ┛
lodsb ; ds:si -> al
cmp al, byte [es:di] ; if al == es:di
jz LABEL_GO_ON
jmp LABEL_DIFFERENT
LABEL_GO_ON:
inc di
jmp LABEL_CMP_FILENAME ; 继续循环
LABEL_DIFFERENT:
and di, 0FFE0h ; else┓ 这时di的值不知道是什么, di &= e0 为了让它是 20h 的倍数
add di, 20h ; ┃
mov si, KernelFileName ; ┣ di += 20h 下一个目录条目
jmp LABEL_SEARCH_FOR_KERNELBIN; ┛
LABEL_GOTO_NEXT_SECTOR_IN_ROOT_DIR:
add word [wSectorNo], 1
jmp LABEL_SEARCH_IN_ROOT_DIR_BEGIN
LABEL_NO_KERNELBIN:
mov dh, 2 ; "No KERNEL."
call DispStr ; 显示字符串
%ifdef _LOADER_DEBUG_
mov ax, 4c00h ; ┓
int 21h ; ┛没有找到 KERNEL.BIN, 回到 DOS
%else
jmp $ ; 没有找到 KERNEL.BIN, 死循环在这里
%endif
LABEL_FILENAME_FOUND: ; 找到 KERNEL.BIN 后便来到这里继续
mov ax, RootDirSectors
and di, 0FFF0h ; di -> 当前条目的开始
push eax
mov eax, [es : di + 01Ch] ; ┓
mov dword [dwKernelSize], eax ; ┛保存 KERNEL.BIN 文件大小
pop eax
add di, 01Ah ; di -> 首 Sector
mov cx, word [es:di]
push cx ; 保存此 Sector 在 FAT 中的序号
add cx, ax
add cx, DeltaSectorNo ; 这时 cl 里面是 LOADER.BIN 的起始扇区号 (从 0 开始数的序号)
mov ax, BaseOfKernelFile
mov es, ax ; es <- BaseOfKernelFile
mov bx, OffsetOfKernelFile ; bx <- OffsetOfKernelFile 于是, es:bx = BaseOfKernelFile:OffsetOfKernelFile = BaseOfKernelFile * 10h + OffsetOfKernelFile
mov ax, cx ; ax <- Sector 号
LABEL_GOON_LOADING_FILE:
push ax ; ┓
push bx ; ┃
mov ah, 0Eh ; ┃ 每读一个扇区就在 "Loading " 后面打一个点, 形成这样的效果:
mov al, '.' ; ┃
mov bl, 0Fh ; ┃ Loading ......
int 10h ; ┃
pop bx ; ┃
pop ax ; ┛
mov cl, 1
call ReadSector
pop ax ; 取出此 Sector 在 FAT 中的序号
call GetFATEntry
cmp ax, 0FFFh
jz LABEL_FILE_LOADED
push ax ; 保存 Sector 在 FAT 中的序号
mov dx, RootDirSectors
add ax, dx
add ax, DeltaSectorNo
add bx, [BPB_BytsPerSec]
jmp LABEL_GOON_LOADING_FILE
LABEL_FILE_LOADED:
call KillMotor ; 关闭软驱马达
mov dh, 1 ; "Ready."
call DispStr ; 显示字符串
jmp LABEL_TO_PROTECT ;跳到准备进入保护模式的代码
;============================================================================
;变量
;----------------------------------------------------------------------------
wRootDirSizeForLoop dw RootDirSectors ; Root Directory 占用的扇区数
wSectorNo dw 0 ; 要读取的扇区号
bOdd db 0 ; 奇数还是偶数
dwKernelSize dd 0 ; KERNEL.BIN 文件大小
;============================================================================
;字符串
;----------------------------------------------------------------------------
KernelFileName db "KERNEL BIN", 0 ; KERNEL.BIN 之文件名
; 为简化代码, 下面每个字符串的长度均为 MessageLength
MessageLength equ 9
LoadMessage: db "Loading "
Message1 db "Ready. "
Message2 db "No KERNEL"
;============================================================================
;----------------------------------------------------------------------------
; 函数名: DispStr
;----------------------------------------------------------------------------
; 作用:
; 显示一个字符串, 函数开始时 dh 中应该是字符串序号(0-based)
DispStr:
mov ax, MessageLength
mul dh
add ax, LoadMessage
mov bp, ax ; ┓
mov ax, ds ; ┣ ES:BP = 串地址
mov es, ax ; ┛
mov cx, MessageLength ; CX = 串长度
mov ax, 01301h ; AH = 13, AL = 01h
mov bx, 0007h ; 页号为0(BH = 0) 黑底白字(BL = 07h)
mov dl, 0
add dh, 3 ; 从第 3 行往下显示
int 10h ; int 10h
ret
;----------------------------------------------------------------------------
; 函数名: ReadSector
;----------------------------------------------------------------------------
; 作用:
; 从序号(Directory Entry 中的 Sector 号)为 ax 的的 Sector 开始, 将 cl 个 Sector 读入 es:bx 中
ReadSector:
; -----------------------------------------------------------------------
; 怎样由扇区号求扇区在磁盘中的位置 (扇区号 -> 柱面号, 起始扇区, 磁头号)
; -----------------------------------------------------------------------
; 设扇区号为 x
; ┌ 柱面号 = y >> 1
; x ┌ 商 y ┤
; -------------- => ┤ └ 磁头号 = y & 1
; 每磁道扇区数 │
; └ 余 z => 起始扇区号 = z + 1
push bp
mov bp, sp
sub esp, 2 ; 辟出两个字节的堆栈区域保存要读的扇区数: byte [bp-2]
mov byte [bp-2], cl
push bx ; 保存 bx
mov bl, [BPB_SecPerTrk] ; bl: 除数
div bl ; y 在 al 中, z 在 ah 中
inc ah ; z ++
mov cl, ah ; cl <- 起始扇区号
mov dh, al ; dh <- y
shr al, 1 ; y >> 1 (其实是 y/BPB_NumHeads, 这里BPB_NumHeads=2)
mov ch, al ; ch <- 柱面号
and dh, 1 ; dh & 1 = 磁头号
pop bx ; 恢复 bx
; 至此, "柱面号, 起始扇区, 磁头号" 全部得到 ^^^^^^^^^^^^^^^^^^^^^^^^
mov dl, [BS_DrvNum] ; 驱动器号 (0 表示 A 盘)
.GoOnReading:
mov ah, 2 ; 读
mov al, byte [bp-2] ; 读 al 个扇区
int 13h
jc .GoOnReading ; 如果读取错误 CF 会被置为 1, 这时就不停地读, 直到正确为止
add esp, 2
pop bp
ret
;----------------------------------------------------------------------------
; 函数名: GetFATEntry
;----------------------------------------------------------------------------
; 作用:
; 找到序号为 ax 的 Sector 在 FAT 中的条目, 结果放在 ax 中
; 需要注意的是, 中间需要读 FAT 的扇区到 es:bx 处, 所以函数一开始保存了 es 和 bx
GetFATEntry:
push es
push bx
push ax
mov ax, BaseOfKernelFile ; ┓
sub ax, 0100h ; ┣ 在 BaseOfKernelFile 后面留出 4K 空间用于存放 FAT
mov es, ax ; ┛
pop ax
mov byte [bOdd], 0
mov bx, 3
mul bx ; dx:ax = ax * 3
mov bx, 2
div bx ; dx:ax / 2 ==> ax <- 商, dx <- 余数
cmp dx, 0
jz LABEL_EVEN
mov byte [bOdd], 1
LABEL_EVEN:;偶数
xor dx, dx ; 现在 ax 中是 FATEntry 在 FAT 中的偏移量. 下面来计算 FATEntry 在哪个扇区中(FAT占用不止一个扇区)
mov bx, [BPB_BytsPerSec]
div bx ; dx:ax / BPB_BytsPerSec ==> ax <- 商 (FATEntry 所在的扇区相对于 FAT 来说的扇区号)
; dx <- 余数 (FATEntry 在扇区内的偏移)。
push dx
mov bx, 0 ; bx <- 0 于是, es:bx = (BaseOfKernelFile - 100):00 = (BaseOfKernelFile - 100) * 10h
add ax, SectorNoOfFAT1 ; 此句执行之后的 ax 就是 FATEntry 所在的扇区号
mov cl, 2
call ReadSector ; 读取 FATEntry 所在的扇区, 一次读两个, 避免在边界发生错误, 因为一个 FATEntry 可能跨越两个扇区
pop dx
add bx, dx
mov ax, [es:bx]
cmp byte [bOdd], 1
jnz LABEL_EVEN_2
shr ax, 4
LABEL_EVEN_2:
and ax, 0FFFh
LABEL_GET_FAT_ENRY_OK:
pop bx
pop es
ret
;----------------------------------------------------------------------------
;----------------------------------------------------------------------------
; 函数名: KillMotor
;----------------------------------------------------------------------------
; 作用:
; 关闭软驱马达
KillMotor:
push dx
mov dx, 03F2h
mov al, 0
out dx, al
pop dx
ret
;----------------------------------------------------------------------------
LABEL_TO_PROTECT:
mov ax,cs
mov ds,ax
mov es,ax
mov ss,ax
mov sp,0100h
;计算GDT表的物理地址,将GDT表的物理地址信息存入GdtPtr中
xor eax,eax
mov ax,cs
shl eax,4
add eax,LABEL_GDT
mov dword [GdtPtr + 2],eax
;现在进行第二步：将GDT表的信息加载到GDTR中
lgdt [GdtPtr] ;装载GDTR
;关中断
cli
;现在进行第三步：打开地址线
in al,92h
or al,00000010b
out 92h,al
;现在进行第四步：置PE为1，表示CPU处于保护模式下
mov eax,cr0
or eax,1
mov cr0,eax
;现在进入第五步：跳到保护模式的代码
jmp dword SelectorFlatC:(BaseOfLoaderPhyAddr + LABEL_PROTECT_BEGIN)
;保护模式下的代码
[SECTION .s32]
ALIGN 32
[BITS 32]
LABEL_PROTECT_BEGIN:
mov ax, SelectorVideo
mov gs, ax
mov ax, SelectorFlatRW
mov ds, ax
mov es, ax
mov fs, ax
mov ss, ax
mov esp, TopOfStack
mov edi,(80 * 10 + 0)*2 ;屏幕的第10行，第0列
mov ah,0Ch
mov al,'p'
mov [gs:edi],ax ;将字符‘p’输出到屏幕
call SetupPaging ;启动分页
mov ax,SelectorVideo ;视频选择子,用于找到显存段的描述符
mov gs,ax
mov edi,(80 * 11 + 0)*2 ;屏幕的第10行，第0列
mov ah,0Ch
mov al,'f'
mov [gs:edi],ax ;将字符‘f’输出到屏幕,表示已启动分页
call InitKernel
jmp SelectorFlatC:KernelEntryPointPhyAddr
SetupPaging:
;为简单，这里让线性地址等于物理地址
;初始化页目录表
mov ax,SelectorFlatRW ;将页目录表的选择子放到es中
mov es,ax
mov ecx,1024 ;1024送到cx，表示循环1024次
mov edi, CatalogPageTableBase
xor eax,eax ;ax清零
mov eax,PageTableBase | PG_P | PG_USU | PG_RWW ;将第一个页表的信息（页目录表中的一个项）放到eax中，准备放到页目录表中
s1:
stosd
add eax,4096 ;eax加4096表示下一个页表的地址（一个页表有4096的大小）
loop s1
;初始化页表的信息
mov ax,SelectorFlatRW ;将第一个页表的选择符放到es
mov es,ax
mov edi, PageTableBase ;
mov ecx,1024*1024 ;循环1024*1024次，因为一个目录表有1024个项，每一个项对应一个页表，而每个页表有1024个项，每一个项
;对应一个物理页
xor eax,eax
mov eax,PG_P | PG_USU | PG_RWW
s2:
stosd
add eax,4096 ;每一页有4k的大小
loop s2
mov eax,CatalogPageTableBase ;将页目录表的地址存入cr3中
mov cr3,eax
mov eax,cr0 ;将cr0的最高位置1,表示启动分页
or eax,80000000h
mov cr0,eax
ret
; InitKernel ---------------------------------------------------------------------------------
; 将 KERNEL.BIN 的内容经过整理对齐后放到新的位置
; --------------------------------------------------------------------------------------------
InitKernel:
xor esi,esi
mov cx, word [BaseOfKernelFilePhyAddr + 2ch] ;program Header Table 中条目(program header)的个数送cx
movzx ecx,cx ;无符号扩展
mov esi,[BaseOfKernelFilePhyAddr + 1ch] ;program header table 在文件中的偏移量送esi
add esi,BaseOfKernelFilePhyAddr ;此时，esi中为program header table 的物理地址
.Begin:
mov eax,[esi + 0] ;将program header 描述的段的类型送eax（program header table 的条目就是program header，program header的第一个字节是段的类型 ）
cmp eax,0 ;判断类型是否为空，如果是则表示该program header所描述的段，是不执行的，
jz .NoAction
;memcpy(段要加载到的虚拟地址，段的地址，段在文件中的长度) 将文件中的段复制到指定虚拟地址（在program header中有描述）处
push dword [esi +010h] ;段的长度
mov eax,[esi + 04h] ;段在文件中的偏移
add eax,BaseOfKernelFilePhyAddr ;段在文件中的偏移+文件的地址=段的地址
push eax
push dword [esi + 08h] ;段要加载到的虚拟地址
call MemCpy
add esp,12
.NoAction:
add esi,20h ;esi指向下一个program header
dec ecx ;ecx-1 ,表已读完了一个program header，所以要读的program header数目减1
jnz .Begin ;program header 还没读完，则循环读下一个
ret
; ------------------------------------------------------------------------
; 内存拷贝，仿 memcpy
; ------------------------------------------------------------------------
; void* MemCpy(void* es:pDest, void* ds:pSrc, int iSize);
; ------------------------------------------------------------------------
MemCpy:
push ebp
mov ebp, esp
push esi
push edi
push ecx
mov edi, [ebp + 8] ; Destination
mov esi, [ebp + 12] ; Source
mov ecx, [ebp + 16] ; Counter
.1:
cmp ecx, 0 ; 判断计数器
jz .2 ; 计数器为零时跳出
mov al, [ds:esi] ; ┓
inc esi ; ┃
; ┣ 逐字节移动
mov byte [es:edi], al ; ┃
inc edi ; ┛
dec ecx ; 计数器减一
jmp .1 ; 循环
.2:
mov eax, [ebp + 8] ; 返回值
pop ecx
pop edi
pop esi
mov esp, ebp
pop ebp
ret ; 函数结束，返回
; MemCpy 结束-------------------------------------------------------------
[SECTION .data]
ALIGN 32
LABEL_DATA:
StackSpace: times 1000h db 0
TopOfStack equ BaseOfLoaderPhyAddr + $ ; 栈顶kernel.asm
; 编译链接方法
; [root@XXX XXX]# nasm -f elf kernel.asm -o kernel.o
; [root@XXX XXX]# ld -s -Ttext 0x30400 -o kernel.bin kernel.o
; [root@XXX XXX]#
[section .text] ; 代码在此
global _start ; 导出 _start
_start: ; 跳到这里来的时候，我们假设 gs 指向显存
mov ah, 0Fh ; 0000: 黑底 1111: 白字
mov al, 'K'
mov [gs:((80 * 1 + 39) * 2)], ax ; 屏幕第 1 行, 第 39 列。
jmp $
1.编译loader.asm 即nasm loader.asm -o loader.bin
2.编译kernel.asm 编译方法在源代码的开头部分已给出。对kernel.asm的编译是在linux下（虚拟机中安装的linux）编译的，编译后，可在虚拟机中linux（图形界面下）下，鼠标右击kernel.bin选择复制，然后，可在windows下，点击右击，选择粘贴，就可把在linux下编译连接的kernel.bin复制到windows下。
3.把得到的loader.bin和kernel.bin复制到软盘镜像（已格式化，并且已将boot.bin复制到软盘镜像，如果没有，请参见第26篇文章）中，用虚拟机启动软盘镜像。
运行结果图：
3997
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
