使用VB6封装Excel文档为EXE文件【综合各平台方法，亲测可用】

最新推荐文章于 2024-04-16 15:15:00 发布

大头海鱼

最新推荐文章于 2024-04-16 15:15:00 发布

阅读量4.4k

点赞数 47

文章标签： excel

本文链接：https://blog.csdn.net/datouhaiyu/article/details/135492073

版权

个人用VBA写的一个计算统计程序，但是并不是每台电脑都使用Excel,有的安装了也不一定是完整版，如果想让此程序在全公司电脑上运行，封装成EXE，使其脱离对Excel的依赖就变成不二选择。
尝试了《EXCEL封装机》，总是被电脑识别为病毒，而且试用2次就要收费；尝试了XCELL插件，注册价格都得以美元计价，试用版在程序运行前会跳出丑陋的注册提示。所以选择此方法自行封装，下面贴出具体步骤。
开始前请安装VB6.0，具体方法参考本文第4部分。
#一、使用VB6.0制作exe文件头部分
（一）打开VB，“文件”-“新建工程”-“标准exe”。在这里插入图片描述
（二）将form1窗体作为软件启动封面窗体，打开Form1的属性串口，对如下属性进行设置：BorderStyle = 0 , StartUpPositon = 2 , Icon与Picture属性设置成你需要的图标和设计好准备的图片（软件封面），窗体的大小设置成你需要的值即可。
（三）窗体中添加一个时钟空间timer1,并将InterVal属性设为1000，该值决定了启动程序时窗体显示时间。
在这里插入图片描述

（四）双击窗体打开代码编辑窗口，录入以下代码：

Private Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
Private Declare Function GetTempFileName Lib "kernel32" Alias "GetTempFileNameA" (ByVal lpszPath As String, ByVal lpPrefixString As String, ByVal wUnique As Long, ByVal lpTempFileName As String) As Long
Private Declare Function GetTempPath Lib "kernel32" Alias "GetTempPathA" (ByVal nBufferLength As Long, ByVal lpBuffer As String) As Long
Private Const MAX_PATH = 260
Private Const EXE_SIZE = 24576   '本EXE实际字节大小，写完新生成exe，看属性确定大小之后再回来修改值
Private Type FileSection
Bytes() As Byte
End Type
Private Type SectionedFile
Files() As FileSection
End Type
Dim StopTime As Integer

Private Sub Form_Activate()
If Command$() = "" Then Main1
End Sub

Private Sub Form_Load()
On Error Resume Next
If Command$() = "" Then
Form1.Visible = True
SetWindowPos Form1.hwnd, -1, 0, 0, 0, 0, &H2 Or &H1 '将封面置为最顶层窗体
Else
Form1.Visible = False
Form1.Timer1.Enabled = True
End If
End Sub
Sub Main1()
Dim StartXLSByte, I, J As Long
Dim AppPath, XlsTmpPath As String
Dim myfile As SectionedFile
Dim xlApp As Excel.Application '定义EXCEL类
Dim xlBook As Excel.Workbook '定义工件簿类
Dim xlsheet As Excel.Worksheet '定义工作表类
AppPath = App.Path
XlsTmpPath = GetTempFile() '取得XLS临时文件名（带路径）
If VBA.Right(App.Path, 1) = "\" Then AppPath = VBA.Left(App.Path, VBA.Len(App.Path) - 1)
Open AppPath & "\" & App.EXEName & ".exe" For Binary As #1
ReDim myfile.Files(1)
ReDim myfile.Files(1).Bytes(1 To LOF(1) - EXE_SIZE) '单独调试时，此语句会报错，不用管，合成后就好了
Open XlsTmpPath For Binary As #2
Get #1, EXE_SIZE + 1, myfile.Files(1).Bytes '此处数字要根据EXE实际头文件大小更改设定
Put #2, 1, myfile.Files(1).Bytes
Close #1
Close #2
Set xlApp = CreateObject("Excel.Application") '创建EXCEL应用类
Set xlBook = xlApp.Workbooks.Open(FileName:=XlsTmpPath, Password:="ldhyob") '打开EXCEL工作簿,已知该工作簿已加打开口令为ldhyob
'以下星号括起部分代码是往xls里写数据（也可不往工作簿里写数据的方法，而生成txt的方法），作用是保存本exe的绝对路径与临时xls绝对路径，以便于EXE重写更新与临时文件删除
'*****************************************
Set xlsheet = xlBook.Worksheets("temp") '设置活动工作表
xlsheet.Cells(1, 1) = AppPath & "\" & App.EXEName & ".exe" '将该EXE完全路径存在工作表单元格内
xlsheet.Cells(2, 1) = XlsTmpPath '将该EXE本次运行产生XLS临时文件路径存在工作表单元格内
'****************************************
xlApp.Visible = True '设置EXCEL可见
Set xlApp = Nothing '释放xlApp对象
StopTime = 0
Me.Timer1.Enabled = True '启动时钟
End Sub

