汇编中try catch的实现

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;平台定义
.386
.Model Flat,StdCall
Option CaseMap:None
;<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;文件包含
include windows.inc
include kernel32.inc
include user32.inc
includelib user32.lib
includelib kernel32.lib
;<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;常量定义
.const
szMsg db "异常发生位置%08x,异常代码:%08x,标志:%08x",0
szSEH1 db "如果发生异常，该对话框将显示",0
szCaption1 db "显示对话框",0
szSEH2 db "如果异常发生，该对话框不应该显示",0
szCaption2 db "永远无法显示的对话框",0
;<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;代码段定义
.code
;自定义的SEH异常处理过程
_Handler proc _lpExceptionRecord,_lpSEH,_lpContext,_lpDispatcherContext
;局部变量的定义
local @szBuffer[256]:byte
       pushad
mov esi,_lpExceptionRecord;
mov edi,_lpContext;
assume esi:ptr EXCEPTION_RECORD,edi:ptr CONTEXT;


;格式化字符串
invoke wsprintf,addr @szBuffer,addr szMsg,[edi].regEip,[esi].ExceptionCode,[esi].ExceptionFlags;
;显示异常信息
invoke MessageBox,NULL,addr @szBuffer,NULL,MB_OK;
 
       
       mov [edi].regEip,offset SEH1;接下来要进行的操作，类似于重定向操作
assume esi:nothing,edi:nothing
popad
mov eax,ExceptionContinueExecution;
ret
_Handler endp;






SEH:
      assume fs:nothing
push offset _Handler;注册异常处理程序
push fs:[0];该参数并不重要，他应该指向的是下一个SEH处理历程，在这里，我们只是需要一个数据来进行占位，表示该数据之后的地址指向了异常处理过程
mov fs:[0],esp;//栈顶指向EXCEPTION_REGISTRATION
xor eax,eax;
mov DWORD ptr[eax],0;这里产生异常读取位置异常，因为要读取[0000]位置的数据
SHE2:
      invoke MessageBox,NULL,addr szSEH2,addr szCaption2,MB_OK;


SEH1:
      invoke MessageBox,NULL,addr szSEH1,addr szCaption1,MB_OK;


pop fs:[0]
pop eax
invoke ExitProcess,0
end SEH;表明程序的入口点
;<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<