uC/OS-II源码解析(os_cpu_a.asm)

最新推荐文章于 2022-04-28 19:55:10 发布
最新推荐文章于 2022-04-28 19:55:10 发布
阅读量242 收藏
点赞数
分类专栏： UCOS-II 源码解析 文章标签： UCOSII 源码

转自：https://blog.csdn.net/u010650845/article/details/7252

;**********************************************************************************
;*
;*ver   : 2.52
;* file  : os_cpu_a.asm
;* brief : 处理器相关汇编文件
;*
;***********************************************************************************




;***********************************************************************************
;                                    声明&定义
;***********************************************************************************

            PUBLIC _OSTickISR            ;时钟节拍中断服务函数
            PUBLIC _OSStartHighRdy       ;最高优先级任务就绪函数
            PUBLIC _OSCtxSw              ;任务级的上下文切换
            PUBLIC _OSIntCtxSw           ;中断级的上下文切换

            EXTRN  _OSIntExit:FAR        ;声明函数OSIntExit()
            EXTRN  _OSTimeTick:FAR       ;声明函数OSTimeTick()
            EXTRN  _OSTaskSwHook:FAR     ;声明函数OSTaskSwHook()

            EXTRN  _OSIntNesting:BYTE    ;声明变量OSIntNesting
            EXTRN  _OSTickDOSCtr:BYTE    ;声明变量OSTickDOSCtr
            EXTRN  _OSPrioHighRdy:BYTE   ;声明变量OSPrioHighRdy
            EXTRN  _OSPrioCur:BYTE       ;声明变量OSPrioCur
            EXTRN  _OSRunning:BYTE       ;声明变量OSRunning
            EXTRN  _OSTCBCur:DWORD       ;声明变量OSTCBCur
            EXTRN  _OSTCBHighRdy:DWORD   ;声明变量OSTCBHighRdy

.MODEL      LARGE
.CODE
.186
            PAGE                                  ; /*$PAGE*/
;************************************************************************************
;                                     就绪态最高优先级任务启动函数
;                                       void OSStartHighRdy(void)
;
; 堆栈结构如下 :
;
; OSTCBHighRdy->OSTCBStkPtr --> DS                               (低地址)
;                               ES
;                               DI
;                               SI
;                               BP
;                               SP
;                               BX
;                               DX
;                               CX
;                               AX
;                               OFFSET  of task code address
;                               SEGMENT of task code address
;                               Flags to load in PSW
;                               OFFSET  of task code address
;                               SEGMENT of task code address
;                               OFFSET  of 'pdata'
;                               SEGMENT of 'pdata'               (高地址)
;
; Note : OSStartHighRdy() 示意性代码:
;           a) 调用OSTaskSwHook(),
;           b) OSRunning = TRUE,
;           c) 得到将要恢复运行任务的堆栈指针，
;                Stack pointer = OSTCBHighRdy->OSTCBStkPtr;
;           d) 从新任务的堆栈中恢复处理器的所有寄存器
;           f) 执行中断返回指令
;**************************************************************************************

_OSStartHighRdy  PROC FAR

            MOV    AX, SEG _OSTCBHighRdy          ; 
            MOV    DS, AX                         ;
;
            CALL   FAR PTR _OSTaskSwHook          ; 调用用户自定义函数 OSTaskSwHook()
;
            MOV    AL, 1                          ; 置变量 OSRunning 为 TRUE
            MOV    BYTE PTR DS:_OSRunning, AL     ; 表明多任务已经启动
;                                                   得到待运行任务的堆栈指针
            LES    BX, DWORD PTR DS:_OSTCBHighRdy ; SS:SP = OSTCBHighRdy->OSTCBStkPtr
            MOV    SS, ES:[BX+2]                  ;
            MOV    SP, ES:[BX+0]                  ;
;
            POP    DS                             ; 弹出寄存器
            POP    ES                             ; 必须按照OSTaskStkInit()中相反方向弹出
            POPA                                  ;
;
            IRET                                  ; 中断返回弹出程序指针、状态寄存器

_OSStartHighRdy  ENDP

            PAGE                                  ; /*$PAGE*/
;****************************************************************************************
;                                           任务切换 (任务级)
;                                           void OSCtxSw(void)
;
; Note(s) : 示意性代码如下:
;          1) 保存处理器寄存器
;          2) 在当前任务的TCB中保存当前任务的堆栈指针
;               OSTCBCur->OSTCBStkPtr = Stack pointer
;          3) OSTaskSwHook()
;          4) OSTCBCur = OSTCBHighRdy
;          5) OSPrioCur = OSPrioHighRdy
;          6) 得到将要开始重新运行的任务的堆栈指针
;               Stack pointer = OSTCBHighRdy->OSTCBStkPtr;
;          7) 从新任务的任务堆栈中恢复处理器所有寄存器的值
;          8) 执行中断返回指令
;
;****************************************************************************************

