快速切换IP地址

你是否曾经有过这样的经历：经常走访客户或者在办公室和家庭等不同的场所使用笔记本，这些场所都有自己的IP地址、网关、子网掩码等，每换一个场所都需要重新设置IP地址。你不觉得这是一个非常繁琐，令人讨厌的事儿吗？其实你可以不用这么麻烦的，只需要下载一款网络配置切换的软件就可以解决这个问题。那么，你有没有想过自己来搞定这个问题呢？如果你有这个想法，那就打开你的记事本，参考下面的代码，编写自己的网络配置，然后保存为.bat文件，以后就可以使用自己的工具方便地切换网络了。

@echo off
rem 设置变量
set NAME1="本地连接"
set W_NAME1="无线网络连接"

set ADDR1=172.16.87.141
set MASK1=255.255.255.0
set GATEWAY1=172.16.87.224
set DNS11=8.8.8.8
set DNS12=8.8.4.4

set W_ADDR1=192.168.1.133
set W_MASK1=255.255.255.0
set W_GATEWAY1=192.168.1.1
set W_DNS11=218.2.135.1
set W_DNS12=202.102.24.35

rem //以上属性依次为IP地址、子网掩码、网关、首选DNS、备用DNS

echo 当前可用操作有：
echo 1 设置本地连接为静态IP（%ADDR1%）
echo 2 设置本地连接为动态IP
echo 6 设置无线网络连接为静态IP（%W_ADDR1%）
echo 7 设置无线网络连接为动态IP
echo 0 退出
echo 请选择后回车：
set /p operate=
if %operate%==1 goto 1
if %operate%==2 goto 2
if %operate%==6 goto 6
if %operate%==7 goto 7
if %operate%==0 goto 0

:1
echo 正在设置本地连接静态IP，请稍等...
echo IP地址 = %ADDR1%
echo 掩码 = %MASK1%
echo 网关 = %GATEWAY1%
netsh interface ipv4 set address name=%NAME1% source=static addr=%ADDR1% mask=%MASK1% gateway=%GATEWAY1% gwmetric=0 >nul 
echo 首选DNS = %DNS11% 
netsh interface ipv4 set dns name=%NAME1% source=static addr=%DNS11% register=PRIMARY >nul 
echo 备用DNS = %DNS12% 
netsh interface ipv4 add dns name=%NAME1% addr=%DNS12% index=2 >nul 
echo 本地连接静态IP已设置！
pause
goto 0

:2
echo 正在设置本地连接动态IP，请稍等...
echo 正在从DHCP自动获取IP地址...
netsh interface ip set address "本地连接" dhcp
echo 正在从DHCP自动获取DNS地址...
netsh interface ip set dns "本地连接" dhcp 
echo 本地连接动态IP已设置！
pause
goto 0

:6
echo 正在设置无线网络连接静态IP，请稍等...
rem //可以根据你的需要更改 
echo IP地址 = %W_ADDR1%
echo 掩码 = %W_MASK1%
echo 网关 = %W_GATEWAY1%
netsh interface ipv4 set address name=%W_NAME1% source=static addr=%W_ADDR1% mask=%W_MASK1% gateway=%W_GATEWAY1% gwmetric=0 >nul 
echo 首选DNS = %W_DNS11% 
netsh interface ipv4 set dns name=%W_NAME1% source=static addr=%W_DNS11% register=PRIMARY >nul 
echo 备用DNS = %W_DNS12% 
netsh interface ipv4 add dns name=%W_NAME1% addr=%W_DNS12% index=2 >nul 
echo 无线网络连接静态IP已设置！
pause
goto 0

:7
echo 正在设置无线网络连接动态IP，请稍等...
echo 正在从DHCP自动获取IP地址...
netsh interface ip set address "无线网络连接" dhcp
echo 正在从DHCP自动获取DNS地址...
netsh interface ip set dns "无线网络连接" dhcp 
echo 无线网络连接动态IP已设置！
pause
goto 0

:0
exit