hit_os_lab2 操作系统启动

ZhengXinTang

已于 2022-12-01 15:17:37 修改

阅读量501

点赞数

分类专栏： # 操作系统文章标签： linux 运维服务器

于 2022-11-29 13:51:50 首次发布

本文链接：https://blog.csdn.net/chumingqian/article/details/128094457

版权

操作系统专栏收录该内容

24 篇文章 3 订阅

订阅专栏

前置知识

1.1 基础概念

入理论课程的学习。如果网易云上的课程无法查看，也可以看 Bilibili 上的操作系统哈尔滨工业大学李治军老师。

L2 开始揭开钢琴的盖子
L3 操作系统启动

同济大学赵炯博士的《Linux 内核 0.11 完全注释（修正版 V3.0）》（以后简称《注释》）的第 6 章是非常有帮助的参考，实验中可能遇到的各种问题，几乎都能找到答案。谢煜波撰写的《操作系统引导探究》也是一份很好的参考。

1.2 概念的代码实现

Linux 0.11 文件夹中的 boot/bootsect.s、boot/setup.s 和 tools/build.c 是本实验会涉及到的源文件。

它们的功能详见《注释》的 6.2、6.3 节和 16 章。

2. 实验内容

阅读《Linux 内核完全注释》的第 6 章，对计算机和 Linux 0.11 的引导过程进行初步的了解；

按照下面的要求改写 0.11 的引导程序 bootsect.s
有兴趣同学可以做做进入保护模式前的设置程序 setup.s。

改写 bootsect.s 主要完成如下功能：

bootsect.s 能在屏幕上打印一段提示信息“XXX is booting…”，其中 XXX 是你给自己的操作系统起的名字，例如 LZJos、Sunix 等（可以上论坛上秀秀谁的 OS 名字最帅，也可以显示一个特色 logo，以表示自己操作系统的与众不同。）

改写 setup.s 主要完成如下功能：

bootsect.s 能完成 setup.s 的载入，并跳转到 setup.s 开始地址执行。而 setup.s 向屏幕输出一行"Now we are in SETUP"。
setup.s 能获取至少一个基本的硬件参数（如内存参数、显卡参数、硬盘参数等），将其存放在内存的特定地址，并输出到屏幕上。
setup.s 不再加载 Linux 内核，保持上述信息显示在屏幕上即可。

2.1 实验提示

操作系统的 boot 代码有很多，并且大部分是相似的。本实验仿照 Linux-0.11/boot 目录下的 bootsect.s 和 setup.s，以剪裁它们为主线。当然，如果能完全从头编写，并实现实验所要求的功能，是再好不过了。

需要注意的是，oslab 中的汇编代码使用 as86 编译。

下面将给出一些更具体的 “提示”。这些提示并不是实验的一步一步的指导，而是罗列了一些实验中可能遇到的困难，并给予相关提示。它们肯定不会涵盖所有问题，也不保证其中的每个字都对完成实验有帮助。所以，它们更适合在你遇到问题时查阅，而不是当作指南一样地亦步亦趋。本课程所有实验的提示都是秉承这个思想编写的。

2.2 实验环境

（1）相关代码文件
Linux 0.11 文件夹中的 boot/bootsect.s、boot/setup.s 和 tools/build.c 是本实验会涉及到的源文件。它们的功能详见《注释》的 6.2、6.3 节和 16 章。

（2）引导程序的运行环境

引导程序bootsect.s 由BIOS 加载并运行，引导程序在执行的过程中，操作系统还不存在，此时整台计算机的所有资源由引导程序掌控，能使用的功能只有BIOS 中断调用，

在此过程中，主要使用了 0X10， 0X13 这两个中断。

3. `bootsect.s`

3.1 修改 bootsect.s

改动，这里需要修改的是字符串长度，即用需要输出的字符串长度替换 mov cx,#24 中的 24。要注意：除了我们设置的字符串 msg1 之外，还有三个换行 + 回车，一共是 6 个字符。比如这里 Hello OS world, my name is Chu Yun 的长度是 34，加上 6 后是 40，所以代码应该修改为 mov cx,#40。
修改启动时的字符串，将 .org 508 修改为 .org 510，是因为这里不需要 root_dev: .word ROOT_DEV，为了保证 boot_flag 一定在最后两个字节，所以要修改 .org。

