★ 我的世界各类奇葩武器实现！（命令方块1.13+）

新版execute一出很多玩家都不会了。开头先给大家说一下怎么以旧换新：
e.g.
旧版：
/execute @e[type=arrow] ~ ~ ~ summon tnt
新版就改为：
/execute at @e[type=arrow] run summon tnt
非常简单！

注记

以下代码块里的命令未经表明一律都是循环命令方块！
不在代码块里的是运行一遍即可（直接在聊天栏里输一次就可以了）

正文走起~

0.获得命令方块

/give @p command_block 64
一定要学会用Tab(自动补全)，非常方便！这条指令可以简记为：
/giTab Tab commTab 64
命令方块界面如下：

1.爆炸箭

这个用了很久了：

tag @e[nbt={inGround:1b}] add inGround

↑给所有插在地上的添加标签inGround。插在地上的只能是箭。
新版的实体选择器允许使用[nbt=]就很方便。

execute at @e[tag=inGround,type=arrow,tag=!shockwave] run summon creeper ~ ~ ~ {CustomName:'{"text":"爆炸箭","color":"red","italic":"false"}',Fuse:0,Tags:["shockwave"]}

一落地就炸。

execute at @e[type=arrow] at @e[type=!player,type=!arrow,distance=..3] run summon minecraft:creeper ~ ~ ~ {CustomName:'{"text":"爆炸箭","color":"red","italic":"false"}',Fuse:0,Tags:["shockwave"]}

不加这句箭射到生物身上就爆不了
两个type=!一定要加，不然秒爆
Fuse:0一定要加，意思是苦力怕瞬爆
Tags:是便捷地为实体添加标签。
点点三 的意思就是<=3.（单位并不是格）同理 三点点 就是>=3，一点点三 就是1到3 [闭区间]

execute at @e[type=arrow] run particle minecraft:cloud ~ ~ ~ 0.2 0.2 0.2 0.1 5

↑（可选）白烟粒子效果(cloud)

kill @e[type=arrow,tag=inGround]

别忘了杀掉爆过的箭.这个命令方块应该最后放，不然爆不了就杀掉了。

☆ 为什么不用TNT呢？因为TNT会破坏方块，不道德。
设成苦力怕后输入 /gamerule mobGriefing false 就可以关闭苦力怕破坏方块。

2.闪电箭

tag @e[nbt={inGround:1b}] add inGround

execute at @e[type=arrow,tag=inGround] run summon lightning_bolt

落地闪电。

execute at @e[type=arrow] at @e[type=!player,type=!arrow,type=!lightning_bolt,distance=..3] run summon lightning_bolt

别忘了type=!lightning_bolt。我这边已经崩溃过一次了。

execute at @e[type=arrow] run particle minecraft:enchanted_hit ~ ~ ~ 0.2 0.2 0.2 0.1 5

↑（可选）附魔暴击粒子效果。

kill @e[type=arrow,tag=inGround]

3.手投式TNT

按Q

execute at @e[type=item,name=TNT,nbt={Age:15s}] run summon creeper ~ ~ ~ {CustomName:'{"text":"TNT","color":"red","italic":"false"}',Fuse:0s,Tags:["shockwave"]}

Age是一个计时器，挺好用的，免去了计分板的痛苦。 到一定时间后就爆炸。15s是估计的（s不是秒的意思）

execute at @e[type=item,name=TNT] run particle smoke ~ ~ ~ 0.1 0.1 0.1 0.1 20

（可选）黑烟滚滚。

execute at @e[type=item,name=TNT,nbt={Age:9s}] run particle minecraft:small_flame ~ ~ ~ 0.3 0.4 0.3 0.1 200

（可选）将炸时窜出火苗。
kill就不用了。因为爆炸会把物品炸掉。

多人PVP必备。

4.滞留型药水炸弹

execute at @e[type=area_effect_cloud] run summon creeper ~ ~ ~ {CustomName:'{"text":"药水","color":"dark_aqua","italic":"false"}',Fuse:0,Tags:["shockwave"]}

爆炸。

execute at @e[type=potion] run particle minecraft:instant_effect ~ ~ ~ 0.1 0.1 0.1 0.001 8 force @a

（可选）瞬间效果粒子效果。

kill @e[type=minecraft:area_effect_cloud]

必须得杀。

5.铁砧镇压

execute at @e[name="铁砧镇压"] run fill ~3 ~3 ~3 ~-3 4 ~-3 anvil

