Delphi控件开发浅入深出（四）

我们这个控件将演示控件的自定义事件的书写。这个控件有一个类型为string的SensitiveText属性，当用户在输入框中输入的文字为InvalidText时就会触发OnSensitiveText事件。按照惯例，我先把源码展示给大家：

unit TextSenseEdit;

interface

uses

SysUtils, Classes, Controls, StdCtrls;

type

TSensitiveTextEvent = procedure(AText: string) of object;//方法指针

TTextSenseEdit = class(TEdit)

private

FSensitiveText: string;

FOnSensitiveText: TSensitiveTextEvent;

procedure SetSensitiveText(AValue: string);

protected

procedure Change;override;

public

published

property SensitiveText: string read FSensitiveText write SetSensitiveText;

property OnSensitiveText: TSensitiveTextEvent read FOnSensitiveText write FOnSensitiveText;

end;

procedure Register;

implementation

procedure Register;

begin

RegisterComponents(‘Linco’, [TTextSenseEdit]);

end;

procedure TTextSenseEdit.Change;

begin

inherited;

if Text = SensitiveText then

if Assigned(OnSensitiveText) then

  OnSensitiveText(Text);

end;

procedure TTextSenseEdit.SetSensitiveText(AValue: string);

begin

FSensitiveText := AValue;

end;

end.

代码解释：

（1）、SensitiveText属性的添加方法大家已经熟悉了，这里不多解释。

（2）、正如大家猜测的，Change方法正是编辑框文字发生变化时的调度方法，它将引起OnChange事件。我们可以在这个方法中监控编辑框文字发生的变化，当文字等于SensitiveText就触发OnSensitiveText事件（具体的实现方法在后边解释）。

（3）、Delphi中的控件的事件机制是通过方法指针来实现的。声明方法指针的格式为：

方法指针名称 = procedure(参数列表) of object;

声明事件属性的方法与声明普通属性的方法相同。在我们这个例子中，我们首先声明一个FOnSensitiveText: TSensitiveTextEvent;私有变量，然后property OnSensitiveText: TSensitiveTextEvent read FOnSensitiveText write FOnSensitiveText; 声明事件属性。这样注册控件后，当用户把控件放到窗体中后，就会在Object Inspector中Evnets页中出现OnSensitiveText事件，我们就可以像使用其他事件一样使用这个事件了。

但是我们现在只是声明了一个事件属性，并没有书写任何代码来激发这个事件。我们应该在合适的时候激发此事件，显而易见我们应该在Change方法中激发此事件：

procedure TTextSenseEdit.Change;

begin

inherited;

if Text = SensitiveText then

if Assigned(OnSensitiveText) then

  OnSensitiveText(Text);

end;

当if Text = SensitiveText时就判断控件使用者是否为OnSetSensitiveText写代码了（准确的说是是否为OnSetSensitiveText事件句柄赋值了），如果写代码了则调用OnSetSensitiveText(Text);来激发OnSetSensitiveText事件，并把控件的Text传递给方法的Avalue参数。正如“方法指针”这个名字一样，被声明为方法指针类型的变量可以当作方法使用，用来激发事件。VCL已经为我们预定义了一些常用的事件句柄，我们直接拿来使用：TnotifyEvent，TmouseEvent，TmouseMoveEvent，TkeyPressEvent等，具体可以参考VCL源码。