C++中引用OC类

问题描述:
使用OC封装了GameCenter的一些特性,然后在一个.mm的工具类中引用OC封装的工具类(在mm文件对应的.h中引用)。然后所有引用这个mm的.cpp文件会报错。
问题分析:循环应用之后,导致纯C++的头文件中引用了OC的头文件
原因:对于预处理器而言,它只做文本的替换操作。所以#include和#import本质上就是递归地复制和粘贴引用文件的内容。所以当循环引用替换之后,会在cpp中出现OC的定义,导致报错。
解决方法:
1、如果可以在.mm的对应的.h中不引用oc的.h的话,可以将oc头文件的引用修改到.mm中。(或用class声明替代#include引用)
2、使用PIMPL,具体请参考下文。

参考:
英文原文:
http://philjordan.eu/article/strategies-for-using-c++-in-objective-c-projects
http://philjordan.eu/article/strategies-for-using-c++-in-objective-c-projects

回顾一下

简言之,如果你有一些C++代码或库,你想在Objective-C项目使用它,这就是我们要研究的问题。通常,C++代码中会定义你要使用的一些类(class),你可以简单的把.m文件扩展名改为.mm就可以改为Objective-C++编译,然后就可以很容易地混合使用C++和Objective-C的代码。这是一个简单的做法,但两个世界确实很不一样,如此这样的深度混合有时会变地很棘手。

你可能会想使用等价的Objective-C类型和函数将C++代码封装(wrap)起来。比方说,你有一个名为CppObject的C++类(CppObject.h):
  1. #include   
  2. class CppObject  
  3. {  
  4. public:  
  5.   void ExampleMethod(const std::string& str);  
  6.   // constructor, destructor, other members, etc.  
  7. };  

在Objectiv-C类允许定义C++类的成员变量,所以可以首先尝试定义一个ObjcObject封装类(ObjcObject.h):
  1. #import   
  2. #import "CppObject.h"  
  3.   
  4.   
  5. @interface ObjcObject : NSObject {  
  6.   CppObject wrapped;  
  7. }  
  8. - (void)exampleMethodWithString:(NSString*)str;  
  9. // other wrapped methods and properties  
  10. @end  


然后在ObjcObject.mm中实现这些方法。不过,此时会在两个头文件(ObjcObject.h&CppObject.h)中得到一个预处理和编译错误。问题出在#include和#import上。对于预处理器而言,它只做文本的替换操作。所以#include和#import本质上就是递归地复制和粘贴引用文件的内容。这个例子中,使用#import"ObjcObject.h"等价于插入如下代码:

  1. // [首先是大量Foundation/Foundation.h中的代码]  
  2. // [无法包含],因为它仅存在于C++模式的include path中  
  3. class CppObject  
  4. {  
  5. public:  
  6.   void ExampleMethod(const std::string& str);  
  7.   // constructor, destructor, other members, etc.  
  8. };  
  9.   
  10.   
  11. @interface ObjcObject : NSObject {  
  12.   CppObject wrapped;  
  13. }  
  14. - (void)exampleMethodWithString:(NSString*)str;  
  15. // other wrapped methods and properties  
  16. @end  

因为classCppObject根本不是有效的Objective-C语法, 所以编译器就被搞糊涂了。 错误通常是这样的:
Unknown type name 'class'; didyou mean 'Class'?
 
正是因为Objective-C中没有class这个关键字.所以要与Objective-C兼容,Objective-C++类的头文件必须仅包含Objective-C代码,绝对没有C++的代码 -这主要是影响类型定义(就像例中的CppObject类)。

保持简洁的头文件
之前的文章已经提到一些解决方案.其中最好的一个是PIMPL,它也适用于现在的情况。这里还有一个适用于clang的新方法,可以将C++代码从Objective-C中隔开,这就是classextensions中ivars的。 

Class extensions (不要同categories弄混)已经存在一段时间了: 它们允许你在class的接口外的扩展部分定义在@implementation段前,而不是在公共头文件中。这个例子就可以声明在ObjcObject.mm中:
  1. #import "ObjcObject.h"  
  2. @interface ObjcObject () // note the empty parentheses  
  3. - (void)methodWeDontWantInTheHeaderFile;  
  4. @end  
  5. @implementation ObjcObject  
  6. // etc.  


GCC也支持这个操作。不过clang还支持添加ivar块,也就是你还可以声明C++类型的实例变量,既可以在classextension中,也可以在@implementation开始的位置。本例中的ObjcObject.h可以被精简为:

  1. #import   
  2.   
  3.   
  4. @interface ObjcObject : NSObject  
  5. - (void)exampleMethodWithString:(NSString*)str;  
  6. // other wrapped methods and properties  
  7. @end  

 

去掉的部分都移到实现文件的classextension中 (ObjcObject.mm):

  1. #import "ObjcObject.h"  
  2. #import "CppObject.h"  
  3. @interface ObjcObject () {  
  4.   CppObject wrapped;  
  5. }  
  6. @end  
  7.   
  8.   
  9. @implementation ObjcObject  
  10. - (void)exampleMethodWithString:(NSString*)str  
  11. {  
  12.   // NOTE: str为nil会建立一个空字串,而不是引用一个指向UTF8String空指针.   
  13.   std::string cpp_str([str UTF8String], [str lengthOfBytesUsingEncoding:NSUTF8StringEncoding]);  
  14.   wrapped.ExampleMethod(cpp_str);  
  15. }  


如果我们不需要interfaceextension来声明额外的属性和方法,ivar块仍然可以放在@implementation开始位置:

  1. #import "ObjcObject.h"  
  2. #import "CppObject.h"  
  3.   
  4.   
  5. @implementation ObjcObject {  
  6.   CppObject wrapped;  
  7. }  
  8.   
  9.   
  10. - (void)exampleMethodWithString:(NSString*)str  
  11. {  
  12.   // NOTE: str为nil会建立一个空字串,而不是引用一个指向UTF8String空指针.  
  13.   std::string cpp_str([str UTF8String], [str lengthOfBytesUsingEncoding:NSUTF8StringEncoding]);  
  14.   wrapped.ExampleMethod(cpp_str);  
  15. }  
定义的CppObject实例wrapped在ObjcObject创建时,CppObject的缺省建构函数会被调用,而在ObjcObject被调用dealloc析构时,ObjcObject的析构函数也会被调用。如果ObjcObject没有提供缺省的建构函数,编译就会失败。

管理被封装C++对象的生命周期
解决方案是透过new关键字掌握建构过程,比如:
  1. @interface ObjcObject () {  
  2.   CppObject* wrapped; // 指针!会在alloc时初始为NULL.  
  3. }  
  4. @end  
  5. @implementation ObjcObject  
  6. - (id)initWithSize:(int)size  
  7. {  
  8.   self = [super init];  
  9.   if (self)  
  10.   {  
  11.     wrapped = new CppObject(size);  
  12.     if (!wrapped) self = nil;  
  13.   }  
  14.   return self;  
  15. }  
  16. //...  


如果是使用C++异常,也可以使用 try {...} catch {...}把创建过程封装起来. 相应地,还要显式地释放封闭对象:

  1. - (void)dealloc  
  2. {  
  3.   delete wrapped;  
  4.   [super dealloc]; // 如果使用了ARC,这句就要略去  
  5. }  


作者接着提到了另一个方法,显示分配一块内存,然后在它的基础上调用new来创建对象。首先声明charwrapped_mem[sizeof(CppObject)]; 再使用wrapped = new(wrapped_mem)CppObject();创建了实例wrapped。释放时if (wrapped) wrapped->~CppObject(); 这样虽然可行,但不建议使用。


 总结
 一定要确保封装的方法仅返回和使用C或Objective-C类型的返回值及参数。同时不要忘记C++中不存在nil,而NUL是不可用于解引用的。

反向:在C++代码中使用Objective-C类
这个问题同样存在于头文件中。你不能因为引入Objective-C类型而污染了C++头文件,或无法被纯C++代码所引用。比方说,我们想封装的Objective-C类ABCWidget,在ABCWidget.h声明为:
  1. #import   
  2. @interface ABCWidget  
  3. - (void)init;  
  4. - (void)reticulate;  
  5. // etc.  
  6. @end  


这样的类定义在Objective-C++中是没有问题的,但在纯C++的代码是不允许的:

  1. #import "ABCWidget.h"  
  2. namespace abc  
  3. {  
  4.   class Widget  
  5.   {  
  6.     ABCWidget* wrapped;  
  7.   public:  
  8.     Widget();  
  9.     ~Widget();  
  10.     void Reticulate();  
  11.   };  
  12. }   


一个纯粹的C++编译器在Foundation.h中的代码和ABCWidget声明位置出错。


永恒的PIMPL
有没有这样的东西作为一类扩展C+ +,这样的把戏将无法正常工作。 另一方面,PIMPL,工作得很好,实际上是比较常用的纯C + +了。在我们的例子中,我们减少到最低限度:C + +类

C++并没有之前提到的classextension,但是却有另一种较为常用的方式:PIMPL (Private Implementation,私有实现)。这里,将C++ class的定义精简为:
  1. namespace abc  
  2. {  
  3.   struct WidgetImpl;  
  4.   class Widget  
  5.   {  
  6.     WidgetImpl* impl;  
  7.   public:  
  8.     Widget();  
  9.     ~Widget();  
  10.     void Reticulate();  
  11.   };  
  12. }  


然后在Widget.mm中:

  1. #include "Widget.hpp"  
  2. #import "ABCWidget.h"  
  3. namespace abc  
  4. {  
  5.   struct WidgetImpl  
  6.   {  
  7.     ABCWidget* wrapped;  
  8.   };  
  9.   Widget::Widget() :  
  10.     impl(new WidgetImpl)  
  11.   {  
  12.     impl->wrapped = [[ABCWidget alloc] init];  
  13.   }  
  14.   Widget::~Widget()  
  15.   {  
  16.     if (impl)  
  17.       [impl->wrapped release];  
  18.     delete impl;  
  19.   }  
  20.   void Widget::Reticulate()  
  21.   {  
  22.     [impl->wrapped reticulate];  
  23.   }  
  24. }   

它的工作原理是,前置声明。声明这样的结构或类对象的指针成员变量、结构或类就足够了。

需要注意的是封装的对象会在析构函数中释放。即便对于使用了ARC的项目,我还是建议你对这样的对C++/Objective-C重引用的文件屏蔽掉它。不要让C++代码依赖于ARC。在XCode中可以针对个别文件屏蔽掉ARC。Targetproperties->Build phase页签,展开'Compile Sources',为特定文件添加编译选项-fno-objc-arc。

C++中封装Objective-C类的捷径
您可能已经注意到,PIMPL解决方案使用两个级别的间接引用。如果包装的目标类像本例中的一样简单,就可能会增大了复杂性。虽然Objective-C的类型一般不能使用在纯C++中,不过有一些在C中实际已经定义了。id类型就是其中之一,它的声明在头文件中。虽然会失去一些Objective-C的安全性,你还是可以把你的对象直接传到C++类中:
  1. #include   
  2. namespace abc  
  3. {  
  4.   class Widget  
  5.   {  
  6.     id  wrapped;  
  7.   public:  
  8.     Widget();  
  9.     ~Widget();  
  10.     void Reticulate();  
  11.   };  
  12. }  


不建议向id对象直接发送消息。这样你会失去很多编译器的检查机制,特别是对于不同类中有着相同selector名字的不同方法时。所以:

  1. #include "Widget.hpp"  
  2. #import "ABCWidget.h"  
  3. namespace abc  
  4. {  
  5.   Widget::Widget() :  
  6.     wrapped([[ABCWidget alloc] init])  
  7.   {  
  8.   }  
  9.   Widget::~Widget()  
  10.   {  
  11.     [(ABCWidget*)impl release];  
  12.   }  
  13.   void Widget::Reticulate()  
  14.   {  
  15.     [(ABCWidget*)impl reticulate];  
  16.   }  
  17. }   


像这样的类型转换很容易在代码中隐藏错误,再尝试一个更好的方式。在头文件中:

  1. #ifdef __OBJC__  
  2. @class ABCWidget;  
  3. #else  
  4. typedef struct objc_object ABCWidget;  
  5. #endif  
  6.   
  7.   
  8. namespace abc  
  9. {  
  10.   class Widget  
  11.   {  
  12.     ABCWidget* wrapped;  
  13.   public:  
  14.     Widget();  
  15.     ~Widget();  
  16.     void Reticulate();  
  17.   };  
  18. }   


如果这个头文件被一个mm文件引用,编译器可以充分识别到正确的类。如果是在纯C++模式中引用,ABCWidget*是一个等价的id类型:定义为typedef struct objc_object*id; 。 #ifdef块还可以被进一步放到一个可重用的宏中:

  1. #ifdef __OBJC__  
  2. #define OBJC_CLASS(name) @class name  
  3. #else  
  4. #define OBJC_CLASS(name) typedef struct objc_object name  
  5. #endif   

现在,我们可以前置声明在头文件中一行就可以适用于所有4种语言:
 OBJC_CLASS(ABCWidget);
阅读更多

没有更多推荐了,返回首页