完整的代码如下：

entry _start
_start:

! Print some inane message
! 读入光标所在位置
	mov	ah,#0x03		! read cursor pos
	xor	bh,bh
	int	0x10

!  显示启动过程中的字符串； “Hello OS world, my name is Chu Yun”	
	!mov	cx,#24
	
	mov cx,#40
	mov	bx,#0x0007		! page 0, attribute 7 (normal)
	mov	bp,#msg1
	
	!mov	ax,#0x1301		! write string, move cursor
	!int	0x10

! es:bp 是显示字符串的地址；
! 相比与原始的代码linux-0.11(原始代码中在输出之前处理了es), 这里增加对es 的处理，
    
	mov ax,#0x07c0
	mov es,ax
	mov ax,#0x1301
	int 0x10

! 设置一个无限循环
inf_loop:
	jmp inf_loop


! 在msg1处放置字符串
msg1:
! 一对回车+ 换行
	.byte  13,10
	.ascii "Hello OS world, my name is Chu Yun"
! 两对回车 + 换行
    .byte  13,10,13,10

.org 510
! 设置引导扇区标记， 0xAA55,  必须有该引导扇区的标记，才能引导；
boot_flag:
	.word 0xAA55

3.2 编译和运行 `bootsect.s`

执行下面两个命令编译和链接 bootsect.s：

$ as86 -0 -a -o bootsect.o bootsect.s
$ ld86 -0 -s -o bootsect bootsect.o

其中 -0（注意：这是数字 0，不是字母 O）表示生成 8086 的 16 位目标程序，-a 表示生成与 GNU as 和 ld 部分兼容的代码，-s 告诉链接器 ld86 去除最后生成的可执行文件中的符号信息。

如果这两个命令没有任何输出，说明编译与链接都通过了。

Ubuntu 下用 ls -l 可列出下面的信息：

~/os/oslab/linux-0.11/boot$ ls -l
总用量 72
-rwxrwxr-x 1 shiyanlou shiyanlou   544 11月 29 15:54 bootsect
-rw-rw-r-- 1 shiyanlou shiyanlou   924 11月 29 15:53 bootsect.o
-rw-r--r-- 1 shiyanlou shiyanlou  5059 8月  28  2008 bootsect_ori.s
-rw-r--r-- 1 shiyanlou shiyanlou  1799 11月 29 15:55 bootsect.s

其中 bootsect.o 是中间文件。bootsect 是编译、链接后的目标文件。

注意到; bootsect 的文件大小是 544 字节，而引导程序必须要正好占用一个磁盘扇区，即 512 个字节。

造成多了 32 个字节的原因是 ld86 产生的是 Minix 可执行文件格式，这样的可执行文件除了文本段、数据段等部分以外，还包括一个 Minix 可执行文件头部，它的结构如下：

struct exec {
    unsigned char a_magic[2];  //执行文件魔数
    unsigned char a_flags;
    unsigned char a_cpu;       //CPU标识号
    unsigned char a_hdrlen;    //头部长度，32字节或48字节
    unsigned char a_unused;
    unsigned short a_version;
    long a_text; long a_data; long a_bss; //代码段长度、数据段长度、堆长度
    long a_entry;    //执行入口地址
    long a_total;    //分配的内存总量
    long a_syms;     //符号表大小
};

算一算：6 char（6 字节）+ 1 short（2 字节） + 6 long（24 字节）= 32，正好是 32 个字节，去掉这 32 个字节后就可以放入引导扇区了（这是 tools/build.c 的用途之一）。

对于上面的 Minix 可执行文件，其 a_magic[0]=0x01，a_magic[1]=0x03，a_flags=0x10（可执行文件），a_cpu=0x04（表示 Intel i8086/8088，如果是 0x17 则表示 Sun 公司的 SPARC），所以 bootsect 文件的头几个字节应该是 01 03 10 04。

为了验证一下，Ubuntu 下用命令hexdump -C bootsect可以看到：