fill指令可以填充一块区域的方块。

kill @e[name="铁砧镇压"]

获得一组铁砧镇压召唤蛋：
/give @p minecraft:cow_spawn_egg{display:{Name:‘{“text”:“铁砧镇压”,“color”:“red”,“bold”:“true”,“italic”:“false”}’},Enchantments:[{id:“unbreaking”,lvl:233}],HideFlags:1s} 64
{Enchantments} 是附魔，耐久233.附魔的物品波光粼粼具有美感。
{HideFlags} 是一个鲜为人知的标签，意思是隐藏指定的物品备注。1代表附魔属性。2,4,8等都有含义，可以进行叠加【用的是标志位原理】。

6.鸡蛋炸弹

execute at @e[type=egg] at @e[type=!egg,type=!item,type=!player,distance=..3] run summon creeper ~ ~ ~ {CustomName:'{"text":"鸡蛋","color":"dark_yellow","italic":"false"}',Fuse:0,Tags:["shockwave"]}

附近有生物就爆炸。落地不炸。

execute at @e[type=egg] run particle minecraft:poof ~ ~ ~ 0.2 0.2 0.2 0.1 10 force
execute at @e[type=egg] at @e[type=!egg,type=!item,type=!player,distance=..3] run particle minecraft:end_rod ~ ~ ~ 1 1 1 0.1 60 force

（可选）粒子效果。包括弹道与击中时的粒子。

execute at @e[type=egg] run playsound minecraft:block.amethyst_block.place neutral @a[distance=..10] ~ ~ ~ 1.0 0.01

（1.17+；可选）发射的音效效果。

7.末影之眼火箭

连续用两个可以飞10格，三个飞到20格，四个就能飞到60格！

execute at @e[type=minecraft:eye_of_ender] run summon creeper ~ ~-2 ~ {CustomName:'{"text":"末影之眼","color":"light_purple","italic":"false"}',Fuse:0,Tags:["shockwave"]}

连续爆炸。不用kill，因为一段距离后末影之眼会变成物品，被炸掉。

execute at @e[type=minecraft:eye_of_ender] run particle minecraft:dragon_breath ~ ~ ~ 0.2 0.2 0.2 0.1 50

（可选）龙息粒子效果。

8.雪球高炮

雪球也有类似的效果，慢速坠落时扔一个可以回天！

execute at @e[type=snowball] run summon creeper ~ ~-1 ~ {CustomName:'{"text":"雪球","color":"gray","italic":"false"}',Fuse:0,Tags:["shockwave"]}

雪球不会被炸掉的。

kill @e[type=snowball,distance=100..]

最好加一句这个（杀掉远去的雪球）。因为雪球会飞无限远，如果被炸上去的话。会死机的。

execute at @e[type=snowball] run particle minecraft:glow ~ ~ ~ 0.1 0.1 0.1 0.1 100

（1.17+；可选）蓝绿色的粒子效果。

9.地雷

这个很实用！

tag @e[nbt={OnGround:1b}] add onGround

为在地上的实体添加标签onGround，方便后续操作。

execute at @e[type=item,tag=onGround,nbt={Item:{id:"minecraft:gunpowder",Count:1b,tag:{display:{Name:'{"text":"地雷(Q)","italic":"false","color":"gold"}'}}}}] run summon creeper ~ ~-1 ~ {CustomName:'{"text":"地雷","color":"gold"}',Tags:["landmine"],NoAI:1b,Silent:1b}

注意：minecraft:gunpowder特别是这个{Item}标签是不能省略前缀minecraft:的！
↑ 往下一格是为了刚好让它在地上露出一个头，跟地雷差不多大，不挡箭之类的。
{NoAI} 是没有AI的意思（也就是没有任何活动。不会运动不会自爆）{Silent} 是不发出任何声音的意思。
【如果想显示地雷，就在上面那条的最后添加一个标签powered:1b】
如果地雷显示，它将会是这样，特别炫酷：

execute at @e[type=item,tag=onGround,nbt={Item:{id:"minecraft:gunpowder",Count:1b,tag:{display:{Name:'{"text":"地雷(Q)","italic":"false","color":"gold"}'}}}}] run playsound minecraft:entity.creeper.primed block @a

↑（可选）埋雷音效是苦力怕的嘶嘶声。

kill @e[type=item,tag=onGround,nbt={Item:{id:"minecraft:gunpowder",Count:1b,tag:{display:{Name:'{"text":"地雷(Q)","italic":"false","color":"gold"}'}}}}]

