standard BAPI(BAPI_ACC_DOCUMENT_POST) to park document

there are serveral steps: 

1. Create an implementaion for BADI BADI_ACC_DOCUMENT.

2. Pass a text like "PARK_DOC" or something to extension2 to parameter of the BAPI (to uniquely identify that this is for parking).

3. Inside BADI method IF_EX_ACC_DOCUMENT~CHANGE, change the value of c_acchd-status_new to "2".

Code like this:

METHOD if_ex_acc_document~change.

  DATA: wa_extension   TYPE bapiparex.
  SORT c_extension2 BY structure.
  LOOP AT c_extension2 INTO wa_extension WHERE structure = 'ZEXTEN'.
    IF wa_extension-valuepart1 = 'PARK'.
      c_acchd-status_new = '2'.
    ENDIF.
  ENDLOOP.

  DATA:zext_data    TYPE zrr02.
  FIELD-SYMBOLS: <accit> TYPE accit.
  IF c_extension2[] IS NOT INITIAL.
    LOOP AT c_extension2 INTO wa_extension WHERE structure = 'ZRR02'.
      zext_data-bschl = wa_extension-valuepart1.
      READ TABLE c_accit ASSIGNING <accit> WITH KEY posnr = zext_data-bschl+0(10)."行项目
      IF sy-subrc = 0.
        <accit>-bschl = zext_data-bschl+10(2)."分别指定要传入到bapi的字段
      ENDIF.
    ENDLOOP.
  ENDIF.
ENDMETHOD.

4. write code about bapi:BAPI_ACC_DOCUMENT_POST

Code like this:

FUNCTION zfunc_document_park.
*"----------------------------------------------------------------------
*"*"Local interface:
*"  TABLES
*"      INPUT STRUCTURE  ZREIMBURSEMENT_G OPTIONAL
*"      OUTPUT STRUCTURE  ZDOCUMENT_OUTPUT OPTIONAL
*"----------------------------------------------------------------------


*&—-G/L ACCOUNT ITEM
  DATA:accountgl TYPE STANDARD TABLE OF bapiacgl09.
  DATA:wa_accountgl TYPE bapiacgl09.

*&—CURRENCY ITEMS
  DATA:currency_amount TYPE STANDARD TABLE OF bapiaccr09.
  DATA:wa_currency_amount TYPE bapiaccr09.
*&—-RETURN PARAMETER
  DATA:return TYPE STANDARD TABLE OF bapiret2 WITH HEADER LINE.

*&—-it_extension2 ITEMS
  DATA:it_extension2 TYPE STANDARD TABLE OF bapiparex WITH HEADER LINE.

*&—WORKAREA FOR ZEXTEN
  DATA:wa_zexten LIKE zexten. "ZEXTEN就是刚才SE11创建的那个结构
  DATA:wa_zrr02 LIKE zrr02. "ZEXTEN就是刚才SE11创建的那个结构
  DATA:header TYPE bapiache09.

  DATA:lv_posnr_acc TYPE posnr_acc.
**********************************************************************
*赋值
**********************************************************************

*& EXTENSION2 扩展字段增强部分
  CLEAR wa_zexten.
  REFRESH it_extension2.
  CLEAR it_extension2.

  wa_zexten-park = 'PARK'. "凭证行项目
  it_extension2-structure  = 'ZEXTEN'.
  it_extension2-valuepart1 = wa_zexten.
  APPEND it_extension2.

