第六章 相同的功能，不同的代码

本章的代码和上一章实现的是同样的功能，但是本章采用更合理的技巧去组织代码，使代码更通用、易懂。具体代码贴在下面，

         ;代码清单6-1
         ;文件名：c06_mbr.asm
         ;文件说明：硬盘主引导扇区代码
         ;创建日期：2011-4-12 22:12 
      
         jmp near start
         
  mytext db 'L',0x07,'a',0x07,'b',0x07,'e',0x07,'l',0x07,' ',0x07,'o',0x07,\
            'f',0x07,'f',0x07,'s',0x07,'e',0x07,'t',0x07,':',0x07
  number db 0,0,0,0,0
  
  start:
         mov ax,0x7c0                  ;设置数据段基地址 
         mov ds,ax
         
         mov ax,0xb800                 ;设置附加段基地址 
         mov es,ax
         
         cld
         mov si,mytext                 
         mov di,0
         mov cx,(number-mytext)/2      ;实际上等于 13
         rep movsw
     
         ;得到标号所代表的偏移地址
         mov ax,number
         
         ;计算各个数位
         mov bx,ax
         mov cx,5                      ;循环次数 
         mov si,10                     ;除数 
  digit: 
         xor dx,dx
         div si
         mov [bx],dl                   ;保存数位
         inc bx 
         loop digit
         
         ;显示各个数位
         mov bx,number 
         mov si,4                      
   show:
         mov al,[bx+si]
         add al,0x30
         mov ah,0x04
         mov [es:di],ax
         add di,2
         dec si
         jns show
         
         mov word [es:di],0x0744

         jmp near $

  times 510-($-$$) db 0
                   db 0x55,0xaa

实验现象：

实验体会：

有了王爽《汇编语言》的基础，读第二部分8086模式的代码没有任何难度，有几个地方需要说明

a）

jns show 当显示完最后一个数位后， SI 的内容是零。执行 dec si 指令后，由于产生了借位，实际的运算结果是 0xffff（SI 只能容纳 16 个比特），因其最高位是“1”，故处理器将标志位 SF 置“1”，表明当前 SI 中的结果可以理解为一个负数（－1）。于是，执行 jns show 时，条件不满足，接着执行后面第 51 行的指令。

b）

jmp near $ 整个程序到此结束。为了使处理器还有事做，源程序第 53 行，是一个无限循环。 NASM编译器ᨀ供了一个标记“$”，该标记等同于标号，你可以把它看成是一个隐藏在当前行行首的标号。因此， jmp near $的意思是，转移到当前指令继续执行，它和infi: jmp near infi是一样的，没有区别，但不需要使用标号，更不必为给标号起一个有意义的名字而伤脑筋。

c）

times 510-($-$$) db 0

db 0x55,0xaa

源程序第 55 行，用于重复伪指令“db 0”若干次。重复的次数是由 510-($-$ $)得到的，除去 0x55 和 0xAA 后，剩余的主引导扇区内容是 510 字节；$是当前行的汇编地址； $ $是 NASM编译器ᨀ供的另一个标记，代表当前汇编节（段）的起始汇编地址。当前程序没有定义节或段， 就默认地自成一个汇编段，而且起始的汇编地址是 0（程序起始处）。这样，用当前汇编地址减去程序开头的汇编地址（0），就是程序实体的大小。再用 510 减去程序实体的大小，就是需要填充的字节数。就像处理器把内存划分成逻辑上的分段一样，源程序也应当按段来组织，划分成独立的代码段、数据段等。