IaC基础设施即代码：Terraform 连接 huaweicloud OBS 实现多资源管理

已于 2024-01-26 14:59:39 修改
阅读量1.2k 收藏 23
点赞数 29
分类专栏： IaC基础设施即代码 文章标签： terraform 云原生 云计算 运维 华为云
于 2024-01-25 16:15:59 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/cronaldo91/article/details/135840807
版权

目录

  一、实验

1.环境

 2.Terraform 连接 huaweicloud OBS

3.申请VPC专有网络资源

4.申请安全组资源

5.申请ECS资源

6.申请EIP资源

7.申请ELB资源

8.申请DNS资源

8.销毁资源

二、问题

1. Terraform申请云主机失败

2.存储桶无法删除

  一、实验

1.环境

（1）主机

表1-1 主机

主机系统软件工具备注
jia

Windows 

Terraform 1.6.6VS Code、 PowerShell、 Chocolatey

 2.Terraform 连接 huaweicloud OBS

（1）验证版本

terraform version

terraform -v

（2）连接

参考本人上一篇博客：

IaC基础设施即代码：使用Terraform 连接huaweicloud华为云 并创建后端OBS-CSDN博客

3.申请VPC专有网络资源

（1）查看目录

 （2）创建主配置文件

main.tf

# Configuration options
provider "huaweicloud" {
  access_key = var.access_key
  secret_key = var.secret_key
  region     = var.region
}

(3) 创建密钥配置文件

terraform.tfvars

access_key = "XXXXX"
secret_key = "XXXXX"

（4）创建版本配置文件

versions.tf

terraform {
  required_providers {
    huaweicloud = {
      source  = "local-registry/huaweicloud/huaweicloud"
      version = "1.60.1"
    }
  }
}

(5)创建变量配置文件

variables.tf

variable "access_key" {
  type = string
}

variable "secret_key" {
  type = string
}

variable "region" {
  type      = string
  default   = "cn-east-3"
  sensitive = true
}

（6）创建后端配置文件

backend.tf

(8) 初始化

terraform init

（7）格式化代码

terraform fmt

（8）验证代码

terraform validate

(9) 创建网络模块

主配置文件 main.tf

resource "huaweicloud_vpc" "vpc" {
  name = var.vpc_name
  cidr = var.vpc_cidr
}

resource "huaweicloud_vpc_subnet" "subnet" {
  name       = var.subnet_name
  cidr       = var.subnet_cidr
  gateway_ip = var.subnet_gateway_ip
  vpc_id     = huaweicloud_vpc.vpc.id
  availability_zone = var.availability_zone
}

变量配置文件 variables.tf

variable "vpc_name" {
}

variable "vpc_cidr" {
  
}
variable "subnet_name" {
  
}

variable "subnet_cidr" {
  
}

variable "availability_zone" {
  
}

variable "subnet_gateway_ip" {
  
}

版本配置文件 versions.tf

terraform {
  required_providers {
    huaweicloud = {
      source  = "local-registry/huaweicloud/huaweicloud"
      version = "1.60.1"
    }
  }
}

(10)查看网络模块目录

（11）创建专有网络资源配置文件

vpc.tf

locals {
  vpc_cidr          = "192.168.0.0/16"
  vpc_name          = "dev-vpc"
  subnet_name       = "dev-subnet"
  subnet_cidr       = "192.168.0.0/21"
  subnet_gateway_ip = "192.168.0.1"
  availability_zone = "cn-east-3a"
}

module "dev-vpc" {
  source            = "../../../modules/vpc"
  vpc_cidr          = local.vpc_cidr
  vpc_name          = local.vpc_name
  subnet_cidr       = local.subnet_cidr
  subnet_gateway_ip = local.subnet_gateway_ip
  subnet_name       = local.subnet_name
  availability_zone = local.availability_zone

}

（12）查看网路服务目录

（13） 初始化

terraform init

（14）格式化代码

terraform fmt

（15）验证代码

terraform validate

（16）计划与预览

 terraform plan

2个资源将要被添加

（17）申请资源

terraform apply

yes

（18）登录华为云系统查看

存储桶已添加网络服务配置文件

私有网络

子网

路由表

4.申请安全组资源

（1） 创建安全组模块

主配置文件 main.tf

resource "huaweicloud_networking_secgroup" "secgroup" {
  name        = var.secgroup_name
  description = var.secgroup_desc
}