hexdump -C bootsect
00000000  01 03 10 04 20 00 00 00  00 02 00 00 00 00 00 00  |.... ...........|
00000010  00 00 00 00 00 00 00 00  00 82 00 00 00 00 00 00  |................|
00000020  b8 c0 07 8e d8 b8 00 90  8e c0 b9 00 01 29 f6 29  |.............).)|

3.3 修改 bootsect 文件大小

接下来干什么呢？

是的，要去掉这 32 个字节的文件头部（tools/build.c 的功能之一就是这个）！随手编个小的文件读写程序都可以去掉它。不过，

在 Ubuntu 下可以用命令：

3.4 ubuntu 中读入文件指定大小字节的数据

dd bs=1 if=bootsect of=Image skip=32
记录了512+0 的读入
记录了512+0 的写出
512字节已复制，0.00892562 s，57.4 kB/s
shiyanlou@respectinglife-Inspiron-24-5459:~/os/oslab/linux-0.11/boot$ ls
bootsect  bootsect.o  bootsect_ori.s  bootsect.s  head.o  head.s  Image  setup  setup.o  setup.s

3.5 运行引导文件 `bootsect`

去掉这 32 个字节后，将生成的文件拷贝到 linux-0.11 目录下，
并一定要命名为Image（注意大小写）。

~/os/oslab/linux-0.11/boot$ cp ./Image  ../Image

然后就“run”吧，注意到这里是在当前路径下，回退的方式运行的；

~/os/oslab/linux-0.11/boot$ ../../run

在这里插入图片描述

3.6 再次修改`bootsect.s`

前面修改bootsect.s 是为了在启动过程中，显示出，
现在需要再一次修改 bootset.s ，这一次修改是为了完成2个功能

使得bootsect.s 能够载入 setup.s 程序；
为了证明载入了setup.s 程序，我们在setup.s 中输出字符串，“Now we are in SETUP”

首先，需要编写 bootsect.s 中载入 setup.s 的关键代码。原版 bootsect.s 中下面的代码就是做这个的。

load_setup:
! 设置驱动器和磁头(drive 0, head 0): 软盘 0 磁头
    mov dx,#0x0000
! 设置扇区号和磁道(sector 2, track 0): 0 磁头、0 磁道、2 扇区
    mov cx,#0x0002
! 设置读入的内存地址：BOOTSEG+address = 512，偏移512字节
    mov bx,#0x0200
! 设置读入的扇区个数(service 2, nr of sectors)，
! SETUPLEN是读入的扇区个数，Linux 0.11 设置的是 4，
! 我们不需要那么多，我们设置为 2（因此还需要添加变量 SETUPLEN=2）
    mov ax,#0x0200+SETUPLEN
! 应用 0x13 号 BIOS 中断读入 2 个 setup.s扇区
    int 0x13
! 读入成功，跳转到 ok_load_setup: ok - continue
    jnc ok_load_setup
! 软驱、软盘有问题才会执行到这里。我们的镜像文件比它们可靠多了
    mov dx,#0x0000
! 否则复位软驱 reset the diskette
    mov ax,#0x0000
    int 0x13
! 重新循环，再次尝试读取
    jmp load_setup
ok_load_setup:
! 接下来要干什么？当然是跳到 setup 执行。
! 要注意：我们没有将 bootsect 移到 0x9000，因此跳转后的段地址应该是 0x7ce0
! 即我们要设置 SETUPSEG=0x07e0

然后，修改setup.s 程序，添加字符串“Now we are in SETUP”；

entry _start

_start:
    ; print the msg2 "Now we are in SETUP"
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#25   ; 这里25 代表字符串的长度是 25 = 19 + 6; 6= 3对回车+ 换行；
    mov bx,#0x0007
    mov bp,#msg2
    mov ax,cs
    mov es,ax
    mov ax,#0x1301
    int 0x10

inf_loop:
    jmp inf_loop


msg2:
    .byte 13,10
    .ascii "Now we are in SETUP"
    .byte 13,10,13,10

.org 510
boot_flag:
    .word 0xAA55

现在有两个文件都要编译、链接。一个个手工编译，效率低下，所以借助 Makefile 是最佳方式。

在 Ubuntu 下，进入 linux-0.11 目录后，使用下面命令（注意大小写）：

每次修改之后，需要到/home/shiyanlou/os/oslab/linux-0.11 的路径下，
重新执行 make clean && make BootImage,

