打开公用对话框的初始视图类型问题

终于找到了下面那几个常数的原始出处了：
http://vbnet.mvps.org/index.html?code/hooks/fileopensavedlghooklvview.htm
原来是一个叫 Brad Martinez 的高人发现的！ 

他还告诉我们，这些常数以及 WM_COMMAND 的消息他都是使用 spy++ 发现的！所以，能够做到聪明的使用工具也是高手和普通人的区别之一，惭愧！下面是他代码中一部分：

2. // These command IDs were obtained by spelunking the File Open dialog with Spy++.
3. enum {
4.     ODM_UNDEFINED   = 0,
5.     ODM_VIEW_ICONS  = 0x7029,
6.     ODM_VIEW_LIST   = 0x702b,
7.     ODM_VIEW_DETAIL = 0x702c,
8.     ODM_VIEW_THUMBS = 0x702d,
9.     ODM_VIEW_TILES  = 0x702e,
10. };
12. //
13. // This class is used to subclass the "SHELLDLL_DefView" window in the file
14. // open dialog.
15. //
16. class CListViewShellWnd : public CWnd
17. {
18. public:
19.     // These are the WM_COMMAND IDs to send to the shell window to set the
20.     // different folder views. These were obtained using Spy++ to examine
21.     // which messages are sent to the shell window.

 

=============================================================

 

不久前在回答关于“如何使打开对话框缺省显示缩略图”的问题时，我是使用模拟鼠标/键盘按键的方法来实现的（参见这里）。昨天，在浏览到 Carlos Alloatti 的网站 上时发现他新增了一个 ctl32_filedialog, ctl32_openfledialog 的类，他是使用 GetOpenFileName API 来调用 comdlg32 中的打开文件对话框；上一篇中我当时说过，要在打开公用对话框时指定视图的样式，只有 GetOpenFileNameEx 函数有此功能，但 MS 只在用于 WindowsMobile 5.0 的 API 函数库中导出了它，在用于 Windows 2K/XP/Vista 的系统中都无法使用！那 Carlos 又是怎样实现的呢？仔细分析了他的代码后发现，他使用了 vfp2c32 中的 CreateBackCallFunc 方法来创建一个回调函数，并放入 OPENFILENAME 结构中传给 GetOpenFileName API，然后在操作系统调用回调函数时找到对话框中的 SHELLDLL_DefView 窗口，发送 WM_COMMAND（？？？）消息给这个窗口，参数是: wParam 为要显示的视图类型，可用的视图类型常数定义如下：

#define SHVIEW_THUMBNAIL    0x702D
#define SHVIEW_TILE         0x702E
#define SHVIEW_ICON         0x7029
#define SHVIEW_LIST         0x702B
#define SHVIEW_REPORT       0x702C

他是如何得知可以用发送 WM_COMMAND 消息的方法，以及这几个常数来自何方就不得而知了！我在 msdn 中也没有看到过这种用法和常数定义，但此法确实可以做到更改视图类型。这样一来，原来的解决方法就可以改得更简单（不用再模拟鼠标/键盘操作了，发一条消息即可），并且更可靠一些（不用担心在模拟鼠标键盘操作时用户快速的移动鼠标来捣乱），基本思路还是用原来的，这样可以避免使用 vfp2c32.fll 外部库，更改后的代码如下：
这里我给这个表单加了一个 InitViewStyle 属性，你只要更改它为 SHVIEW_xxxx 中其他值就可以指定打开对话框的初始样式，你也可以很容易的将它改写为一个公用类，再提供一个 SetInitViewStyle 方法就可以指定打开对话框时的任意样式了。

2. #define WM_COMMAND              0x0111
3. #define WM_TIMER                0x0113  
4. #define TIMER_ID                100
6. #define SHVIEW_THUMBNAIL        0x702D
7. #define SHVIEW_TILE             0x702E
8. #define SHVIEW_ICON             0x7029
9. #define SHVIEW_LIST             0x702B
10. #define SHVIEW_REPORT           0x702C
12. PUBLIC oForm
13. oForm = NEWOBJECT( 'MyForm' ) 
14. oForm.Show()
15. READ EVENTS
17. DEFINE CLASS MyForm AS form
18.   Height = 78
19.   Width = 293
20.   DoCreate = .T.
21.   AutoCenter = .T.
22.   Caption = "Form1"
23.   AllowOutput = .F.
24.   Name = "Form1"
25.   
26.   InitViewStyle = SHVIEW_THUMBNAIL      && 你只要修改这里就可以指定缺省的打开时样式
27.   
28.   ADD OBJECT command1 AS commandbutton WITH ;
29.     Top = 24, ;
30.     Left = 180, ;
31.     Height = 27, ;
32.     Width = 84, ;
33.     Caption = "打开图片", ;
34.     Name = "command1"
36.   PROCEDURE ToggleViewStyle
37.     LPARAMETERS p1, p2, p3, p4
39.     LOCAL hWndLvw
41.     m.hWndLvw = This.FindListViewWindow()
42.     IF ( 0 != m.hWndLvw )
43.       KillTimer( This.hWnd, TIMER_ID )
44.       SendMessage( m.hWndLvw, WM_COMMAND, This.InitViewStyle, 0 )
45.     ENDIF
46.   ENDPROC
48.   PROCEDURE FindListViewWindow
49.     LOCAL hWndDlg, hWndLvw
51.     m.hWndLvw = 0
52.     m.hWndDlg = FindWindow( '#32770', This.dlg.DialogTitle ) 
53.     IF ( 0 != m.hWndDlg )
54.       m.hWndLvw = FindWindowEx( m.hWndDlg, 0, 'SHELLDLL_DefView', NULL ) 
55.     ENDIF
56.     RETURN m.hWndLvw
57.   ENDPROC
59.   PROCEDURE api_decl
60.     DECLARE Long SetTimer IN WIN32API ;
61.       Long hWnd, Long nIDEvent, Long uElapse, Long lpTimerFunc
62.     DECLARE Long KillTimer IN WIN32API ;
63.       Long hWnd, Long uIDEvent
64.     DECLARE Long FindWindow IN WIN32API ;
65.       String lpClassName, String lpWindowName
66.     DECLARE Long FindWindowEx IN WIN32API ;
67.       Long hwndParent, Long hwndChildAfter, String lpszClass, String lpszWindow
68.     DECLARE Long SendMessage IN WIN32API ;
69.       Long hWnd, Long nMsg, Long wParams, Long lParams
70.   ENDPROC
72.   PROCEDURE GetPictureFile
73.     This.api_decl()
74.     BINDEVENT( This.hWnd, WM_TIMER, This, 'ToggleViewStyle' ) 
75.     SetTimer( This.hWnd, TIMER_ID, 50, 0 )
76.     This.dlg.FileName = '' 
77.     This.dlg.ShowOpen()
78.     UNBINDEVENT( This.hWnd, WM_TIMER )
79.     RETURN This.dlg.FileName
80.   ENDPROC
82.   PROCEDURE Init
83.     This.NewObject( 'dlg', 'olecontrol',,, 'MSComDlg.CommonDialog' ) 
84.     This.dlg.DialogTitle = '请选择要打开的图片文件' 
85.   ENDPROC
87.   PROCEDURE Unload
88.     CLEAR EVENTS
89.   ENDPROC
91.   PROCEDURE command1.Click
92.     MESSAGEBOX( Thisform.GetPictureFile() )
93.   ENDPROC
94. ENDDEFINE