resource "huaweicloud_networking_secgroup_rule" "secgroup_rule_80" {
  security_group_id = huaweicloud_networking_secgroup.secgroup.id
  direction         = "ingress"
  ethertype         = "IPv4"
  protocol          = "tcp"
  port_range_min    = 80
  port_range_max    = 80
  remote_ip_prefix  = "0.0.0.0/0"
}

resource "huaweicloud_networking_secgroup_rule" "secgroup_rule_22" {
  security_group_id = huaweicloud_networking_secgroup.secgroup.id
  direction         = "ingress"
  ethertype         = "IPv4"
  protocol          = "tcp"
  port_range_min    = 22
  port_range_max    = 22
  remote_ip_prefix  = "0.0.0.0/0"
}

resource "huaweicloud_networking_secgroup_rule" "allsecgroup_rule" {
  security_group_id = huaweicloud_networking_secgroup.secgroup.id
  direction         = "egress"
  ethertype         = "IPv4"
  protocol          = "tcp"
  port_range_min    = 1
  port_range_max    = 65535
  remote_ip_prefix  = "0.0.0.0/0"
}

变量配置文件 variables.tf

variable "secgroup_name" {
  
}

variable "secgroup_desc" {
  
}

版本配置文件 versions.tf

terraform {
  required_providers {
    huaweicloud = {
      source  = "local-registry/huaweicloud/huaweicloud"
      version = "1.60.1"
    }
  }
}

(2)查看安全组模块目录

（3）创建安全配置文件

secgroup.tf

locals {
  secgroup_name = "dev-secgroup"
  secgroup_desc = "dev group"
}

module "dev-secgroup" {
  source        = "../../../modules/secgroup"
  secgroup_name = local.secgroup_name
  secgroup_desc = local.secgroup_desc

}

（4）创建输出配置文件

output "vpc_id" {
  value = module.dev-vpc.vpc_id
}

output "subnet_id" {
  value = module.dev-vpc.subnet_id
}

output "subnet_subnet_id" {
  value = module.dev-vpc.subnet_subnet_id
}

output "secgroup_id" {
  value = module.dev-secgroup.secgroup_id
}

（5）查看网络服务目录

（6）  初始化

terraform init

（7）格式化代码

terraform fmt

（8）验证代码

terraform validate

（8）计划与预览

 terraform plan

（9）申请资源

terraform apply

yes

（10）登录华为云系统查看

安全组

入方向规则

出方向规则

5.申请ECS资源

（1）查看目录

 （2）创建配置文件

主配置文件main.tf 、密钥配置文件terraform.tfvars、版本配置文件versions.tf 与之前的网络服务相同。

（3）创建后端配置文件

backend.tf

(4)  修改主配置文件

main.tf

(5) 初始化

terraform init

（6）创建云主机模块

主配置文件main.tf

resource "huaweicloud_compute_instance" "basic" {
  name               = var.instance_name
  image_id           = var.image_id
  flavor_id          = var.flavor_id
  security_group_ids = [var.secgroup_id]
  availability_zone  = var.availability_zone
  user_data          = <<-EOF
                        #!/bin/bash 
                        yum -y install nginx 
                        echo `hostname` >/usr/share/nginx/html/index.html
                        systemctl restart nginx 
                        EOF
  admin_pass        = "devops@123"

  network {
    uuid = var.subnet_id
  }

  lifecycle {
    create_before_destroy = true
  }
}

输出配置文件outputs.tf

output "instance_id" {
    value = huaweicloud_compute_instance.basic.id
  
}

output "instance_ip" {
    value = huaweicloud_compute_instance.basic.access_ip_v4
}

变量配置文件cariables.tf

variable "instance_name" {
  
}

variable "flavor_id" {
  
}

variable "image_id" {
  
}

variable "secgroup_id" {
  
}
variable "availability_zone" {
  
}
variable "subnet_id" {
  
}

variable "vpc_id" {
  
}

版本配置文件versions.tf

terraform {
  required_providers {
    huaweicloud = {
      source  = "local-registry/huaweicloud/huaweicloud"
      version = "1.60.1"
    }
  }
}

（7）查看云主机模块

(8) 创建云主机配置文件

ecs.tf

locals {
  availability_zone = "cn-east-3a"
}