_OSCtxSw    PROC   FAR
;
            PUSHA                                  ; 保存处理器寄存器
            PUSH   ES                              ;
            PUSH   DS                              ;
;
            MOV    AX, SEG _OSTCBCur               ; Reload DS in case it was altered
            MOV    DS, AX                          ;
;                                将堆栈指针保存在任务控制块中
            LES    BX, DWORD PTR DS:_OSTCBCur      ; OSTCBCur->OSTCBStkPtr = SS:SP
            MOV    ES:[BX+2], SS                   ;
            MOV    ES:[BX+0], SP                   ;
;
            CALL   FAR PTR _OSTaskSwHook           ; 调用用户自定义函数OSTaskSwHook()
;                                                    新任务控制块赋值给当前任务控制块
            MOV    AX, WORD PTR DS:_OSTCBHighRdy+2 ; OSTCBCur = OSTCBHighRdy
            MOV    DX, WORD PTR DS:_OSTCBHighRdy   ;
            MOV    WORD PTR DS:_OSTCBCur+2, AX     ;
            MOV    WORD PTR DS:_OSTCBCur, DX       ;
;                                                    新任务优先级赋值给当前任务优先级
            MOV    AL, BYTE PTR DS:_OSPrioHighRdy  ; OSPrioCur = OSPrioHighRdy
            MOV    BYTE PTR DS:_OSPrioCur, AL      ;
;                                                    得到新的任务堆栈指针
            LES    BX, DWORD PTR DS:_OSTCBHighRdy  ; SS:SP = OSTCBHighRdy->OSTCBStkPtr
            MOV    SS, ES:[BX+2]                   ;
            MOV    SP, ES:[BX]                     ;
;
            POP    DS                              ; 从新任务堆栈中恢复cpu寄存器
            POP    ES                              ;
            POPA                                   ;
;
            IRET                                   ; 中断返回指令，弹出程序指针和状态寄存器
;
_OSCtxSw    ENDP

            PAGE                                   ; /*$PAGE*/
;****************************************************************************************
;                                          任务切换 (中断级)
;                                        void OSIntCtxSw(void)
;
; Note(s): 示意性代码如下: 
;         1) 调用用户自定义 OSTaskSwHook()
;         2) OSTCBCur = OSTCBHighRdy
;         3) OSPrioCur = OSPrioHighRdy
;         4) 得到将要重新执行的任务的堆栈指针
;              Stack pointer = OSTCBHighRdy->OSTCBStkPtr
;         5) 从新任务的堆栈中恢复所有处理器寄存器
;         6) 执行中断返回指令
;*****************************************************************************************

_OSIntCtxSw PROC   FAR
;
            CALL   FAR PTR _OSTaskSwHook           ; 调用用户自定义函数OSTaskSwHook()
;
            MOV    AX, SEG _OSTCBCur               ; 
            MOV    DS, AX                          ;
;                                                    新任务控制块赋值给当前任务控制块
            MOV    AX, WORD PTR DS:_OSTCBHighRdy+2 ; OSTCBCur = OSTCBHighRdy
            MOV    DX, WORD PTR DS:_OSTCBHighRdy   ;
            MOV    WORD PTR DS:_OSTCBCur+2, AX     ;
            MOV    WORD PTR DS:_OSTCBCur, DX       ;
;                                                    新任务优先级赋值给当前任务优先级
            MOV    AL, BYTE PTR DS:_OSPrioHighRdy  ; OSPrioCur = OSPrioHighRdy
            MOV    BYTE PTR DS:_OSPrioCur, AL
;                                                    得到将要重新运行的任务堆栈指针
            LES    BX, DWORD PTR DS:_OSTCBHighRdy  ; SS:SP = OSTCBHighRdy->OSTCBStkPtr
            MOV    SS, ES:[BX+2]                   ;
            MOV    SP, ES:[BX]                     ;
;
            POP    DS                              ; 从新任务堆栈中恢复所有处理器寄存器
            POP    ES                              ;
            POPA                                   ;
;
            IRET                                   ; 执行中断返回指令弹出程序指针和状态寄存器
;
_OSIntCtxSw ENDP

            PAGE                                   ; /*$PAGE*/