Private Function GetTempFile() As String '用来产生系统临时文件名
    Dim lngRet As Long
    Dim strBuffer As String, strTempPath As String
    strBuffer = String$(MAX_PATH, 0)
    lngRet = GetTempPath(Len(strBuffer), strBuffer)
    If lngRet = 0 Then Exit Function
    strTempPath = Left$(strBuffer, lngRet)
    strBuffer = String$(MAX_PATH, 0)
    lngRet = GetTempFileName(strTempPath, "tmp", 0&, strBuffer)
    If lngRet = 0 Then Exit Function
    If lngRet > 0 Then
        GetTempFile = Left$(strBuffer, lngRet - 1)
    Else
        GetTempFile = strBuffer
    End If
End Function

Private Sub Timer1_Timer()
    On Error Resume Next
    If Command() <> "" Then
        If VBA.Dir(Command()) <> "" Then
            Kill Command() '删除本次运行遗留的临时XLS文件
        Else
            End
        End If
    Else
        StopTime = StopTime + 1 '计时累加
        If StopTime = 1 Then Unload Me: End '2秒后自动关闭退出
    End If
End Sub

（五）将编辑好的工程项目保存到指定的文件夹，可以命名为“工程1”。
（六）进行编译，“文件”-“生成工程1.exe”。
（七）查看第6步生成的EXE文件字节大小，并将具体数字记下来，并将VB模块中的“Private Const EXE_SIZE = 24576”保证一致（这里的24576是笔者例子的结果数字，每个人在实际时会有不同）。此例此步很重要，必须要做，该数字在xls文档VBA中还要使用到。
（八）重新编译，命名为“abc.exe”。
至此，文件头部分已做完，abc.exe文件也已生成于磁盘中。
特别提示:编译前,确保VB里"工程"—"引用"里"Microsoft Excel 16.0 Object Library"前面的勾已打上。如果引用中找不到EXCEL选项，可以参考文后链接文章5解决。
此次单独调试文件头部分时，会提示错误，忽略错误，待最终exe合成后就不会报错了。
#二、编辑xls文档部分
（一）给工作簿增加一个工作表temp，将其置为隐藏。在这里插入图片描述

（二）增加xls文档宏代码以实现文档关闭时EXE数据刷新。
打开xls文档，打开VBE窗口，在ThisWorkBook代码区头部加入以下代码：

Private Const EXE_SIZE = 24576 '此处根据文件头exe大小修改
Private Type FileSection
Bytes() As Byte
End Type

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    ThisWorkbook.Close True
    Dim myfile As FileSection '定义变量
    Dim comc, exec, xlsc As String '定义变量
    Application.Visible = False '隐藏EXCEL主窗口
    exec = Worksheets("temp").Cells(1, 1).Value
    xlsc = Worksheets("temp").Cells(2, 1).Value
    comc = exec & " " & xlsc
    Open exec For Binary As #1 '打开EXE文件
    ReDim myfile.Bytes(1 To EXE_SIZE)
    Get #1, 1, myfile.Bytes '取得固有文件头
    Close #1
    If VBA.Dir(exec) <> "" Then Kill exec
    Open exec For Binary As #1 '生成新的EXE文件
    Put #1, 1, myfile.Bytes '先写入文件头
    Open xlsc For Binary As #2 '打开xls临时文件
    ReDim myfile.Bytes(1 To FileLen(xlsc))
    Get #2, 1, myfile.Bytes
    Put #1, EXE_SIZE + 1, myfile.Bytes '将xls部分追加进EXE
    Close #1
    Close #2
    Application.Quit
    Shell comc, vbMinimizedNoFocus '删除临时xls文件
