在Delphi XE的TStringGrid中使用TComboBox作为单元格编辑器

需要进行以下几步：

1. 创建StringGrid，在OnSelectCell事件中显示ComboBox覆盖单元格作为编辑器
2. 创建ComboBox，将其Parent设置为StringGrid，并将StringGrid的行高设置为ComboBox的高度
3. 处理ComboBox的OnChange事件，修改StringGrid单元格的值
4. 处理ComboBox的OnExit事件，隐藏ComboBox
5. 创建新单元，定义同名类TStringGrid继承Vcl.Grids.TStringGrid并重写其WMCommand方法
6. 在使用StringGrid的单元头部引用新单元，必须放在Vcl.Grids之后

以下是示例代码：

单元1：

点击(此处)折叠或打开

1. unit Unit1;
   
2. 
   
3. interface
   
4. 
   
5. uses
   
6.   Winapi.Windows, Winapi.Messages, System.SysUtils, System.Classes,
   
7.   Vcl.Controls, Vcl.Forms, Vcl.StdCtrls, Vcl.Grids,
   
8.   //必须将重定义的TStringGrid单元引用放置在Vcl.Grids之后
   
9.   Unit2;
   
10. 
    
11. type
    
12.   TForm1 = class(TForm)
    
13.     StringGrid1: TStringGrid;
    
14.     procedure FormCreate(Sender: TObject);
    
15.     procedure StringGrid1SelectCell(Sender: TObject; ACol, ARow: Integer;
    
16.       var CanSelect: Boolean);
    
17.   private
    
18.     FComboBox: TComboBox;
    
19.     procedure OnComboBoxChange(Sender: TObject);
    
20.     procedure OnComboBoxExit(Sender: TObject);
    
21.     { Private declarations }
    
22.   public
    
23.     { Public declarations }
    
24.   end;
    
25. 
    
26. var
    
27.   Form1: TForm1;
    
28. 
    
29. implementation
    
30. 
    
31. {$R *.dfm}
    
32. 
    
33. procedure TForm1.FormCreate(Sender: TObject);
    
34. begin
    
35.   //创建ComboBox，也可以直接拖拽到Form
    
36.   //此处只需要设置Parent := StringGrid1
    
37.   FComboBox := TComboBox.Create(StringGrid1);
    
38.   FComboBox.Parent := StringGrid1;
    
39.   FComboBox.Items.Add('Item1');
    
40.   FComboBox.Items.Add('Item2');
    
41.   FComboBox.OnChange := OnComboBoxChange;
    
42.   FComboBox.OnExit := OnComboBoxExit;
    
43.   FComboBox.Visible := False;
    
44.   //ComboBox高度是固定不能改变的
    
45.   //因此设置StringGrid1的行高与ComboBox高度一致
    
46.   StringGrid1.DefaultRowHeight := FComboBox.Height;
    
47. end;
    
48. 
    
49. procedure TForm1.OnComboBoxChange(Sender: TObject);
    
50. begin
    
51.   StringGrid1.Cells[StringGrid1.Col, StringGrid1.Row] := FComboBox.Text;
    
52. end;
    
53. 
    
54. procedure TForm1.OnComboBoxExit(Sender: TObject);
    
55. begin
    
56.   FComboBox.Visible := False;
    
57. end;
    
58. 
    
59. procedure TForm1.StringGrid1SelectCell(Sender: TObject; ACol, ARow: Integer;
    
60.   var CanSelect: Boolean);
    
61. var
    
62.   ARect: TRect;
    
63. begin
    
64.   //示例代码仅在第二列中使用ComboBox作为编辑器
    
65.   if CanSelect and (ACol = 1) then
    
66.   begin
    
67.     FComboBox.ItemIndex := FComboBox.Items.IndexOf
    
68.       (StringGrid1.Cells[ACol, ARow]);
    
69.     //使ComboBox显示并覆盖住选中单元格
    
70.     ARect := StringGrid1.CellRect(ACol, ARow);
    
71.     FComboBox.Left := ARect.Left;
    
72.     FComboBox.Top := ARect.Top;
    
73.     FComboBox.Width := ARect.Right - ARect.Left;
    
74.     FComboBox.Visible := True;
    
75.     FComboBox.SetFocus;
    
76.   end;
    
77. end;
    
78. 
    
79. end.

单元2：

点击(此处)折叠或打开

1. unit Unit2;
   
2. 
   
3. interface
   
4. 
   
5. uses
   
6.   Vcl.Grids, Winapi.Windows, Winapi.Messages, Vcl.Controls;
   
7. 
   
8. type
   
9.   TStringGrid = class(Vcl.Grids.TStringGrid)
   
10.   private
    
11.     procedure WMCommand(var AMessage: TWMCommand); message WM_COMMAND;
    
12.   end;
    
13. 
    
14. implementation
    
15. 
    
16. { TStringGrid }
    
17. 
    
18. procedure TStringGrid.WMCommand(var AMessage: TWMCommand);
    
19. begin
    
20.   //如果当前是StringGrid内置编辑框，调用父类方法
    
21.   //否则向控件发送CN_COMMAND事件
    
22.   if (InplaceEditor <> nil) and (AMessage.Ctl = InplaceEditor.Handle) then
    
23.     inherited
    
24.   else if AMessage.Ctl <> 0 then
    
25.   begin
    
26.     AMessage.Result := SendMessage(AMessage.Ctl, CN_COMMAND,
    
27.       TMessage(AMessage).WParam, TMessage(AMessage).LParam);
    
28.   end;
    
29. end;
    
30. 
    
31. end.

说明：

1. TStringGrid只支持内置的输入框做为单元格编辑器，所以只好放置一个ComboBox并覆盖住要编辑的单元格
2. TStringGrid祖先类TCustomGrid在WMCommand方法中限制了只处理InplaceEditor，所以需要重写这个方法

也可以继承TStringGrid而不是使用同名类，再全部动态创建，但是太麻烦而且基本没什么区别

来自 “ ITPUB博客 ” ，链接：http://blog.itpub.net/634491/viewspace-2155218/，如需转载，请注明出处，否则将追究法律责任。

转载于:http://blog.itpub.net/634491/viewspace-2155218/