;*****************************************************************************************
;                                            时钟节拍中断服务子程序
;
; brief    : _OSTickISR1和_OSTickISR2是和PC DOS相关的操作，无需关注
;
; Note(s)  : 需要关注的示意性代码如下:
;
;              保存处理器寄存器;
;              调用OSIntEnter()或者直接给OSIntNexting加1
;              if (OSIntNesting == 1) {
;                 OSTCBCur->OSTCBStkPtr = Stack pointer
;              }
;              给产生中断的设备清中断
;              重新允许中断(可选)
;              OSTimeTick();            
;              OSIntExit();            
;              恢复处理器寄存器
;              执行中断返回指令
;******************************************************************************************
;
_OSTickISR  PROC   FAR
;
            PUSHA                                ; 保存处理器寄存器
            PUSH   ES
            PUSH   DS
;
            MOV    AX, SEG(_OSIntNesting)        ; 
            MOV    DS, AX
            INC    BYTE PTR DS:_OSIntNesting     ; OSIntNesting加1
;
            CMP    BYTE PTR DS:_OSIntNesting, 1  ; if (OSIntNesting == 1)
            JNE    SHORT _OSTickISR1             
            MOV    AX, SEG(_OSTCBCur)            ;     
            MOV    DS, AX                        ; 堆栈指针保存到TCB中
            LES    BX, DWORD PTR DS:_OSTCBCur    ;     OSTCBCur->OSTCBStkPtr = SS:SP
            MOV    ES:[BX+2], SS                 ;
            MOV    ES:[BX+0], SP                 ;
;
_OSTickISR1:
            MOV    AX, SEG(_OSTickDOSCtr)        ; Reload DS
            MOV    DS, AX
            DEC    BYTE PTR DS:_OSTickDOSCtr
            CMP    BYTE PTR DS:_OSTickDOSCtr, 0
            JNE    SHORT _OSTickISR2             ; Every 11 ticks (~199.99 Hz), chain into DOS
;
            MOV    BYTE PTR DS:_OSTickDOSCtr, 11
            INT    081H                          ; Chain into DOS's tick ISR
            JMP    SHORT _OSTickISR3

_OSTickISR2:
            MOV    AL, 20H                       ; Move EOI code into AL.
            MOV    DX, 20H                       ; Address of 8259 PIC in DX.
            OUT    DX, AL                        ; Send EOI to PIC if not processing DOS timer.
;
_OSTickISR3:
            CALL   FAR PTR _OSTimeTick           ; 调用 OSTimeTick()
;
            CALL   FAR PTR _OSIntExit            ; 调用 OSInitExit()
;
            POP    DS                            ; 恢复处理器寄存器
            POP    ES
            POPA
;
            IRET                                 ; 中断返回弹出程序指针和状态寄存器
_OSTickISR  ENDP
;
            END

8764

