【双队列】【NOIP2004提高组】二、合并果子

二、合并果子

(fruit.pas／dpr／c／cpp)

【问题描述】

    在一个果园里，多多已经将所有的果子打了下来，而且按果子的不同种类分成了不同的堆。多多决定把所有的果子合成一堆。

    每一次合并，多多可以把两堆果子合并到一起，消耗的体力等于两堆果子的重量之和。可以看出，所有的果子经过n-1次合并之后，就只剩下一堆了。多多在合并果子时总共消耗的体力等于每次合并所耗体力之和。

    因为还要花大力气把这些果子搬回家，所以多多在合并果子时要尽可能地节省体力。假定每个果子重量都为1，并且已知果子的种类数和每种果子的数目，你的任务是设计出合并的次序方案，使多多耗费的体力最少，并输出这个最小的体力耗费值。

    例如有3种果子，数目依次为1，2，9。可以先将1、2堆合并，新堆数目为3，耗费体力为3。接着，将新堆与原先的第三堆合并，又得到新的堆，数目为12，耗费体力为12。所以多多总共耗费体力=3+12=15。可以证明15为最小的体力耗费值。

【输入文件】

    输入文件fruit.in包括两行，第一行是一个整数n(1<＝n<=10000)，表示果子的种类数。第二行包含n个整数，用空格分隔，第i个整数ai(1<＝ai<=20000)是第i种果子的数目。

【输出文件】

    输出文件fruit.out包括一行，这一行只包含一个整数，也就是最小的体力耗费值。输入数据保证这个值小于231。

【样例输入】

3
1 2 9

【样例输出】

15

【数据规模】

对于30％的数据，保证有n<=1000：
对于50％的数据，保证有n<=5000；
对于全部的数据，保证有n<=10000。

 

利用贪心，先算的后面都会重复计算，所以要让先算的尽量小！

可以用双队列！先进行一次快排，从最小的开始选，组成的新代价加入另外一个队列，保证两个队列都有序，没去取都去两个队列中的最小两个

除了双队列，还可以用堆

Pascal Code

program fruit;//双队列

type
  qu=record
    node:array[1..10000+10] of longint;
    l,r:longint;
  end;
  
var
  n:longint;
  a,b:qu;
  

procedure init;
begin
  assign(input,'fruit.in');
  assign(output,'fruit.out');
  reset(input);
  rewrite(output);
end;
procedure outit;
begin
  close(input);
  close(output);
  halt;
end;

procedure swap(var a,b:longint);
var
  t:longint;
begin
  t:=a;a:=b;b:=t;
end;

procedure qsort(var q:qu;l,r:longint);
var
  i,j,x:longint;
begin
  i:=l;  j:=r;
  x:=q.node[(l+r)div 2];
  repeat
    while q.node[i]<x do inc(i);
    while q.node[j]>x do dec(j);
    if i<=j then
    begin
      swap(q.node[i],q.node[j]);
      inc(i);
      dec(j);
    end;
  until i>j;
  if i<r then qsort(q,i,r);
  if l<j then qsort(q,l,j);
end;

procedure pushback(var q:qu;x:longint);
begin
  with q do
  begin
    inc(r);
    node[r]:=x;
  end;
end;

function popfront(var q:qu):longint;
begin
  with q do
  begin
    inc(l);
    exit(node[l]);
  end;
end;

function getfront(var q:qu):longint;
begin
  with q do
  begin
    exit(node[l+1]);
  end;
end;

function isempty(var q:qu):boolean;
begin
  with q do
  begin
    exit(l=r);
  end;
end;

function getmin:longint;
begin
  if isempty(a) then
  begin
    exit(popfront(b));
  end;

  if isempty(b) then
  begin
    exit(popfront(a));
  end;

  if getfront(a)<getfront(b) then
  begin
    exit(popfront(a));
  end
  else begin
    exit(popfront(b));
  end;

end;

procedure readdata;
var
  i,x:longint;
begin
  read(n);
  for i:=1 to n do
  begin
    read(x);
    pushback(a,x);
  end;
  qsort(a,1,n);
end;

procedure main;
var
  i,x,sum:longint;
begin
  sum:=0;
  for  i:=1 to n-1 do
  begin
    x:=getmin+getmin;
    pushback(b,x);
    sum:=sum+x;
  end;
  writeln(sum);
end;

begin
  init;
  readdata;
  main;
  outit;
end.

 

 

附Pascal Code（堆）

program fruit;

var
  heap:array[1..100000+10] of longint;
  size:longint;
  n,sum:longint;

procedure init;
begin
  assign(input,'fruit.in');
  reset(input);
  assign(output,'fruit.out');
  rewrite(output);
end;
procedure outit;
begin
  close(input);
  close(output);
  halt;
end;

procedure exchange(var a,b:longint);
var
  t:longint;
begin
  t:=a;a:=b;b:=t;
end;

procedure insert(x:longint);
var
  i,j:longint;
begin
  inc(size);
  heap[size]:=x;
  
  i:=size;
  j:=i div 2;
  while (j>=1)and(heap[i]<heap[j]) do
  begin
    exchange(heap[i],heap[j]);
    i:=j;
    j:=i div 2;
  end;
end;

procedure delete;
var
  i,j:longint;
begin
  heap[1]:=heap[size];
  dec(size);
  
  i:=1;
  j:=i*2;
  if (j<size)and(heap[j+1]<heap[j]) then inc(j);
  while (j<=size)and(heap[i]>heap[j]) do
  begin
    exchange(heap[i],heap[j]);
    i:=j;
    j:=i*2;
    if (j<size)and(heap[j+1]<heap[j]) then inc(j);
  end;
end;

procedure readdata;
var
  i,x:longint;
begin
  readln(n);
  for i:=1 to n do
  begin
    read(x);
    insert(x);
  end;
end;

procedure main;
var
  i:longint;
  a1,a2,a:longint;
begin
  for i:=1 to n-1 do
  begin
    a1:=heap[1];
    delete;
    a2:=heap[1];
    delete;

    a:=a1+a2;
    sum:=sum+a;
    insert(a);

  end;
  writeln(sum);
end;

begin
  init;
  readdata;
  main;
  outit;
end.

 

转载于:https://www.cnblogs.com/oijzh/archive/2012/08/19/2646696.html