End Sub

在这里插入图片描述

（三）保存文档，命名为“test.xls”，退出，关闭EXCEL。（提示：XLS文档不要在open事件中显示起始窗体，在关闭事件中，最好增加询问用户是否保存的语句）
单独调试VBA时，会报错，忽略错误，待最终exe合成后，错误就会消失。
#三、将EXE与XLS结合生成新的EXE
（一）将第一步得到的abc.exe与第二步得到的test.xls（文件名随你愿意取）放到同一目录下。
（二）在该目录下鼠标右键“新建”—“文本文档”，输入以下内容：
@echo off
copy /b abc.exe + test.xls main.exe
（三）保存，更改文件名（包括扩展名）为“合并.bat”，然后双击它，不一会就会发现在当前目录下会多出一个EXE文件main.exe，这就是封装成品了，你可以将其重命名为所需要的名称。

#四、相关资料链接
感谢各平台高手文章，参考了几篇很有价值的文章，在此贴出相关文章链接。
##（一）个人图书馆–VB Excel封装方法
文章链接：http://www.360doc.com/content/10/0910/22/3036050_52742622.shtml
##（二）百度文库–XLS封装成EXE制作全攻略
文章链接：https://wenku.baidu.com/view/d5dd5ebe960590c69ec376f1?aggId=undefined&fr=catalogMain_text_ernie_recall_backup_new%3Awk_recommend_main3&wkts=1704811975135&bdQuery=%E5%B0%86Excel+VBA%E5%B0%81%E8%A3%85%E6%88%90exe%E7%A8%8B%E5%BA%8F
##（三）CSDN–XLS封装成EXE制作全攻略
文章链接：https://blog.csdn.net/weixin_33795806/article/details/92899197?ops_request_misc=%257B%2522request%255Fid%2522%253A%2522170480084416800215063501%2522%252C%2522scm%2522%253A%252220140713.130102334.pc%255Fall.%2522%257D&request_id=170480084416800215063501&biz_id=0&utm_medium=distribute.pc_search_result.none-task-blog-2_allfirst_rank_ecpm_v1~rank_v31_ecpm-3-92899197-null-null.142^v99pc_search_result_base1&utm_term=SectionedFile&spm=1018.2226.3001.4187
##（四）CSDN–将Excel VBA封装成exe程序[老贴收藏]
文章链接：https://blog.csdn.net/miaozk2006/article/details/82417176
##（五）CSDN --vb6.0没有Microsoft Excel 15.0 Object Library如何引用——机房遇到问题（二）
文章链接：https://blog.csdn.net/zybqmy/article/details/42151967
##（六）win11安装VB6.0（已解决）
文章链接：

大头海鱼

关注

47
点赞
踩
68

收藏

觉得还不错? 一键收藏
0
评论
使用VB6封装Excel文档为EXE文件【综合各平台方法，亲测可用】

（二）将form1窗体作为软件启动封面窗体，打开Form1的属性串口，对如下属性进行设置：BorderStyle = 0 , StartUpPositon = 2 , Icon与Picture属性设置成你需要的图标和设计好准备的图片（软件封面），窗体的大小设置成你需要的值即可。所以选择此方法自行封装，下面贴出具体步骤。（三）保存，更改文件名（包括扩展名）为“合并.bat”，然后双击它，不一会就会发现在当前目录下会多出一个EXE文件main.exe，这就是封装成品了，你可以将其重命名为所需要的名称。
复制链接

扫一扫