↑ 杀死特定的火药。

effect give @e[tag=landmine] minecraft:resistance 1000 10 true
effect give @e[tag=landmine] minecraft:invisibility 1000 10 true

↑ 地雷无敌+隐身。

execute at @e[tag=!landmine,type=!item] run data merge entity @e[tag=landmine,distance=..3,limit=1] {Fuse:0s,powered:1b}
execute at @e[tag=!landmine,type=!item] run tp @e[tag=landmine,distance=..3,limit=1] ~ ~1 ~

↑ 生物靠近后爆炸（将苦力怕设置为瞬爆+高压）。往上tp一格才能炸飞。。效果才能显著。

execute at @e[tag=!landmine,type=!item] at @e[tag=landmine,limit=1,distance=..2] run particle minecraft:block dirt ~ ~ ~ 0.8 0.9 0.8 0.1 500 force
execute at @e[tag=!landmine,type=!item] at @e[tag=landmine,limit=1,distance=..2] run particle minecraft:block sand ~ ~ ~ 0.8 0.9 0.8 0.1 500 force

（可选）粒子效果。跟土豆地雷差不多。
获得一组地雷：
/give @p minecraft:gunpowder{display:{Name:‘{“text”:“地雷(Q)”,“italic”:“false”,“color”:“gold”}’},Enchantments:[{id:“unbreaking”,lvl:10}],HideFlags:1s} 64
丢在地上即可埋雷

10.附魔之瓶手榴弹

原理就是在经验球处放瞬爆苦力怕，所以得先输入下面两个指令：
/gamerule doTileDrops false
/gamerule doMobLoot false
关闭经验球的自然产生。（注意，会关闭怪物与方块掉落）

execute at @e[type=minecraft:experience_orb] run summon creeper ~ ~ ~ {CustomName:'{"text":"手雷","color":"green","italic":"false"}',Fuse:0s,Tags:["shockwave"]}

↑ 爆炸。

execute at @e[type=minecraft:experience_bottle] run particle minecraft:small_flame ~ ~ ~ 0.2 0.2 0.2 0.1 10 force
execute at @e[type=minecraft:experience_orb] run particle lava ~ ~ ~ 1 1 1 0.1 55 force

↑（可选）附魔之瓶与经验球的粒子效果。

execute at @e[type=minecraft:experience_bottle] at @p[distance=..2] run playsound minecraft:entity.evoker.cast_spell player @p

↑ （可选）扔手雷的音效。

execute at @e[type=minecraft:experience_orb] at @p run playsound minecraft:entity.evoker.celebrate master @p

↑ （可选）手雷爆炸后的欢呼声。

11.史莱姆烟花

无人机的又一大杀手！燃放一个史莱姆打击上空目标！！

tag @e[type=slime,name="史莱姆烟花"] add slimefw

添加标签，方便后续操作。

effect give @e[tag=slimefw] minecraft:levitation 100 50 true

飘浮效果，实现升天。

execute at @e[tag=slimefw] run particle minecraft:firework ~ ~ ~ 0.2 0.2 0.2 0.1 5 force

↑（可选）烟花轨迹粒子效果。

execute at @e[tag=slimefw,tag=onGround] if block ~ ~-0.1 ~ #minecraft:dirt run playsound minecraft:entity.firework_rocket.launch player @a

↑（可选）烟花升空的音效。

kill @e[tag=slimefw,distance=200..]

防止升太高卡存档。杀掉远去的烟花。

execute at @e[tag=!onGround,tag=!inGround,tag=!slimefw,tag=!shockwave] at @e[tag=slimefw,distance=..3] run summon minecraft:firework_rocket ~ ~ ~ {LifeTime:0,FireworksItem:{id:"firework_rocket",Count:1,tag:{Fireworks:{Explosions:[{Flicker:10,Trail:1,Type:4,Colors:[I;16711680],FadeColors:[I;16711680]},{Flicker:10,Trail:0,Type:1,Colors:[I;65280],FadeColors:[I;65280]}]}}},ShotAtAngle:0b,Motion:[0.0,0.0,0.0]}
execute at @e[tag=!onGround,tag=!inGround,tag=!slimefw,tag=!shockwave] at @e[tag=slimefw,distance=..3] run summon creeper ~ ~ ~ {CustomName:'{"text":"史莱姆烟花","color":"green","italic":"false"}',Fuse:0s,Tags:["shockwave"]}