*其他参数表的字段赋值如下例
  CLEAR header.
  CLEAR input.
  READ TABLE input INDEX 1.
  IF sy-subrc EQ 0.
    header-header_txt = input-bktxt."'TEST HEADER'."凭证抬头文本
    header-username   = sy-uname.   "用户名
    header-comp_code  = input-bukrs."'1100'."公司代码
    header-doc_date   = input-bldat."sy-datum."凭证中的凭证日期
    header-pstng_date = input-budat."sy-datum."凭证中的记帐日期
    header-doc_type   = input-blart."'SA'."凭证类型
    header-ref_doc_no = input-xblnr.
  ENDIF.

  lv_posnr_acc = '0000000010'.
  LOOP AT input.
    CLEAR wa_zrr02.
    CONCATENATE lv_posnr_acc input-bschl INTO wa_zrr02-bschl.
    it_extension2-structure  = 'ZRR02'.
    it_extension2-valuepart1 = wa_zrr02.
    APPEND it_extension2.

    IF strlen( input-hkont ) <= 8.
      CONCATENATE '00' input-hkont INTO input-hkont.
    ENDIF.

    IF strlen( input-kostl ) <= 6 AND input-kostl <> ''.
      CONCATENATE '0000' input-kostl INTO input-kostl.
    ENDIF.
    wa_accountgl-itemno_acc = lv_posnr_acc."'0000000010'. "会计凭证行项目编号
    wa_accountgl-gl_account = input-hkont."'0055020101'. "总分类帐帐目
    wa_accountgl-costcenter = input-kostl."'0000110001'.
    wa_accountgl-item_text  = input-sgtxt.
    wa_accountgl-alloc_nmbr = input-zuonr.
    wa_accountgl-orderid    = input-aufnr.

    SELECT SINGLE
           fipos
           INTO wa_accountgl-cmmt_item
           FROM skb1
           WHERE saknr = input-hkont.

    APPEND wa_accountgl TO accountgl.
    CLEAR wa_accountgl.

    wa_currency_amount-itemno_acc = lv_posnr_acc."'0000000010'. "行项目编号
    IF input-bschl = '40' OR input-bschl = '01' OR input-bschl = '09' OR input-bschl = '21'  OR input-bschl = '29'.
      wa_currency_amount-amt_doccur = input-dmbtr."'500'. "金额
    ELSEIF input-bschl = '50'  OR input-bschl = '11' OR input-bschl = '19' OR input-bschl = '31'  OR input-bschl = '39'..
      wa_currency_amount-amt_doccur = 0 - input-dmbtr."'500'. "金额
    ENDIF.

    wa_currency_amount-currency = input-waers."'RMB'.
    APPEND wa_currency_amount TO currency_amount.
    CLEAR wa_currency_amount.

    lv_posnr_acc = lv_posnr_acc + 10.
  ENDLOOP.
*执行BAPI
  CALL FUNCTION 'BAPI_ACC_DOCUMENT_POST'
    EXPORTING
      documentheader = header
*     CUSTOMERCPD =
*     CONTRACTHEADER =
*     IMPORTING
*     OBJ_TYPE =
*     OBJ_KEY =
*     OBJ_SYS =
    TABLES
      accountgl = accountgl
*     ACCOUNTRECEIVABLE =
*     ACCOUNTPAYABLE =
*     ACCOUNTTAX =
      currencyamount = currency_amount
*     CRITERIA =
*     VALUEFIELD =
*     EXTENSION1 =
      return = return
*     PAYMENTCARD =
*     CONTRACTITEM =
      extension2 = it_extension2
*     REALESTATE =
    .

  IF return-type NA 'E'.
    CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
      EXPORTING
        wait = 'X'.
    LOOP AT input.
      MOVE-CORRESPONDING input TO output.
      output-flag = 'S'.
      output-message = return-message.
      APPEND output.
      CLEAR output.

      UPDATE zreimbursement_g SET belnr = ''
                                  gjahr = ''
                                  code  = 'S'
                                  message = return-message
                                  WHERE fid = input-fid.
    ENDLOOP.
  ELSE.
    LOOP AT input.
      MOVE-CORRESPONDING input TO output.
      output-flag = 'E'.
      output-message = return-message.
      APPEND output.
      CLEAR output.
      UPDATE zreimbursement_g SET belnr = ''
                                  gjahr = ''
                                  code  = 'E'
                                  message = return-message
                                  WHERE fid = input-fid.
    ENDLOOP.
  ENDIF.

ENDFUNCTION.