SET XACT_ABORT

SET XACT_ABORT

指定當 Transact-SQL 陳述式發生執行時期錯誤時，Microsoft® SQL Server™ 是否會自動復原目前的交易。

語法

 

SET XACT_ABORT { ON | OFF }

備註

當 SET XACT_ABORT 設定為 ON 時，如果 Transact-SQL 陳述式發生執行期錯誤，整個交易都會中斷並復原。設定為 OFF 時，只有發生錯誤的 Transact-SQL 陳述式會復原，交易將繼續處理。編譯錯誤，例如語法錯誤並不會受到 SET XACT_ABORT 的影響。

大部份 OLE DB 提供者的隱含或內顯交易的資料修改陳述式都要求必須將 XACT_ABORT 設定為 ON，包含 SQL Server在內。唯一不需要設定此選項的情形是當提供者支援巢狀交易時。如需詳細資訊，請參閱分散式查詢及分散式交易。

SET XACT_ABORT 的設定是在執行或執行時期設定，而不是在剖析時期設定。

範例

本範例在還有其他 Transact-SQL 陳述式的交易中，造成外部索引鍵違反錯誤。在第一組陳述式中會產生錯誤，但是其他的陳述式將成功地執行，交易也會成功地認可。在第二組陳述式中，SET XACT_ABORT 設定變更為 ON，將造成陳述式錯誤，中斷批次及交易復原。

CREATE TABLE t1 (a int PRIMARY KEY)
CREATE TABLE t2 (a int REFERENCES t1(a))
GO
INSERT INTO t1 VALUES (1)
INSERT INTO t1 VALUES (3)
INSERT INTO t1 VALUES (4)
INSERT INTO t1 VALUES (6)
GO
SET XACT_ABORT OFF
GO
BEGIN TRAN
INSERT INTO t2 VALUES (1)
INSERT INTO t2 VALUES (2) /* Foreign key error */
INSERT INTO t2 VALUES (3)
COMMIT TRAN
GO

SET XACT_ABORT ON
GO

BEGIN TRAN
INSERT INTO t2 VALUES (4)
INSERT INTO t2 VALUES (5) /* Foreign key error */
INSERT INTO t2 VALUES (6)
COMMIT TRAN
GO

/* Select shows only keys 1 and 3 added. 
   Key 2 insert failed and was rolled back, but
   XACT_ABORT was OFF and rest of transaction
   succeeded.
   Key 5 insert error with XACT_ABORT ON caused
   all of the second transaction to roll back. */

SELECT * 
FROM t2
GO

DROP TABLE t2
DROP TABLE t1
GO