data "huaweicloud_compute_flavors" "flavor_1C1G" {
  availability_zone = local.availability_zone
  performance_type  = "normal"
  cpu_core_count    = 1
  memory_size       = 1
}

output "ecs_flavor" {
  value = data.huaweicloud_compute_flavors.flavor_1C1G.ids[0]
}

data "huaweicloud_images_image" "image" {
  architecture = "x86"
  os_version   = "CentOS 7.9 64bit"
  visibility   = "public"
  most_recent  = true
}

output "image_id" {
    value = data.huaweicloud_images_image.image.id

}

(9) 计划与预览

 terraform plan

拿到镜像id和实例类型

（10）修改云主机配置文件

ecs.tf ，添加如下代码

locals {
  availability_zone = "cn-east-3a"
    flavor_id         = data.huaweicloud_compute_flavors.flavor_1C1G.ids[0]
    instance_name     = "dev-ecs"
    counts            = 2
    subnet_id         = data.terraform_remote_state.network.outputs.subnet_id
    vpc_id            = data.terraform_remote_state.network.outputs.vpc_id
    image_id          = data.huaweicloud_images_image.image.id
    secgroup_id       = data.terraform_remote_state.network.outputs.secgroup_id
}

module "dev-ecs" {
  source            = "../../../modules/ecs"
  count             = local.counts
  availability_zone = local.availability_zone
  flavor_id         = local.flavor_id
  instance_name     = "${local.instance_name}-${count.index}"
  subnet_id         = local.subnet_id
  vpc_id            = local.vpc_id
  image_id          = local.image_id
  secgroup_id       = local.secgroup_id

}

（11）初始化

terraform init

（12）格式化代码

terraform fmt

（13）验证代码

terraform validate

（14）修改云主机配置文件

ecs.tf

  os_version   = "CentOS 8.0 64bit"

（15）计划与预览

 terraform plan

（16）申请资源

terraform apply

yes

(17) 登录华为云系统查看

已新增2台云主机

（18）远程登录

（18）登录成功

(29) 查看存储桶

已新增service配置文件

（21）查看服务目录

6.申请EIP资源

 （1）创建EIP模块

主配置文件main.tf

// 共享带宽
resource "huaweicloud_vpc_bandwidth" "bandwidth_1" {
  name = var.bandwidth_name
  size = 5
}

// EIP
resource "huaweicloud_vpc_eip" "eip" {
  count = length(var.instances)
  publicip {
    type = "5_bgp"
  }
  bandwidth {
    share_type = "WHOLE"
    id         = huaweicloud_vpc_bandwidth.bandwidth_1.id
  }
}

// 关联
resource "huaweicloud_compute_eip_associate" "associated" {
  count = length(var.instances)
  public_ip   = huaweicloud_vpc_eip.eip.*.address[count.index]
  instance_id = var.instances[count.index]
}

输出配置文件outputs.tf

output "bandwidth_id" {
  value = huaweicloud_vpc_bandwidth.bandwidth_1.id
}

变量配置文件variables.tf

variable "bandwidth_name" {
  
}


variable "instances" {
  
}

版本配置文件versions.tf

terraform {
  required_providers {
    huaweicloud = {
      source  = "local-registry/huaweicloud/huaweicloud"
      version = "1.60.1"
    }
  }
}

（7）查看EIP模块

(8) 创建EIP配置文件

eip.tf

locals {
  bandwidth_name = "dev-bandwidth"
  instances      = module.dev-ecs.*.instance_id
}


module "dev-eip" {
  source         = "../../../modules/eip"
  bandwidth_name = local.bandwidth_name
  instances      = local.instances
}

(9) 初始化

terraform init

(10)格式化代码

terraform fmt

(11)验证代码

terraform validate

(12)计划与预览

 terraform plan

5个资源将要被添加 （1个共享带宽组、2个ECS实例、2个关联）

（13）申请资源

terraform apply

yes

(14)登录华为云查看

弹性公网IP

共享带宽

弹性云服务器已新增公网IP

（15）修改云主机配置文件

ecs.tf

os_version   = "CentOS 8.1 64bit"

（16） 计划与预览

 terraform plan

先销毁旧的2个实例，再新建2个新的实例

（17） 申请资源

terraform apply

yes

（18）观察云主机变化

新增2个新实例

运行中

弹性公网已绑定

正在删除旧实例

已删除旧实例

（19）访问

7.申请ELB资源

 1）创建ELB模块

主配置文件main.tf