该命令会执行Makefile 文件，而Makefile 文件则会调调用tools/build 中的文件；
在这里插入图片描述

有 Error！这是因为 make 根据 Makefile 的指引执行了 tools/build.c，它是为生成整个内核的镜像文件而设计的，没考虑我们只需要 bootsect.s 和 setup.s 的情况。它在向我们要 “系统” 的核心代码。

Unable to open 'system'
make: *** [BootImage] Error 1

为完成实验，接下来给它打个小补丁。

build.c 从命令行参数得到 bootsect、setup 和 system 内核的文件名，将三者做简单的整理后一起写入 Image。其中 system 是第三个参数（argv[3]）。当 “make all” 或者 “makeall” 的时候，这个参数传过来的是正确的文件名，build.c 会打开它，将内容写入 Image。而 “make BootImage” 时，传过来的是字符串 “none”。所以，改造 build.c 的思路就是当 argv[3] 是"none"的时候，只写 bootsect 和 setup，忽略所有与 system 有关的工作，或者在该写 system 的位置都写上 “0”。

修改工作主要集中在 build.c 的尾部，可以参考下面的方式，将圈起来的部分注释掉。

	fprintf(stderr,"Setup is %d bytes.\n",i);
	for (c=0 ; c<sizeof(buf) ; c++)
		buf[c] = '\0';
	while (i<SETUP_SECTS*512) {
		c = SETUP_SECTS*512-i;
		if (c > sizeof(buf))
			c = sizeof(buf);
		if (write(1,buf,c) != c)
			die("Write call failed");
		i += c;
	}
	
// 	if ((id=open(argv[3],O_RDONLY,0))<0)
// 		die("Unable to open 'system'");
// //	if (read(id,buf,GCC_HEADER) != GCC_HEADER)
// //		die("Unable to read header of 'system'");
// //	if (((long *) buf)[5] != 0)
// //		die("Non-GCC header of 'system'");
// 	for (i=0 ; (c=read(id,buf,sizeof buf))>0 ; i+=c )
// 		if (write(1,buf,c)!=c)
// 			die("Write call failed");
// 	close(id);
// 	fprintf(stderr,"System is %d bytes.\n",i);
// 	if (i > SYS_SIZE*16)
// 		die("System is too big");

	return(0);
}

4. `setup.S` 获取硬件参数

setup.s 将获得硬件参数放在内存的 0x90000 处。
原版 setup.s 中已经完成了光标位置、内存大小、显存大小、显卡参数、第一和第二硬盘参数的保存。

4.1 获取硬件参数

用 ah=#0x03 调用 0x10 中断可以读出光标的位置，用 ah=#0x88 调用 0x15 中断可以读出内存的大小。
有些硬件参数的获取要稍微复杂一些，如磁盘参数表。

在 PC 机中 BIOS 设定的中断向量表中 int 0x41 的中断向量位置(4*0x41 = 0x0000:0x0104)存放的并不是中断程序的地址，而是第一个硬盘的基本参数表。
第二个硬盘的基本参数表入口地址存于 int 0x46 中断向量位置处。每个硬盘参数表有 16 个字节大小。

下表给出了硬盘基本参数表的内容：

在这里插入图片描述

mov    ax,#INITSEG
! 设置 ds = 0x9000
mov    ds,ax
mov    ah,#0x03
! 读入光标位置
xor    bh,bh
! 调用 0x10 中断
int    0x10
! 将光标位置写入 0x90000.
mov    [0],dx

! 读入内存大小位置
mov    ah,#0x88
int    0x15
mov    [2],ax

! 从 0x41 处拷贝 16 个字节（磁盘参数表）
mov    ax,#0x0000
mov    ds,ax
lds    si,[4*0x41]
mov    ax,#INITSEG
mov    es,ax
mov    di,#0x0004
mov    cx,#0x10
! 重复16次
rep
movsb

4.2 显示硬件参数

现在已经将硬件参数（只包括光标位置、内存大小和硬盘参数，其他硬件参数取出的方法基本相同，此处略去）取出来放在了 0x90000 处，接下来的工作是将这些参数显示在屏幕上。这些参数都是一些无符号整数，所以需要做的主要工作是用汇编程序在屏幕上将这些整数显示出来。

