S3C2440存储控制器-SDRAM

S3C2440引出27条地址线 ADDR0-ADDR26  访问范围只有128M

CPU对外还引出8跟片选信号nGCS0-nGCS7对应BANK0-BANK7，低电平有效

总共地址空间8*128 = 1G

(JZ2440开发板BANK0-NorFlash  BANK6-SDRAM)

作为32位的CPU 理论上总地址空间应该是4GB，除去1G的外设地址空间外，

还有一部分是CPU内部寄存器的地址（0x48000000-0x5FFFFFFF）剩下的地址空间没有使用。


存储控制器例子： SDRAM
BANK6-SDRAM 起始地址0x30000000 总共64M
.text
.global _start
_start:
    bl  disable_watch_dog               @ 关闭WATCHDOG，否则CPU会不断重启
    bl  memsetup                        @ 设置存储控制器
    bl  copy_steppingstone_to_sdram     @ 复制代码到SDRAM中
    ldr pc, =on_sdram                   @ 跳到SDRAM中继续执行
on_sdram:
    ldr sp, =0x34000000                 @ 设置堆栈
    bl  main
halt_loop:
    b   halt_loop
...
...
...
memsetup:

    @ 设置存储控制器以便使用SDRAM等外设

    mov r1,     #MEM_CTL_BASE       @ 存储控制器的13个寄存器的开始地址
    adrl    r2, mem_cfg_val         @ 这13个值的起始存储地址
    add r3,     r1, #52             @ 13*4 = 54
1:  
    ldr r4,     [r2], #4            @ 读取设置值，并让r2加4
    str r4,     [r1], #4            @ 将此值写入寄存器，并让r1加4
    cmp r1,     r3                  @ 判断是否设置完所有13个寄存器
    bne 1b                           @ 若没有写成，继续  
    mov pc,     lr                  @ 返回
.align 4
mem_cfg_val:
    @ 存储控制器13个寄存器的设置值
    .long   0x22011110      @ BWSCON
    .long   0x00000700      @ BANKCON0
    .long   0x00000700      @ BANKCON1
    .long   0x00000700      @ BANKCON2
    .long   0x00000700      @ BANKCON3  
    .long   0x00000700      @ BANKCON4
    .long   0x00000700      @ BANKCON5
    .long   0x00018005      @ BANKCON6
    .long   0x00018005      @ BANKCON7
    .long   0x008C07A3      @ REFRESH
    .long   0x000000B1      @ BANKSIZE
    .long   0x00000030      @ MRSRB6
    .long   0x00000030      @ MRSRB7

Makefile如下：
sdram.bin : head.S  leds.c
arm-linux-gcc  -c -o head.o head.S
arm-linux-gcc -c -o leds.o leds.c
arm-linux-ld -Ttext 0x30000000 head.o leds.o -o sdram_elf
arm-linux-objcopy -O binary -S sdram_elf sdram.bin
arm-linux-objdump -D -m arm  sdram_elf > sdram.dis
clean:
rm -f   sdram.dis sdram.bin sdram_elf *.o

程序链接地址为0x30000000（SDRAM起始地址）

这段程序烧写在nandflash 上电硬件自动将nandflash前4K代码复制到片内SRAM并执行，

虽然链接地址是0x30000000，但是由于是与位置无关的相对地址 在SRAM上一样可以执行

ldr pc, =on_sdram，将pc赋值为绝对地址 程序跳到SDRAM上执行（SDRAM在前面的代码已初始化完成）


相关指令：

add r3,      r1, #52         @r3=r1+52 13个4字节的寄存器

ldr r4,     [r2], #4            @ 读取设置值，并让r2加4

        str r4,     [r1], #4            @ 将此值写入寄存器，并让r1加4

        bne 1b                           @ bne不相等跳转 ,1b表示往后跳转回1标识符 

                                              @1b的b表示backward，相应的有1f表示forward

.align   4                        @表示下面的13个寄存器值4字节对齐