T-SQL象数组一样处理字符串、分割字符串

从目标字符串中查找是否有指定一个或多个子字符串

/**************************************
*fn_FindString
*
*从目标字符串中查找是否有指定一个或多个子字符串
*
*xspf.cn@gmail.com
***************************************/

--@StrDest:目标字符串','分隔
--@StrPattern:需匹配字符串(','分隔)

--返回：找到的所有匹配项

IF EXISTS(SELECT [name] FROM sysobjects WHERE [name] = 'fn_FindString' AND [type] = 'tf')
BEGIN
 DROP FUNCTION fn_FindString
END

GO

CREATE FUNCTION fn_FindString(@StrDest varchar(255),@StrPattern varchar(255))
RETURNS @Result table(substr varchar(31))
AS
BEGIN
 DECLARE @StartPos int,
  @CommaPos int

 DECLARE @DestSubstrTable table(substr varchar(31))
 DECLARE @PatternSubstrTable table(substr varchar(31))

 /*需匹配的字符串拆分为子字符串*/
 SET @StartPos = 0
 SET @CommaPos = CHARINDEX(',',@StrPattern,@StartPos) 

 WHILE(@CommaPos!=0)
 BEGIN
  
  INSERT INTO @PatternSubstrTable VALUES(LTRIM(RTRIM(SUBSTRING(@StrPattern,@StartPos,@CommaPos-@StartPos))))

  SET @StartPos = @CommaPos + 1
  SET @CommaPos = CHARINDEX(',',@StrPattern,@StartPos)
 END

 INSERT INTO @PatternSubstrTable VALUES(LTRIM(RTRIM(SUBSTRING(@StrPattern,@StartPos,LEN(@StrPattern)+1-@StartPos))))

 /*目标字符串拆分为子字符串*/
 SET @StartPos = 0
 SET @CommaPos = CHARINDEX(',',@StrDest,@StartPos) 

 WHILE(@CommaPos!=0)
 BEGIN
  
  INSERT INTO @DestSubstrTable VALUES(LTRIM(RTRIM(SUBSTRING(@StrDest,@StartPos,@CommaPos-@StartPos))))

  SET @StartPos = @CommaPos + 1
  SET @CommaPos = CHARINDEX(',',@StrDest,@StartPos)
 END

 INSERT INTO @DestSubstrTable VALUES(LTRIM(RTRIM(SUBSTRING(@StrDest,@StartPos,LEN(@StrDest)+1-@StartPos))))

 /*结果为目标字符串中所有匹配项*/
 INSERT INTO @Result
 SELECT lhs.* FROM @DestSubstrTable AS lhs JOIN @PatternSubstrTable AS rhs
  ON lhs.subStr = rhs.subStr

 RETURN
 
END

GO

 select * from fn_FindString('10,20,25,26,28,30,32','12,1,20,30')

GO 

---

T-SQL象数组一样处理字符串、分割字符串

T-SQL对字符串的处理能力比较弱，比如我要循环遍历象1,2,3,4,5这样的字符串，如果用数组的话，遍历很简单，但是T-SQL不支持数组，所以处理下来比较麻烦。下边的函数，实现了象数组一样去处理字符串。

一、按指定符号分割字符串，返回分割后的元素个数，方法很简单，就是看字符串中存在多少个分隔符号，然后再加一，就是要求的结果。
CREATE function Get_StrArrayLength
(
 @str varchar(1024),  --要分割的字符串
 @split varchar(10)  --分隔符号
)
returns int
as
begin
 declare @location int
 declare @start int
 declare @length int

 set @str=ltrim(rtrim(@str))
 set @location=charindex(@split,@str)
 set @length=1
 while @location<>0
 begin
   set @start=@location+1
   set @location=charindex(@split,@str,@start)
   set @length=@length+1
 end
 return @length
end
调用示例：select dbo.Get_StrArrayLength('78,1,2,3',',')
返回值：4

二、按指定符号分割字符串，返回分割后指定索引的第几个元素，象数组一样方便
CREATE function Get_StrArrayStrOfIndex
(
 @str varchar(1024),  --要分割的字符串
 @split varchar(10),  --分隔符号
 @index int --取第几个元素
)
returns varchar(1024)
as
begin
 declare @location int
 declare @start int
 declare @next int
 declare @seed int

 set @str=ltrim(rtrim(@str))
 set @start=1
 set @next=1
 set @seed=len(@split)
 
 set @location=charindex(@split,@str)
 while @location<>0 and @index>@next
 begin
   set @start=@location+@seed
   set @location=charindex(@split,@str,@start)
   set @next=@next+1
 end
 if @location =0 select @location =len(@str)+1
--这儿存在两种情况：1、字符串不存在分隔符号 2、字符串中存在分隔符号，跳出while循环后，@location为0，那默认为字符串后边有一个分隔符号。
 
 return substring(@str,@start,@location-@start)
end
调用示例：select dbo.Get_StrArrayStrOfIndex('8,9,4',',',2)
返回值：9

三、结合上边两个函数，象数组一样遍历字符串中的元素

declare @str varchar(50)
set @str='1,2,3,4,5'
declare @next int  
set @next=1
while @next<=dbo.Get_StrArrayLength(@str,',')
begin
 print dbo.Get_StrArrayStrOfIndex(@str,',',@next)
 set @next=@next+1
end

调用结果：
1
2
3
4
5