↑ 烟花+苦力怕式华丽爆炸
这个新版的烟花火箭指令与旧版我发现有两个不同：
①要把FireworksItem:{id:401把401改成英文id “firework_rocket”
②要在每个Colors及FadeColors标签中括号里加大写字母I以及分号。

获得一组史莱姆烟花指令：
/give @p minecraft:slime_spawn_egg{display:{Name:‘{“text”:“史莱姆烟花”,“color”:“green”,“italic”:“false”}’},Enchantments:[{id:“unbreaking”,lvl:10}],HideFlags:1s,EntityTag:{Size:0.1,Silent:1b}} 64
{EntityTag}是一个很有用的标签，表示修改对刷怪蛋刷出来的生物的初始数据，直接嵌入到物品中。

12.蘑菇神功（1.19+）

在某生物上扔一个蘑菇（必须扔在草方块上，不能是草），直接被蘑菇树击飞！

execute at @e[type=item,tag=onGround,nbt={Item:{id:"minecraft:red_mushroom",Count:1b,tag:{display:{Name:'{"text":"蘑菇神功(Q)","italic":"false","color":"red"}'}}}}] run place feature minecraft:huge_red_mushroom ~ ~ ~

生成红色蘑菇树。/place是1.19+的命令。非常厉害。

execute at @e[type=item,tag=onGround,nbt={Item:{id:"minecraft:red_mushroom",Count:1b,tag:{display:{Name:'{"text":"蘑菇神功(Q)","italic":"false","color":"red"}'}}}}] at @e[distance=..3,type=!item,tag=onGround] run tp @s ~ ~16 ~
execute at @e[type=item,tag=onGround,nbt={Item:{id:"minecraft:red_mushroom",Count:1b,tag:{display:{Name:'{"text":"蘑菇神功(Q)","italic":"false","color":"red"}'}}}}] run effect give @e[distance=..3,type=!item,tag=onGround] minecraft:levitation 1 99 true

↑ 将附近生物顶飞。

execute at @e[type=item,tag=onGround,nbt={Item:{id:"minecraft:red_mushroom",Count:1b,tag:{display:{Name:'{"text":"蘑菇神功(Q)","italic":"false","color":"red"}'}}}}] run playsound minecraft:entity.evoker_fangs.attack block @a

↑ （可选）音效。

execute at @e[type=item,tag=onGround,nbt={Item:{id:"minecraft:red_mushroom",Count:1b,tag:{display:{Name:'{"text":"蘑菇神功(Q)","italic":"false","color":"red"}'}}}}] run particle minecraft:entity_effect ~ ~1 ~ 1 3 1 0.1 100 force

↑ （可选）粒子效果。

kill @e[type=item,tag=onGround,nbt={Item:{id:"minecraft:red_mushroom",Count:1b,tag:{display:{Name:'{"text":"蘑菇神功(Q)","italic":"false","color":"red"}'}}}}]

↑ 杀掉物品。
获得一组蘑菇神功：
/give @p minecraft:red_mushroom{display:{Name:‘{“text”:“蘑菇神功(Q)”,“italic”:“false”,“color”:“red”}’},Enchantments:[{id:“unbreaking”,lvl:10}],HideFlags:1s} 64
丢弃使用。

13.悦灵炸弹（1.19+）

仅对手上有东西的悦灵有效！
如果想手上没东西也生效，将nbt={…}删除即可。

execute at @e[type=!player,type=!item,type=!allay,type=!trident,type=!item_frame,type=!minecraft:glow_item_frame] at @e[distance=..3,type=allay,nbt={CanPickUpLoot:1b}] run summon creeper ~ ~ ~ {CustomName:'{"text":"悦灵炸弹","color":"aqua","italic":"false"}',Fuse:0s,Tags:["shockwave"],powered:1b}

悦灵靠近 非玩家（当然，可以改） 生物时爆炸。

execute at @e[type=allay,nbt={CanPickUpLoot:1b}] run particle minecraft:sculk_soul ~ ~ ~ 0.3 0.4 0.3 0.1 1 force

↑（可选）幽匿灵魂粒子(1.19+)。

execute at @e[type=allay,nbt={CanPickUpLoot:1b}] run playsound minecraft:entity.wither.ambient hostile @a[distance=..1]

↑（可选）走进后的凋灵的啸声。

---

持续更新！别忘了点赞关注~