以下脚本均来源于论坛Ten Forums,侵删。
可以一键开启,任务栏显示的功能。
需要注意的是以下脚本点击之后会重启Windows文件资源管理器,所有已打开的文件夹都会被关闭,其他正在运行的程序不受任何影响。
桌面模式:
平板模式:
- 开启自动隐藏:Turn_On_Auto-hide_Taskbar_in_Tablet_Mode.bat
- 关闭自动隐藏:Turn_Off_Auto-hide_Taskbar_in_Tablet_Mode.bat
顺便参考了脚本,自己写了一个一键切换模式的脚本,这样只需点击同一个文件即可:
源码:
https://gist.github.com/zhou9110/86581778b0a11c7dfce336a8bd529dc8
中文版脚本:https://gist.github.com/zhou9110/1d0f730269118c5fb43b9a6e4ea261cb
:: Switch the auto-hide taskbar in tablet mode on and off
:: by overwriting registery via batch script
:: Modified by: zhou9110 (Github: zhou9110, Zhihu: @周兲子)
:: Modified on: October 14th 2019
:: Version No.: V1.0
::
:: Reference:
:: Originally Created by: Shawn Brink
:: Originally Created on: April 22nd 2016
:: Tutorial:
:: http://www.tenforums.com/tutorials/48127-taskbar-auto-hide-tablet-mode-turn-off-windows-10-a.html
:: Original File:
:: https://www.tenforums.com/attachments/tutorials/76240d1461384444-taskbar-auto-hide-tablet-mode-turn-off-windows-10-a-turn_on_auto-hide_taskbar_in_tablet_mode.bat
:: https://www.tenforums.com/attachments/tutorials/76239d1461384444-taskbar-auto-hide-tablet-mode-turn-off-windows-10-a-turn_off_auto-hide_taskbar_in_tablet_mode.bat
@echo off
REM Declare to use code page UTF-8
chcp 65001 >NUL
SET REGKEY=HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced
SET REGVAL=TaskbarAutoHideInTabletMode
SET DISPLAY_TEXT_ENABLED=自动隐藏任务栏功能已开启
SET DISPLAY_TEXT_DISABLED=自动隐藏任务栏功能已关闭
SET TIMEOUT_SECOND=2
REM Query the value in registery
SET TASKBAR_AUTO_HIDE_ENABLED=
FOR /F "tokens=2,*" %%A IN ('REG Query %REGKEY% /V %REGVAL% ^|findstr %REGVAL%') DO (
SET TASKBAR_AUTO_HIDE_ENABLED=%%B
)
REM Checking if the value is set
IF not defined TASKBAR_AUTO_HIDE_ENABLED (
SET TASKBAR_AUTO_HIDE_ENABLED=0
)
IF %TASKBAR_AUTO_HIDE_ENABLED% EQU 0 (
REM Enable Auto-hide in tablet mode
REG ADD %REGKEY% /V %REGVAL% /T REG_DWORD /D 1 /F >NUL
ECHO %DISPLAY_TEXT_ENABLED%
) ELSE (
REM Disable Auto-hide in tablet mode
REG ADD %REGKEY% /V %REGVAL% /T REG_DWORD /D 0 /F >NUL
ECHO %DISPLAY_TEXT_DISABLED%
)
TIMEOUT %TIMEOUT_SECOND% >NUL
REM To kill and restart explorer to take effects
TASKKILL /f /im explorer.exe
START explorer.exe
顺便贴一下自己知乎上的回答:
win10平板,想要批处理隐藏任务栏,bat里面应该怎么写?-回答
参考来源:
Turn On or Off Auto-hide Taskbar in Desktop Mode in Windows 10
How to Turn On or Off Auto-hide the Taskbar in Tablet Mode in Windows 10