第6章 循环、批量传送和条件转移-1.34h

c06_mbr.asm

         ;代码清单6-1
         ;文件名：c06_mbr.asm
         ;文件说明：硬盘主引导扇区代码
         ;创建日期：2011-4-12 22:12 
      
         jmp near start
         
  mytext db 'L',0x07,'a',0x07,'b',0x07,'e',0x07,'l',0x07,' ',0x07,'o',0x07,\
            'f',0x07,'f',0x07,'s',0x07,'e',0x07,'t',0x07,':',0x07
  number db 0,0,0,0,0
  
  start:
         mov ax,0x7c0                  ;设置数据段基地址 
         mov ds,ax
         
         mov ax,0xb800                 ;设置附加段基地址 
         mov es,ax
         
         cld
         mov si,mytext                 
         mov di,0
         mov cx,(number-mytext)/2      ;实际上等于 13
         rep movsw
     
         ;得到标号所代表的偏移地址
         mov ax,number
         
         ;计算各个数位
         mov bx,ax
         mov cx,5                      ;循环次数 
         mov si,10                     ;除数 
  digit: 
         xor dx,dx
         div si
         mov [bx],dl                   ;保存数位
         inc bx 
         loop digit
         
         ;显示各个数位
         mov bx,number 
         mov si,4                      
   show:
         mov al,[bx+si]
         add al,0x30
         mov ah,0x04
         mov [es:di],ax
         add di,2
         dec si
         jns show
         
         mov word [es:di],0x0744

         jmp near $

  times 510-($-$$) db 0
                   db 0x55,0xaa

label_a:
	....

如果label_a的汇编地址是0x05，程序加载到内存后，他在段内的便宜地址仍然是0x05

[14.1]–跳过非指令的数据区.mp4

mov byte [0x00] ,'L'
mov byte [0x01] ,0x2f 

\续行符

指令指针寄存器的值是0x7x00，段地址寄存器的值是0x0000

[14.2]–逻辑段地址的重新设定.mp4

[14.3]–串传送指令和标志寄存器.mp4

DF处理器自动设置的，我们的程序只能读不能写

cld DF清零

std

rep 重复执行“CX中值”次，CX值为0，则执行下一条指令

[14.4]–NASM的$和$$记号.mp4

$ 当前行的汇编地址；例如：jmp $ 跳转到自身，无限循环

$$ 程序起始汇编地址

[14.5]–使用循环指令LOOP分解数位.mp4

[14.6]–基址寻址和INC指令.mp4

[14.7]–数字的显示和DEC指令.mp4

[14.8]–基址变址寻址和条件转移指令.mp4