以十六进制方式显示比较简单。这是因为十六进制与二进制有很好的对应关系（每 4 位二进制数和 1 位十六进制数存在一一对应关系），显示时只需将原二进制数每 4 位划成一组，按组求对应的 ASCII 码送显示器即可。ASCII 码与十六进制数字的对应关系为：0x30 ～ 0x39 对应数字 0 ～ 9，0x41 ～ 0x46 对应数字 a ～ f。从数字 9 到 a，其 ASCII 码间隔了 7h，这一点在转换时要特别注意。为使一个十六进制数能按高位到低位依次显示，实际编程中，需对 bx 中的数每次循环左移一组（4 位二进制），然后屏蔽掉当前高 12 位，对当前余下的 4 位（即 1 位十六进制数）求其 ASCII 码，要判断它是 0 ～ 9 还是 a ～ f，是前者则加 0x30 得对应的 ASCII 码，后者则要加 0x37 才行，最后送显示器输出。以上步骤重复 4 次，就可以完成 bx 中数以 4 位十六进制的形式显示出来。

下面是完成显示 16 进制数的汇编语言程序的关键代码，其中用到的 BIOS 中断为 INT 0x10，功能号 0x0E（显示一个字符），即 AH=0x0E，AL=要显示字符的 ASCII 码。

    ;以16进制方式打印栈顶的16位数，
print_hex:
    ; 4个十六进制数字
    mov cx,#4
    ; 将bp 所指的值放入dx中， 如果bp 是指向栈顶的话，
    ;mov dx,(bp)

print_digit:
    ; 循环以使得低4比特用上， 取dx 的高4比特， 移到低4比特处；
    rol dx,#4
  
    ; ah= 请求的功能值， al=半字节 （4个比特）掩玛；
    mov ax,#0xe0f
    ; 取出dl 的低四比特
    and al,dl
    ;给al 加上十六进制0x30
    add al,#0x30
    cmp al,#0x3a
    ; 一个不大于十的数字
    jl outp
    ;a-f ，多加7
    add al,#0x07


; 此处，使用loop 指令， 每次执行loop指令， cx 减一， 然后判断cx 是否等于0；
;  cx不为0， 则转移到 loop 指令后的标号处， 实现循环；
;  =0, 顺序执行；


;  还有一个相似的指令 rep, 每次执行rep 指令， cx 减一， 判断cx 是否等于0；
;  不为0， 继续执行rep 指令后的串操作指令， 直到cx = 0, 实现重复；


outp:
    int 0x10
    loop print_digit
    ret

; 打印回车 + 换行；
print_nl:
    ; CR
    mov  ax,#0xe0d
    int 0x10

    ;LF
    mov al,#0xa
    int 0x10
    ret

只要在适当的位置调用 print_bx 和 print_nl（注意，一定要设置好栈，才能进行函数调用）就能将获得硬件参数打印到屏幕上，完成此次实验的任务。但事情往往并不总是顺利的，前面的两个实验大多数实验者可能一次就编译调试通过了

（这里要提醒大家：编写操作系统的代码一定要认真，因为要调试操作系统并不是一件很方便的事）。但在这个实验中会出现运行结果不对的情况（为什么呢？因为我们给的代码并不是 100% 好用的）。所以接下来要复习一下汇编，并阅读《Bochs 使用手册》，学学在 Bochs 中如何调试操作系统代码。

在这里插入图片描述
Memory Size 是 0x3C00KB，算一算刚好是 15MB（扩展内存），加上 1MB 正好是 16MB，

看看 Bochs 配置文件 bochs/bochsrc.bxrc：

$3* 16^3$ + $C(12) * 16^2$ = 3* 4096 + 12* 256 = 15360 kB;
; 15360 kb / 1024 = 15 MB;

mode=flat, cylinders=204, heads=16, spt=38
boot: a

4.3 参考代码


INITSEG = 0x9000

entry _start

