2440间接访问外部存储设备:
CPU通过配置好Memory Controller的寄存器,来让Memory Controller去访问外部的存储设备。这样可以减少CPU去处理一些繁琐的工作。
Memory Controller的结构:
有8个BANK,每个BANK对外引出27条地址线,因此共128Mbit=2^27bit的地址空间,即可寻址空间。因此总共1Gbit。
每个BANK的功能和特性:
总线位宽可编程控制(8 / 16 / 32 bit),但是BANK0只能是16 / 32 bit。BANK(0~5)可外接ROM、SRAM,BANK(6、7)可外接ROM、SRAM和SDRAM。BANK(0~6)的起始地址是固定的,BANK7可编程选择。每个BANK的访问周期可编程控制,可通过外部的“wait”信号延长总线的访问周期。
我们知道2440的CPU是32位的,理论上它有4G Byte的地址可以使用。前面已说到的1G用来给存储控制器Memory Controller连接外设,剩下的3G一部分是CPU内部寄存器的地址,再剩下的就是没使用到的。
tq2440外接了两个32M byte的SDRAM,下面的这种SDRAM有4个逻辑L-BANKs,每个BANK的行地址数是13位、列地址数9位,16个数据IO口,因此这个32M byte=4 x (2^13 x 2^9 ) x 16bit=256Mbit。两块合起来就实现了32位了。SDRAM是储存阵列,每一个单元格就是一个储存单元。
下面是例子展示:代码来自韦东山的《嵌入式Linux应用开发完全手册》
head.S文件:设置SDRAM,将程序复制到SDRAM,然后跳到SDRAM继续执行
.equ MEM_CTL_BASE, 0x48000000
.equ SDRAM_BASE, 0x30000000
.text
.global _start
_start:
bl disable_watch_dog
bl memsetup @ 设置存储控制器
bl copy_steppingstone_to_sdram @ 复制代码到SDRAM中
ldr pc, =on_sdram @ 跳到SDRAM中继续执行
on_sdram:
ldr sp, =0x34000000 @ 设置堆栈,指向SDRAM的顶端
bl main
halt_loop:
b halt_loop
copy_steppingstone_to_sdram:
@ Steppingstone起始地址为0x00000000,SDRAM中起始地址为0x30000000
mov r1, #0
ldr r2, =SDRAM_BASE
mov r3, #4*1024
1:
ldr r4, [r1],#4 @ 从Steppingstone读取4字节的数据,之后让源地址加4
str r4, [r2],#4 @ 将此4字节的数据复制到SDRAM中,之后让目地地址加4
cmp r1, r3 @ 判断是否完成:源地址等于Steppingstone的未地址?
bne 1b @ 若没有复制完,继续。1b:是往后找助记符“1”,若是1f:往前找助记符“1”
mov pc, lr @ 返回
memsetup:
mov r1, #MEM_CTL_BASE @ 存储控制器的13个寄存器的开始地址
adrl r2, mem_cfg_val @ 这13个值的起始存储地址
add r3, r1, #52 @ 13*4 = 54,用于后面的比较
1:
ldr r4, [r2], #4 @ 读取设置值,并让r2加4
str r4, [r1], #4 @ 将此值写入寄存器,并让r1加4
cmp r1, r3 @ 判断是否设置完所有13个寄存器
bne 1b
mov pc, lr @ 返回
.align 4 @内存对齐方式:4字节对齐
mem_cfg_val:
@ 存储控制器13个寄存器的设置值
.long 0x22011110 @ BWSCON .long:定义变量的数据类型为长整型
.long 0x00000700 @ BANKCON0
.long 0x00000700 @ BANKCON1
.long 0x00000700 @ BANKCON2
.long 0x00000700 @ BANKCON3
.long 0x00000700 @ BANKCON4
.long 0x00000700 @ BANKCON5
.long 0x00018005 @ BANKCON6
.long 0x00018005 @ BANKCON7
.long 0x008C07A3 @ REFRESH
.long 0x000000B1 @ BANKSIZE
.long 0x00000030 @ MRSRB6
.long 0x00000030 @ MRSRB7
第1行:0x48000000这个地址是存储控制器的配置寄存器地址的起始地址,结束地址是0x48000030,具体是哪一个要参照s3c2440的芯片手册
第32行:adrl指令用来加载地址,是相对寻址,程序运行到这里的时候才知道被加载的地址值。这条伪指令将基于PC相对偏移的地址值或基于寄存器相对偏移的地址值读取到寄存器中(adr类似)。区别于ldr:ldr是绝对寻址,它不加“=”时是加载地址指向的内容。第44~56行:定义的变量是要赋给存储控制器的配置寄存器的,配置的内容:行地址和列地址位数(看SDRAM芯片手册对应配置2440的寄存器),行列选通信号(SDRAM的行地址线和列地址线是分时复用的,即地址要分两次送出,先行后列)刷新周期,BANKs片选信号,字节写允许信号
小结访问一个芯片的条件:
(1)地址总线:(SDRAM的A0~A12接CPU地址总线的ADDR2~ADDR14)
(2)数据总线:设置数据位宽(SDRAM的位宽为32位,即一次可取出的数据是32位长的,这个要根据2440的原理图)
(3)时钟、频率:关系到cpu访问芯片的频率有多快。未使用PLL时SDRAM的时钟周期为12M。
(4)芯片相关的一些参数(比如上面的配置内容)
(1、2点通常是硬件决定,3、4点是软件设置)