Delphi控件开发浅入深出 四 五

Delphi控件开发浅入深出（四）

五、复合控件

复合控件是Delphi控件中非常重要的一种控件，复合控件就是将两个或两个以上的控件重新组合成一个新的控件。例如TspinEdit、TlabeledEdit、TDBNavigator等就是复合控件，TDBNavigator其实就是在一个Panel放上若干个Button而已。制作一个复合控件时，我们一般从TwinControl派生控件。

我们这次做的控件是拥有一个Edit编辑框和一个Button按钮的复合控件，在用户在编辑框中输入文字的过程中，Button将随时显示编辑框中文字的长度。我们把控件的源码先展示给大家。

unit EditButton;

interface

uses

  SysUtils, Classes, Controls, StdCtrls, Messages;

type

  TEditButton = class(TWinControl)

  private

    FEdit: TEdit;

    FButton: TButton;

    FText: string;

    procedure FSetText(AValue: string);

    procedure OnEditChange(Sender: TObject);

  protected

    procedure WMSize(var Msg: TMessage);message WM_SIZE;

  public

    constructor Create(AOwner: TComponent);override;

    destructor Destroy;override;

  published

    property Text: string read FText write FSetText;

  end;

procedure Register;

implementation

procedure Register;

begin

  RegisterComponents('Linco', [TEditButton]);

end;

constructor TEditButton.Create(AOwner: TComponent);

begin

  inherited;

  FEdit := TEdit.Create(nil);

  FEdit.Parent := self;

  FEdit.Top := 0;

  FEdit.Left := 0;

  FEdit.Height := Height;

  FEdit.Width := Width div 2;

  FEdit.OnChange := OnEditChange;

  FButton := TButton.Create(nil);

  FButton.Parent := self;

  FButton.Top := 0;

  FButton.Left := Width div 2;

  FButton.Height := Height;

  FButton.Width := Width div 2;

end;

destructor TEditButton.Destroy;

begin

  FEdit.Free;

  FButton.Free;

  inherited;

end;

procedure TEditButton.FSetText(AValue: string);

begin

  FEdit.Text := AValue;

end;

procedure TEditButton.OnEditChange(Sender: TObject);

begin

  FButton.Caption := IntToStr(Length(FEdit.Text));

end;

procedure TEditButton.WMSize(var Msg: TMessage);

begin

  FEdit.Height := Height;

  FEdit.Width := Width div 2;

  FButton.Left := Width div 2;

  FButton.Height := Height;

  FButton.Width := Width div 2;

end;

end.

代码解释：

（1）、我们首先定义了两个变量   

    FEdit: TEdit;

    FButton: TButton;

  分别代表复合控件中的文字编辑框和按钮。

（2）所谓复合控件说简单一点就是在一个共同的基板上将组成复合控件的各个控件（可以叫做子控件）画出来。所以我们在构造函数中建立各个子控件，然后分别设定它们的位置等属性。

以文字编辑框为例：

FEdit := TEdit.Create(nil);

的作用是建立编辑框控件。如果Create的参数指定为nil,则子控件在设计状态是可以响应用户的操作的；而如果设定为self(即设定子控件的父控件为基板)，则子控件在设计时时不可响应用户操作的，如果设定为self则析构函数中就不用Fedit.Free来销毁对象了，对象会自动销毁。

  FEdit.Parent := self;的作用是设定子控件的父控件，如果没有这一句则控件是无法显示的。

  FEdit.Top := 0;

  FEdit.Left := 0;

  FEdit.Height := Height;

  FEdit.Width := Width div 2;

这四句是设定控件在基板上的相对位置的，这里的Top,Left不是相对于窗体的，而是相对于基板的。

  FEdit.OnChange := OnEditChange;

则是设定编辑框控件的OnChange(文字改变事件)的处理句柄为OnEditChange；

（1）    用户有可能在设计时或运行时通过代码改变控件的大小，这时控件中子控件的顺序就会变得乱七八糟，所以需要相应控件的WM_SIZE事件（控件大小发生变化的事件）重新设定子控件的位置，大小等。函数WMSize的作用就是这样的。

安装控件后发现控件已经可以正确运行了，但是还有一个问题，就是这个控件没有了Onclick,Onchange等必须的属性。我们只要为控件增加事件处理句柄属性，然后把事件处理句柄属性的读写方法都指向子控件的事件处理句柄属性即可。例如我们为控件增加OnClick事件，这个事件发生在用户单击按钮时，我么只要在Pulished部分增加如下代码：

property  OnClick:  TnotifyEvent read GetOnClick write SetOnClick

在Private中增加如下方法声明：

function GetOnclick: TnotifyEvent;