resource "huaweicloud_lb_loadbalancer" "lb" {
  vip_subnet_id = var.subnet_id
}

resource "huaweicloud_lb_listener" "listener" {
  protocol        = "HTTP"
  protocol_port   = 80
  loadbalancer_id = huaweicloud_lb_loadbalancer.lb.id
}

resource "huaweicloud_lb_pool" "pool" {
  protocol    = "HTTP"
  lb_method   = "ROUND_ROBIN"
  listener_id = huaweicloud_lb_listener.listener.id

  persistence {
    type        = "APP_COOKIE"
    cookie_name = "testCookie"
  }
}

resource "huaweicloud_lb_member" "member" {
  count = length(var.instance_ips)
  address       = var.instance_ips[count.index]
  protocol_port = 80
  pool_id       = huaweicloud_lb_pool.pool.id
  subnet_id     = var.subnet_id
}

输出配置文件outputs.tf

output "elb_vip_port_id" {
    value = huaweicloud_lb_loadbalancer.lb.vip_port_id
}

变量配置文件variables.tf

variable "subnet_id" {
  
}

variable "instance_ips" {
  
}

版本配置文件versions.tf

terraform {
  required_providers {
    huaweicloud = {
      source  = "local-registry/huaweicloud/huaweicloud"
      version = "1.60.1"
    }
  }
}

（7）查看ELB模块

(8) 创建ELB配置文件

elb.tf

module "dev-elb" {
  source       = "../../../modules/elb"
  subnet_id    = data.terraform_remote_state.network.outputs.subnet_subnet_id
  instance_ips = module.dev-ecs.*.instance_ip
}

(9) 初始化

terraform init

(10)格式化代码

terraform fmt

(11)验证代码

terraform validate

(12)计划与预览

 terraform plan

5个资源将要被添加

（13）申请资源

terraform apply

yes

(14)登录华为云查看

已新增负载均衡

后端服务器组

 监听方式(RR轮询)

（15）修改EIP配置文件

eip.tf,添加如下代码，实现绑定负载均衡

//ELB-EIP
resource "huaweicloud_vpc_eip" "elb-eip" {
  publicip {
    type = "5_bgp"
  }
  bandwidth {
    share_type = "WHOLE"
    id         = module.dev-eip.bandwidth_id
  }
}
resource "huaweicloud_networking_eip_associate" "eip_elb" {
  public_ip = huaweicloud_vpc_eip.elb-eip.address
  port_id   = module.dev-elb.elb_vip_port_id
}

（16）创建输出配置文件

outputs.tf

output "slb_eip_address" {
  value = huaweicloud_vpc_eip.elb-eip.address

}

 (17) 初始化

terraform init

(18)格式化代码

terraform fmt

(19)验证代码

terraform validate

(20)计划与预览

 terraform plan

2个资源将要被添加

（21）申请资源

terraform apply

yes

（16）华为云系统查看

负载均衡已添加EIP

（17）访问（刷新）

实现轮询

8.申请DNS资源

（1）创建域名

(2) 查看

（3）创建DNS配置文件

dns.tf

(3)  计划与预览

 terraform plan

(4) 申请资源

terraform apply

yes

（5）登录华为云系统查看

云解析DNS

（6）访问

轮询显示

（7）测试

 dig devops.hexian.site

8.销毁资源

  (1) 销毁服务资源

terraform destroy

yes ,15个资源将要被删除

（2）销毁网络资源

terraform destroy

yes,6个资源将要被删除

（3）登录华为云系统查看

云主机 已删除

DNS云解析已移除

ELB负载均衡已删除

存储桶

（4）查看完整目录

网络network与服务service

模块modules

二、问题

1. Terraform申请云主机失败

（1）报错

