VBA 函数参数和结果输出的二三事

想说的都写在批注了，就不多写了。

'带有一个参数的函数
Function CAL(a) As Double
    Select Case a
        Case Is > 100:
            CAL = 100
        Case 55 To 100
            CAL = 55
        Case Else
            CAL = 0
    End Select
End Function

'带1个参数写1个，带2个写2个，多个的话可以选择数组
'函数过程主要是在单元格用，意味着经常一框，不晓得多少个参数，怎么处理？
'用数组作为参数
'经过测试，类似=SUMARRAY(A4:D4)可以运行，但是=SUMARRAY(A4,B4,C4,D4)无法计算

Function SUMARRAY(list) As Double
    '未明确是啥类型就用Variant
    Dim Item As Variant
    SUMARRAY = 0
    For Each Item In list
        '是数字就加总
        If WorksheetFunction.IsNumber(Item) Then
            SUMARRAY = SUMARRAY + Item
        End If
    Next Item
End Function
Sub MakeList()
    Dim nums(1 To 100) As Double
    Dim i As Integer
    For i = 1 To 100
        '随机赋值1-100的值到nums数组的各个元素
        nums(i) = Rnd * 100
    Next i
    MsgBox SUMARRAY(nums)
End Sub

'部分函数带可选参数，可选参数怎么实现呢？
'在参数名前面加上Optional就是可选参数啦！
'假设实现一个返回大小写功能的函数，不写参数全大写，可选参数填了则全小写


Function UPORLOW(cell As Variant, Optional UpperCase As Variant)
    'cell是必须提供的参数，用IsMissing判断是否提供了后面的UpperCse参数
    
    If IsMissing(UpperCase) Then
        UPORLOW = UCase(cell)
    Else
        UPORLOW = LCase(cell)
    End If
        
End Function

'参数传入1.固定数量参数；2.数组；3.可选参数
'问题：怎么输出数组

Function WEEKTOTAL()
    WEEKTOTAL = Array("周一", "周二", "周三", "周四", "周五", "周六", "周日")
    '使用方法
    '1.框柱不能多于数组数量的单元格(多了的会显示错误值，还不能单独删除)
    '2.把=WEEKTOTAL输入到单元格中，然后注意不要就按回车键哈，是按Ctrl+Shift+Enter三个一起
    '3.数组输出的值在单元格只会横着排
End Function

'怎么实现想横着就横着想竖着就竖着的数组排列呢？
'和之前一样，传入一个可选参数，这里简单点，随便穿了参数就当做竖着排列好了
Function WEEKTOTALPLUS(Optional arg As Variant)
    '基本流程就是1.没参数，不管了；有参数，横着排
    Dim weeks As Variant
    '不能Dim weeks(7) as String ，然后weeks =arry(7个值)这样操作
    weeks = Array("周一", "周二", "周三", "周四", "周五", "周六", "周日")
    '还是用IsMissing判断有没有参数
    If IsMissing(arg) Then
        WEEKTOTALPLUS = weeks
    Else
        '有参数了，就变成竖的往下排列，用系统的转置函数
        WEEKTOTALPLUS = Application.Transpose(weeks)
    End If
End Function

'刚才例子SUMARRAY在输入=SUMARRAY(A4:D4)可以运行，但输入=SUMARRAY(A4,B4,C4,D4)无法计算
'不定数量的参数的处理办法:使用数组作为最后一个参数，加上关键字PrarmArray

Function SUMPLUS(ParamArray arglist() As Variant) As Double
    Dim arg As Variant
    For Each arg In arglist
        SUMPLUS = SUMPLUS + arg
    Next arg
    '这个时候输入=SUMARRAY(A4,B4,C4,D4)等等多个参数可以计算
    '但是输入=SUMARRAY(A4:D4)又可以运行，后面完善类似SUM的功能
End Function