dallas48
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
uC/OS-II源码入门分析
qq_29233719的博客
02-26 388
一、uC/OS-II的简介 uC/OS是一个微型的实时操作系统，包括了一个操作系统最基本的一些特性，如任务调度、任务通信、内存管理、中断管理等，而且这是一个代码完全开放的实时操作系统，简单明了的结构和严谨的代码风格，非常适合初涉嵌入式操作系统的人士学习，它可以让我们以最快的速度来了解操作系统的概念、结构和模块工作原理，并由浅入深逐步推广到商用操作系统上。同时对于那些对操作系统感兴趣的爱好者来
uC/OS-II在C8051F上的移植
12-08
- **OS_CPU_A.ASM**：这是汇编语言文件，包含了与特定CPU架构相关的初始化和关键操作，如任务上下文切换和中断服务。 - **OS_CPU_C.C**：包含C语言实现的CPU相关功能，如任务切换钩子函数和其他与处理器特性相关的...
ucos-II在51系列单片机上的移植源码
02-24
UCOS-II移植到MCS-51系列单片机，适合嵌入式初学者
os_cpu_a.asm
weixin_30735391的博客
04-22 135
在OS_CPU_A.ASM中，定义了开、关中断的方法，在uC/OS-II系统中有三种方法可以实现中断开关，而ARM只适用于模式三，即使用一个局部变量，在中断进入之间保存CPU状态，退出时候再恢复状态。 OSStart()函数调用OSStartHighRdy()来使就绪态任务中优先级最高的任务开始运行，OSStartHighRdy()必须调用OSTaskSwHook()，调用完STaskSwHoo...
uCOS-II移值过程实例讲解
huobengluantiao8
08-14 166
uCOS-II移值过程实例讲解 我将uCOS-II 移植到了EPONS 的C33209的平台上，接下来我就基于我移植好的代码讲解如何将uCOS-II从一种MCU移植到另一种MCU。 首先介绍uCOS-II的文件，如下表： ucos_ii.h os_cfg.h os_cpu.h os_core.c os_dbg_r.c os_flag.c os_mbox.c os_mem....
对os_cpu_a.asm的认识
weixin_42900105的博客
08-20 595
;******************************************************************************************************** ; 声明和导出 ;*************************************************************************************...
uCOS-II.rar_OS_CPU_A.ASM_ucos ii 实例
09-23
本文将基于提供的"uCOS-II.rar"压缩包中的"OS_CPU_A.ASM"文件，结合uCOS-II的C语言编程实例，深入解析其核心机制和编程技巧。 首先，我们来看"OS_CPU_A.ASM"文件。在uCOS-II中，"OS_CPU_"系列文件是为特定处理器...
uC_OS-II.rar_uC OS_uc/os
09-23
这部分工作通常在“os_cpu_a.asm”或“os_cpu_c.c”文件中进行。 4. **设置堆栈**：每个任务都需要自己的堆栈空间。在创建任务时，必须分配足够的内存并正确设置堆栈指针，以满足函数调用和局部变量的需求。 5. **...
uC-OS-II-V2.85.rar_V2 _uC-OS_uc os II_uc os ii 2.85_uc85II
09-21
- uC-OS-II设计为高度可移植的，通过`os_cpu.h`和`os_cpu_a.asm`文件，适应不同处理器架构。 通过分析和理解uC-OS-II V2.85的源代码，开发者能够深入理解嵌入式实时操作系统的内部机制，这对于优化系统性能、解决...
UCOSii在51单片机上的移植代码
04-20
UCOSii在移植到51单片机上的代码，目前关于UCOSii在单片机上的移植理论书籍很多但是实际的代码不容易获得，我愿意将我所获得的资源共享出来。
UCOSII 移植到51单片机源码
07-20
UCOSII移植到51单片机源码 移植成功 可直接使用
嵌入式微系统的筋骨：精简uC/OS-II
08-30
通过以上六步操作操作之后，uC/OS-II非常简单明了，只有os.c、os.h和os_a.asm三个文件，os.c中只有寥寥15个函数，os_a.asm中只有4个汇编函数。考虑到扩展性，还是保留了uC/OS-II的一些影子，其实若再精简下去，可能...
移植RT-Thread报错
weixin_38974768的博客
04-28 721
移植RT-Thread报错
Raw-OS操作系统内核代码汇编部分cpu.asm分析
wcc243588569的博客
06-11 972
文章目录和汇编文件相关的头文件部分： 和汇编文件相关的头文件部分： #ifndef RAW_CPU_H #define RAW_CPU_H unsigned int OS_CPU_SR_Save(void); //上述函数是用来读取Restore时保存进R0的PRIMASK的值。 //关于PRIMASK，PRIMASK是只有1个位的寄存器，用于屏蔽中断 void OS_CPU_SR_Restore(unsigned int sr);
在win7下使用nasm编译asm系统源码并在VMware上运行的图文教程
醉猫
10-20 5210
1.工欲善其事，必先利其器！ 先下载需要的文件：虚拟机（用来运行你编译出来的系统），nasm（用来编译源码），notepad++， 虚拟机我用的是vmware，我这里有破解汉化版的，下载地址：http://pan.baidu.com/s/1i3Hw4gX,nasm我也有，下载地址http://pan.baidu.com/s/1gdKizWR，notepad++就不说了，工具有了就是安装，这都很
uCOS-II移植之os_cpu_a.asm文件说明
Lost_forgiveness的博客
04-18 1500
uCOS-II移植需要需要改动的文件主要有有os_cpu_a.asm、 .c、os_cpu.h三个文件，首先来讲一下汇编文件os_cpu_a.asm。 os_cpu_a.asm中用到的汇编知识及语法： 1、EXTERN：用于声明变脸，表示被声明的变量在其他文件中定义，在本文件中使用 2、EXPORT：用于定义变量，且此变量被其他文件所使用的，与之相对的是IMPORT,表示只能在本文件中使用。 3、M
ucos-ii中os_cpu_a.asm函数解释
zuotian5212008的专栏
08-13 2856
1、 对进入临界区和跳出临界区的函数理解#define OS_ENTER_CRITICAL() {cpu_sr = OS_CPU_SRSave();} #define OS_EXIT_CRITICAL() {OS_CPU_SR_Restore(cpu_sr);}OS_CPU_SR_Save MRS R0, PRIMASK
具体描述基于STM32F103RCT6单片机的μC/OS-II移植的文件OS_CPU_A.ASM 修改
最新发布
06-10
好的，我会尽力描述一下基于STM32F103RCT6单片机的μC/OS-II移植的文件OS_CPU_A.ASM的修改。 1. 中断处理：在STM32F103RCT6单片机上，中断向量表位于地址0x0800 0000处，包含了所有中断处理函数的入口地址。在移植...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值