│ Error: error creating server: Bad request with: [POST https://ecs.cn-east-3.myhuaweicloud.com/v1.1/890711b0c9894f1db268f9a82f3affb9/cloudservers], request_id: d6d2706a57ef3b514e1d9a684a4e3f65, error message: {"error":{"message":"The flavor does not match the image.","code":"Ecs.0005"}}
│
│   with module.dev-ecs[1].huaweicloud_compute_instance.basic,
│   on ..\..\..\modules\ecs\main.tf line 1, in resource "huaweicloud_compute_instance" "basic":
│    1: resource "huaweicloud_compute_instance" "basic" {
│
╵
╷
│ Error: error creating server: Bad request with: [POST https://ecs.cn-east-3.myhuaweicloud.com/v1.1/890711b0c9894f1db268f9a82f3affb9/cloudservers], request_id: b18522c96ac4c1985012dc15a1574eea, error message: {"error":{"message":"The flavor does not match the image.","code":"Ecs.0005"}}
│
│   with module.dev-ecs[0].huaweicloud_compute_instance.basic,
│   on ..\..\..\modules\ecs\main.tf line 1, in resource "huaweicloud_compute_instance" "basic":
│    1: resource "huaweicloud_compute_instance" "basic" {

（2）原因分析

通用计算型 | s3.small.1 | 1vCPUs | 1GiB 不支持CentOS 7.9服务器64位，

（3）解决方法

修改为CentOS 8.0服务器64位。

修改前：

修改后：

成功：

2.存储桶无法删除

（1）查看

（2）删除

(3) 对象

（4）确定

（5）再次删除

（6）验证

（7）成功

cronaldo91
关注
  • 29
    点赞
  • 踩
  • 23
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
tads-boilerplate：Terraform + Ansible + Docker Swarm模板= DevOps on | 基础架构即代码
01-30
创建完整的基础架构即代码（IaC）存储库的样板，从供应到部署均使用以下方法： Terraform创建您的云基础架构流浪汉在本地重现类似于生产的环境Ansible来配置虚拟机，并成立了泊坞群簇再次Ansible部署您的书库它处理...
terraform-infra-as-code-coverage-badges：Terraform基础结构即代码覆盖标志-Terraform管理您的AWS多少基础结构？
01-30
在IT行业中，基础结构即代码（Infrastructure as Code，IaC）是一种管理IT资源的方式，它将基础设施的配置描述为可版本控制的代码。Terraform是HashiCorp公司推出的一种流行的IaC工具，允许用户用声明式语言定义和...
使用Terraform来玩转华为云1-准备工作
chengxunhg的博客
06-04 1127
terraform 工具准备 https://www.terraform.io/downloads.html 选择对应平台的版本，例如 macOS 或者 Linux 下载，解压，可以放到 /usr/local/bin/ 目录下 $terraform-v Terraformv0.11.11 YourversionofTerraformisoutofdate!...
Terraform 华为云最佳实践
热门推荐
小楼一夜听春雨，深巷明朝卖杏花
11-28 1万+
之后在network下面创建其backend。}}配置好backend之后就去init一下。init完之后就去模块化资源，然后创建vpc和安全组。（反正就是注意使用variable去定义模块需要传入的参数和output模块需要输出的参数）注意vpc里面需要设置gateway的IP，这是一个特殊的地方。}}接下来就是创建安全组和规则了。网络这块是单独使用state进行存储的，后面在创建ecs和service的时候，需要使用到这里的输出，所以需要将vpc和subnet的id都得拿出来。
Terraform 华为云实践 项目初始化
小楼一夜听春雨，深巷明朝卖杏花
10-31 4196
这个架构就是DNS加上负载均衡加ecs，最后vpc的架构。网络这块是DNS和VPC，对象存储是用来做terraform的后端来配置。
IaC基础设施即代码：使用Terraform 连接huaweicloud华为云 并创建后端OBS
cronaldo91的博客
01-25 1382
手工下载华为云 provider至本地目录，然后搭建本地registry并修改 terraform块中的required_providers配置。国内用户在下载 Provider 时会遇到下载缓慢甚至下载失败的问题。（7）查看tentcloud provider 示例。yes ,系统上传配置文件到华为云OBS。（1）登录 （统一身份认证）（11）创建后端存储配置文件。（8）华为云查看OBS服务。（10）登录华为云系统查看。（13）登录华为云系统查看。(3) 创建密钥配置文件。（15）删除项目配置文件。
【云原生】基于Kubevela华为云的Terraform addon开发
在数字化道路无限探索
07-15 620
kubevela 的 terraform addon 插件是通过 controllor和 crd(Provider，Configuration)来实现和 terraform 一样的功能。 其核心原理在于terraform controllor通过监控Provider、Configuration 的变更来实现具体的操作。
IaC基础设施即代码：Terraform 连接 aws S3 实现多资源管理
cronaldo91的博客
01-18 1157
terraform.tfvars、variables.tf 、versions.tf 配置文件与 global/backend下的配置文件相同。私钥名称改为myecs_private_key.pem，公钥名称改为myecs_public_key.pub。将vpc,tf 的locals 字段 移动到main.tf，并添加端口信息。（3）创建默认变量配置文件（存储IAM密钥）（10）查看aws provider 示例。vpc.tf，添加子网subnet信息。main.tf ，添加如下代码。
IaC基础设施即代码：Terraform 连接 alicloud OSS 实现多资源管理
cronaldo91的博客
01-17 1419
env\dev存放实例的配置文件，global\backend存放后端配置文件，modules存放模块文件。（5）密钥、变量、版本配置文件与global\backend相同。env\dev下创建network存放网络资源实例的配置文件。env\dev下network存放网络资源实例的配置文件。（6）修改网络资源的输出配置文件(添加安全组id的输出)env\dev下ecs存放云主机资源实例的配置文件。（2）修改主配置文件(安全组附加到VPC)（1）修改modules的ecs主配置文件。
基础设施即代码(IAC)，Zalando Postgres Operator 简介.doc
07-13
基础设施即代码(IAC)，Zalando Postgres Operator 简介 在当前的云计算时代，基础设施即代码(IAC)已经成为潮流，Zalando Postgres Operator 正是这种趋势的代表。作为一种基于 Kubernetes 的 PostgreSQL 集群管理...
iac-strategies:云计算中的Kubernetes，terraform，docker和基础架构即代码策略
03-27
总而言之，云计算中的 IAC 策略涉及 Kubernetes 的容器编排、Docker 的容器化应用、Terraform 的基础设施管理，以及在各大云平台上实现这些策略的具体方法。通过掌握这些技术和工具，IT 专业人员能够构建高效、可靠...
terraform-associate：Terraform Associate认证考试的资源
02-04
在IT行业中，Terraform是一种流行的基础设施即代码（IAC）工具，用于自动化云环境的配置和管理。Terraform Associate认证是针对那些希望验证自己对Terraform基础理解和应用能力的专业人士设立的。这个“terraform-...
【Terraform学习】Terraform_count使用（Terraform配置语言学习）
zerotoall的博客
08-15 534
【Terraform学习】Terraform_count使用（Terraform配置语言学习） resource "aws_iam_user" "lb" { name = var.elb_names[count.index] count = 3 path = "/sys/" } 接下来，编辑main.tf以使用count根据新变量的值和私有子网的数量为 EC2 实例预置资源块。
5 大场景上手通义灵码企业知识库 RAG
阿里巴巴云原生的博客
08-12 881
大家好，我是通义灵码，你的智能编程助手！最近我又升级啦，智能问答功能全面升级至 Qwen2，新版本在各个方面的性能和准确性都得到了显著提升。此外，行间代码补全效果也全面优化，多种编程语言生成性能及准确性大幅提升，如前端、Java、Go、Python、C++ 等。此外，灵码新增代码提交信息（Commit Message）生成，支持 Visual Studio 端。
【kubernetes】k8s配置资源管理
最新发布
qq_54188720的博客
08-14 747
configMap资源（简称cm）作用：用于保存配置文件、环境变量等不需要加密的信息。它可以实现将配置信息与应用程序镜像解耦创建cm资源kubectl create cm <资源名称> -n <命名空间> --from-file=文件|目录 --from-liternal=<键名>=<键值>查看cm资源kubectl describe -n <命名空间> cm <资源名称>kubectl get -n <命名空间> cm <资源名称> -o yaml。
微服务架构
Kang
08-14 888
微服务架构
征服云端：Kubernetes如何让微服务与云原生技术如虎添翼
qq_44771627的博客
08-14 514
在这个数字化转型的时代，微服务架构已经成为构建现代应用程序的首选方式。它不仅提高了开发效率，还增强了系统的可扩展性和灵活性。而随着云计算技术的迅猛发展，**云原生**的概念逐渐深入人心，它代表了一种全新的软件开发方法论，旨在利用云基础设施的优势来构建和运行可伸缩的应用程序。在这一背景下，Kubernetes（简称K8s）作为容器编排领域的佼佼者，其重要性不言而喻。本文将深入探讨Kubernetes在微服务与云原生技术中的应用，通过一系列基础和高级实例，帮助你掌握Kubernetes集群管理的关键技能。
Kubernetes之Probe探针
qq_63627848的博客
08-14 1124
探针probe的概念和配置
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值