弹出"选择文件夹"对话框

最新推荐文章于 2024-11-12 09:30:12 发布

cike_1111

最新推荐文章于 2024-11-12 09:30:12 发布

阅读量741

点赞数

文章标签： string function command integer object shell

本文链接：https://blog.csdn.net/cike_1111/article/details/2029095

版权

API部分:

Private Type BrowseInfo
    hWndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
    ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type
Private Const BIF_RETURNONLYFSDIRS = 1
Private Const MAX_PATH = 260

Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As Long)
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long

'定义一个过程
Public Function BrowseForFolder(hWndOwner As Long, sPrompt As String) As String
Dim sDefaultPath As Variant
Dim iNull As Integer
Dim lpIDList As Long
Dim lResult As Long
Dim sPath As String
Dim udtBI As BrowseInfo
With udtBI
    .hWndOwner = hWndOwner
    .lpszTitle = lstrcat(sPrompt, "")
    .ulFlags = BIF_RETURNONLYFSDIRS
    .pIDLRoot = sDefaultPath
End With
lpIDList = SHBrowseForFolder(udtBI)
If lpIDList Then
    sPath = String$(MAX_PATH, 0)
    lResult = SHGetPathFromIDList(lpIDList, sPath)
    Call CoTaskMemFree(lpIDList)
    iNull = InStr(sPath, vbNullChar)
    If iNull Then
        sPath = Left$(sPath, iNull - 1)
    End If
End If
BrowseForFolder = sPath
End Function

应用部分:

Private Sub form_Click() '窗体的单击事件
Dim a As String
a = BrowseForFolder(Me.hWnd, "请选择目录") '变量a 存储提取的文件夹
Cls '清屏
Print a '在窗体上打印出路径
End Sub

以上为方法1 下面介绍一个更为简便的方法直接获取选择的文件夹路径和文件夹的名称：

===========================================================================================

建立一个窗体,添加两个TEXT控件,分别命名为text1,text2;另外添加一个命令按钮Command1,在代码中添加好下代码:

Option Explicit

Private Sub Command1_Click()
      On Error Resume Next
      Dim a As Object
      Set a = CreateObject("shell.application")
      Dim b As Object
      Set b = a.BrowseForFolder(Me.hWnd, "select folder", 0)
      Text1 = b.Title
      Text2 = b.Self.Path
End Sub

text1就显示文件夹名,text2显示文件夹路径