procedure SetOnclick(AValue: TnotifyEvent);

这两个方法的实现分别为：

function  TeditButton. GetOnclick: TnotifyEvent;

begin

  result := Fbutton.Onclick;

end;

procedure TeditButton. SetOnclick(AValue: TnotifyEvent);

begin

  Fbutton.OnClick := Avalue;

end;

思考题：

1、做一个模仿播放器中的操作按钮的复合控件，控件由三个按钮组成，分别是“播放”、“暂停”、“停止”，请按照正常的逻辑关系，处理这三个按钮的可用/不可用关系。（提示：可以参考TDBNavigator的源代码）

 

Delphi控件开发浅入深出（五）

六、控件手拉手――控件关联的实现

控件的关联在Delphi中也是很常见的，我们可以设定一个控件的某个属性指向另一个控件。比如我们在窗体上放上Tedit,TpopupMenu两个控件，然后设定Tedit的PopupMenu属性为TpopupMenu控件，运行后在Tedit点击右键就会弹出刚才设定的那个TpopupMenu菜单，也就是说Tedit,TpopupMenu联手完成了任务。再比如TDBEdit控件的DataSource属性就可以指向一个TdataSource控件，这样就可以在TDBEdit控件中显示TdataSource输出的某个字段的值了。

  下面我们将写一个简单的实现控件关联的控件。这个控件派生于Tedit,它可以与一个Tlabel控件关联，在控件的编辑框中输入文字时，与它关联的Tlabel控件的文字将随着它而变化。代码如下：

unit MyEdit;

interface

uses

  SysUtils, Classes, Controls, StdCtrls;

type

  TMyEdit = class(TEdit)

  private

    FLinkLabel: TLabel;

    procedure FSetLinkLabel(AValue: TLabel);

  protected

    procedure Notification(AComponent: TComponent;Operation: TOperation);

          override;

    procedure Change;override;

  public

  published

    property LinkLabel: TLabel read FLinkLabel write FSetLinkLabel;

  end;

procedure Register;

implementation

procedure Register;

begin

  RegisterComponents('Linco', [TMyEdit]);

end;

procedure TMyEdit.Change;

begin

  inherited;

  if LinkLabel <> nil then

    LinkLabel.Caption := Text;

end;

procedure TMyEdit.FSetLinkLabel(AValue: TLabel);

begin

  FLinkLabel := AValue;

  if AValue <> nil then

    FLinkLabel.FreeNotification(self);

end;

procedure TMyEdit.Notification(AComponent: TComponent;

  Operation: TOperation);

begin

  inherited;

  if (Operation = opRemove) and (AComponent = LinkLabel) then

    LinkLabel := nil;

end;

end.

代码解释：

（1）、我们只要将控件的任意一个属性的类型设定为另外一个控件的类名称，那么我们就可以在控件的Object Inspector中将这个属性指向那个控件（或那个控件的派生控件）的一个实例。比如本例中我们增加了LinkLabel属性，它的类型为 Tlabel，所以我们就可以把LinkLabel属性指向一个标签控件。

（2）、请注意FsetLinkLabel中的这段代码：

if AValue <> nil then

FLinkLabel.FreeNotification(self);

如果我们将控件关联属性指向了一个控件，可是后来又将被指向的控件删除了，那么我们的控件关联属性是不会自动删除的，这样就会造成控件关联属性指向的控件不存在的现象。我们必须自动感知被关联控件的删除并重新设定控件关联属性为不指向任何控件，这样就避免了错误的发生。

FLinkLabel.FreeNotification(self);的作用就是这样的。它调用控件的FreeNotification方法（在Tcomponent中定义）向被指向的控件注册一个“消息”，当被指向控件被删除时，会向所有向他注册的控件发送一个它被删除的消息，此时向他注册的控件就会触发Notification方法，这样我们就可以自动感知被指向控件的状态了。这是设计模式中Observer(观察者)模式的典型应用。

既然向他注册的控件就会触发Notification方法，我们就覆盖父类的Notification方法，写出如下的代码：

  if (Operation = opRemove) and (AComponent = LinkLabel) then

    LinkLabel := nil;

这句话的意思是：如果控件被删除并且被删除的控件（因为我们的控件可能向多个控件注册了消息）是LinkLabel，那么我们就设定LinkLabel属性不指向任何控件。

（3）覆盖父类的Change调度方法。在此方法里为连接的LinkLabel的Caption赋值就达到我们的目的了。

思考题：

1、做一个Label控件，给它增加一个DataSource属性，该属性可以指向一个TdataSource类型的控件，它有一个GetRecordCount方法。当调用此方法时，就在Label控件中显示这个DataSource对应的数据集中的记录的条数。