groovy脚本编写, 处理中文乱码, 结合lombok+fastjson, 输出数据库生成实体类

解决文件输出中文乱码的问题

 PrintWriter output = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "utf-8"))
    output.withPrintWriter { out -> generate(out, className, fields) }

输出表的注释

 if (isNotEmpty(table.getComment())) {
        out.println ""
        out.println "/**"
        out.println " * ${table.getComment()}"
        out.println " */"
    }

结合lombok+fastjson, 去除原有get, set 方法.

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */

packageName = "com.sample;"
typeMapping = [
        (~/(?i)int/)                      : "long",
        (~/(?i)float|double|decimal|real/): "double",
        (~/(?i)datetime|timestamp/)       : "java.sql.Timestamp",
        (~/(?i)date/)                     : "java.sql.Date",
        (~/(?i)time/)                     : "java.sql.Time",
        (~/(?i)/)                         : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each {
        generate(it, dir)
    }

}

def generate(table, dir) {
    def className = javaName(table.getName(), true) + "Dto"
    def fields = calcFields(table)
    PrintWriter output = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "utf-8"))
    output.withPrintWriter { out -> generate(out, className, fields,table) }
//    new File(dir, className + ".java").withPrintWriter { out -> generate(out, className, fields) }
}

def generate(out, className, fields,table) {
    out.println "package $packageName"
    out.println ""
    out.println "import java.io.Serializable;"
    out.println "import lombok.Data;"
    out.println "import lombok.NoArgsConstructor;"
    out.println "import lombok.AllArgsConstructor;"
    out.println "import com.alibaba.fastjson.annotation.JSONField;"
    out.println ""
    out.println ""
    if (isNotEmpty(table.getComment())) {
        out.println ""
        out.println "/**"
        out.println " * ${table.getComment()}"
        out.println " */"
    }
    out.println "@Data"
    out.println "@NoArgsConstructor"
    out.println "@AllArgsConstructor"
    out.println "public class $className implements Serializable {"
    out.println ""
    def msum = (long) (Math.random() * 1000000000000000000 + 1000000000000000000)
    out.println "\tprivate static final long serialVersionUID = ${msum}L;"
    out.println ""
    fields.each() {
        out.println ""
        if (isNotEmpty(it.commoent)) {
            out.println ""
            out.println "\t/**"
            out.println "\t * ${it.commoent.toString()}"
            out.println "\t */"
        }
        if (it.annos != "") {
            out.println "\t${it.annos}"
        }
        out.println "\t@JSONField(name =\"" + it.name + "\")"
        out.println "\tprivate ${it.type} ${it.name};"

    }
    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        fields += [[
                           name    : javaName(col.getName(), false),
                           type    : typeStr,
                           commoent: col.getComment(),
                           annos   : ""]]
    }
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}