_start:
    ; print the msg2 "Now we are in SETUP"
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#25   ; 这里25 代表字符串的长度是 25 = 19 + 6; 6= 3对回车+ 换行；
    mov bx,#0x0007
    mov bp,#msg2
    mov ax,cs
    mov es,ax
    mov ax,#0x1301
    int 0x10


    mov ax,cs
    mov es,ax

    ; init ss:sp
    mov ax,#INITSEG
    mov ss,ax
    mov sp,#0xFF00


    ; get params 
    ;  设置ds = 0x9000
    mov ax,#INITSEG
    mov ds,ax
    mov ah,#0x03
    
    ;读入光标位置
    xor bh,bh
    ;调用0x10中断
    int 0x10
    ;将光标位置写入0x90000
    mov [0],dx


    ;读入内存大小位置
    mov ah,#0x88
    int 0x15
    mov [2],ax

    ; 磁盘参数表， 从0x41 处拷贝16个字节，
    mov ax,#0x0000
    mov ds,ax
    lds si,[4*0x41]
    mov ax,#INITSEG
    mov es,ax
    mov di,#0x0004
    mov cx,#0x10
    ; repeat 16 次数
    rep
    movsb


; be ready to print

    mov ax,cs
    mov es,ax
    mov ax,#INITSEG
    mov ds,ax

    ;cursor Position
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#18
    mov bx,#0x0007
    mov bp,#msg_cursor
    mov ax,#0x1301
    int 0x10
    mov dx,[0]
    call print_hex

    ;Memory size
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#14
    mov bx,#0x0007
    mov bp,#msg_memory
    mov ax,#0x1301
    int 0x10
    mov dx,[2]
    call print_hex


    ;add kB
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#2
    mov bx,#0x0007
    mov bp,#msg_kb
    mov ax,#0x1301
    int 0x10

    ;cycles
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#9
    mov bx,#0x0007
    mov bp,#msg_cycles
    mov ax,#0x1301
    int 0x10
    mov dx,[4]
    call print_hex

    ;heads
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#8
    mov bx,#0x0007
    mov bp,#msg_heads
    mov ax,#0x1301
    int 0x10
    mov dx,[6]
    call print_hex

    ;sectors
    mov ah,#0x03
    xor bh,bh
    int 0x10
    mov cx,#10
    mov bx,#0x0007
    mov bp,#msg_sectors
    mov ax,#0x1301
    int 0x10
    mov dx,[12]
    call print_hex


inf_loop:
    jmp inf_loop


    ;以16进制方式打印栈顶的16位数，
print_hex:
    ; 4个十六进制数字
    mov cx,#4
    ; 将bp 所指的值放入dx中， 如果bp 是指向栈顶的话，
    ;mov dx,(bp)

print_digit:
    ; 循环以使得低4比特用上， 取dx 的高4比特， 移到低4比特处；
    rol dx,#4
  
    ; ah= 请求的功能值， al=半字节 （4个比特）掩玛；
    mov ax,#0xe0f
    ; 取出dl 的低四比特
    and al,dl
    ;给al 加上十六进制0x30
    add al,#0x30
    cmp al,#0x3a
    ; 一个不大于十的数字
    jl outp
    ;a-f ，多加7
    add al,#0x07


; 此处，使用loop 指令， 每次执行loop指令， cx 减一， 然后判断cx 是否等于0；
;  cx不为0， 则转移到 loop 指令后的标号处， 实现循环；
;  =0, 顺序执行；


;  还有一个相似的指令 rep, 每次执行rep 指令， cx 减一， 判断cx 是否等于0；
;  不为0， 继续执行rep 指令后的串操作指令， 直到cx = 0, 实现重复；


outp:
    int 0x10
    loop print_digit
    ret

; 打印回车 + 换行；
print_nl:
    ; CR
    mov  ax,#0xe0d
    int 0x10

    ;LF
    mov al,#0xa
    int 0x10
    ret 

msg2:
    .byte 13,10
    .ascii "Now we are in SETUP"
    .byte 13,10,13,10
    
msg_cursor:
    .byte 13,10
    .ascii "Cursor position:"

msg_memory:
    .byte 13,10
    .ascii "Memory size:"

msg_cycles:
    .byte 13,10
    .ascii "Cycles:"


msg_heads:
    .byte 13,10
    .ascii "Heads:"

msg_sectors:
    .byte 13,10
    .ascii "Sectors:"

msg_kb:
    .ascii "KB"

.org 510
boot_flag:
    .word 0xAA55