ABAP面向对象之抽象工厂模式（Abstract Factory Pattern）

南南阿爸

已于 2022-05-17 09:37:40 修改

阅读量103

点赞数 1

分类专栏： ABAP设计模式文章标签：抽象工厂模式

于 2022-05-17 09:36:27 首次发布

本文链接：https://blog.csdn.net/duoergui/article/details/124814382

版权

ABAP设计模式专栏收录该内容

8 篇文章 1 订阅

订阅专栏

概述

抽象工厂模式（Abstract Factory Pattern）隶属于设计模式中的创建型模式，用于产品族的构建。抽象工厂模式（Abstract Factory Pattern）是围绕一个超级工厂创建其他工厂。该超级工厂又称为其他工厂的工厂。这种类型的设计模式属于创建型模式，它提供了一种创建对象的最佳方式。

应用实例

工作了，为了参加一些聚会，肯定有两套或多套衣服吧，比如说有商务装（成套，一系列具体产品）、时尚装（成套，一系列具体产品），甚至对于一个家庭来说，可能有商务女装、商务男装、时尚女装、时尚男装，这些也都是成套的，即一系列具体产品。假设一种情况（现实中是不存在的，要不然，没法进入共产主义了，但有利于说明抽象工厂模式），在您的家中，某一个衣柜（具体工厂）只能存放某一种这样的衣服（成套，一系列具体产品），每次拿这种成套的衣服时也自然要从这个衣柜中取出了。用 OO 的思想去理解，所有的衣柜（具体工厂）都是衣柜类的（抽象工厂）某一个，而每一件成套的衣服又包括具体的上衣（某一具体产品），裤子（某一具体产品），这些具体的上衣其实也都是上衣（抽象产品），具体的裤子也都是裤子（另一个抽象产品）。

优点

当一个产品族中的多个对象被设计成一起工作时，它能保证客户端始终只使用同一个产品族中的对象。

缺点

产品族扩展非常困难，要增加一个系列的某一产品，既要在抽象的 Creator 里加代码，又要在具体的里面加代码。

使用场景

网站更换主题，一套的更换。
生成不同操作系统的程序。
注意事项：产品族难扩展，产品等级易扩展。

实现

我们将创建 Shape 和 Color 接口和实现这些接口的实体类。下一步是创建抽象工厂类 AbstractFactory。接着定义工厂类 ShapeFactory 和 ColorFactory，这两个工厂类都是扩展了 AbstractFactory。然后创建一个工厂创造器/生成器类 FactoryProducer。
AbstractFactoryPatternDemo，我们的演示类使用 FactoryProducer 来获取 AbstractFactory 对象。它将向 AbstractFactory 传递形状信息 Shape（CIRCLE / RECTANGLE / SQUARE），以便获取它所需对象的类型。同时它还向 AbstractFactory 传递颜色信息 Color（RED / GREEN / BLUE），以便获取它所需对象的类型。

创建两个接口 IF_SHAPE 和 IF_COLOR

INTERFACE  if_shape .
  METHODS draw.
ENDINTERFACE.

INTERFACE  if_color .
  METHODS fill.
ENDINTERFACE.

创建对应的这两个接口实现类

CLASS cl_rectangle DEFINITION.
  PUBLIC SECTION.
    INTERFACES if_shape.
    ALIASES draw FOR if_shape~draw.
ENDCLASS.

CLASS cl_rectangle IMPLEMENTATION.
  METHOD draw.
    WRITE:/ 'Inside cl_rectangle->draw() method.'.
  ENDMETHOD.
ENDCLASS.


CLASS cl_square  DEFINITION.
  PUBLIC SECTION.
    INTERFACES if_shape.
    ALIASES draw FOR if_shape~draw.
ENDCLASS.


CLASS cl_square IMPLEMENTATION.
  METHOD draw.
    WRITE:/ 'Inside cl_square->draw() method.'.
  ENDMETHOD.
ENDCLASS.


CLASS cl_circle  DEFINITION.
  PUBLIC SECTION.
    INTERFACES if_shape.
    ALIASES draw FOR if_shape~draw.
ENDCLASS.



CLASS cl_circle IMPLEMENTATION.
  METHOD draw.
    WRITE:/ 'Inside cl_circle->draw() method.'.
  ENDMETHOD.
ENDCLASS.


CLASS cl_red DEFINITION.
  PUBLIC SECTION.
    INTERFACES if_color.
    ALIASES fill FOR if_color~fill.
ENDCLASS.

CLASS cl_red IMPLEMENTATION.
  METHOD fill.
    WRITE:/ 'Inside cl_red->fill() method.'.
  ENDMETHOD.
ENDCLASS.

CLASS cl_blue DEFINITION.
  PUBLIC SECTION.
    INTERFACES if_color.
    ALIASES fill FOR if_color~fill.
ENDCLASS.

CLASS cl_blue IMPLEMENTATION.
  METHOD fill.
    WRITE:/ 'Inside cl_blue->fill() method.'.
  ENDMETHOD.
ENDCLASS.

CLASS cl_green DEFINITION.
  PUBLIC SECTION.
    INTERFACES if_color.
    ALIASES fill FOR if_color~fill.
ENDCLASS.

CLASS cl_green IMPLEMENTATION.
  METHOD fill.
    WRITE:/ 'Inside cl_green->fill() method.'.
  ENDMETHOD.
ENDCLASS.

创建一个抽象工厂类

CLASS cl_abstract_factory  DEFINITION
                           ABSTRACT.
  PUBLIC SECTION.
    METHODS:  get_shape ABSTRACT
      IMPORTING
                iv_shape_type      TYPE string
      RETURNING VALUE(ro_instance) TYPE REF TO if_shape.

    METHODS:  get_color ABSTRACT
      IMPORTING
                iv_color           TYPE string
      RETURNING VALUE(ro_instance) TYPE REF TO if_color.
ENDCLASS.


CLASS cl_shape_factory DEFINITION
  INHERITING FROM cl_abstract_factory.

  PUBLIC SECTION.
    METHODS:  get_shape REDEFINITION .
    METHODS:  get_color REDEFINITION .
ENDCLASS.

分别实现子类SHAPE和COLOR的子类

CLASS cl_shape_factory IMPLEMENTATION.
  METHOD get_shape .
    CASE to_upper( iv_shape_type ).
      WHEN 'CIRCLE'.
        ro_instance = NEW cl_circle( ).
      WHEN 'RECTANGLE'.
        ro_instance = NEW cl_rectangle( ).
      WHEN 'SQUARE'.
        ro_instance = NEW cl_square( ).
      WHEN OTHERS.
    ENDCASE.
  ENDMETHOD.

  METHOD get_color.

  ENDMETHOD.
ENDCLASS.


CLASS cl_color_factory DEFINITION
INHERITING FROM cl_abstract_factory.

  PUBLIC SECTION.
    METHODS:  get_shape REDEFINITION .
    METHODS:  get_color REDEFINITION .

ENDCLASS.

CLASS cl_color_factory IMPLEMENTATION.
  METHOD get_shape .
  ENDMETHOD.

  METHOD get_color.
    CASE to_upper( iv_color ).
      WHEN 'RED'.
        ro_instance = NEW cl_red( ).
      WHEN 'BLUE'.
        ro_instance = NEW cl_blue( ).
      WHEN 'GREEN'.
        ro_instance = NEW cl_green( ).
      WHEN OTHERS.
    ENDCASE.
  ENDMETHOD.
ENDCLASS.

生成超级工厂生成类

CLASS cl_factory_producer DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS:  get_factory
      IMPORTING iv_choice          TYPE string
      RETURNING VALUE(ro_instance) TYPE REF TO cl_abstract_factory.
ENDCLASS.


CLASS cl_factory_producer IMPLEMENTATION.
  METHOD get_factory.
    CASE to_upper( iv_choice ).
      WHEN 'SHAPE'.
        ro_instance = NEW cl_shape_factory( ).
      WHEN 'COLOR'.
        ro_instance = NEW cl_color_factory( ).
      WHEN OTHERS.
    ENDCASE.
  ENDMETHOD.
ENDCLASS.

最后测试

CLASS cl_application DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS:  run .
ENDCLASS.

CLASS cl_application IMPLEMENTATION.
  METHOD run.
    DATA(lo_shape_factory) = cl_factory_producer=>get_factory('SHAPE').

    "获取 Circle 的对象，并调用它的 draw 方法
    DATA(lo_shape1) = lo_shape_factory->get_shape( 'CIRCLE' ).

    " 调用 Circle 的 draw 方法
    lo_shape1->draw( ).

    "获取 Rectangle 的对象，并调用它的 draw 方法
    DATA(lo_shape2)  = lo_shape_factory->get_shape( 'RECTANGLE').

    "调用 Rectangle 的 draw 方法
    lo_shape2->draw( ).

    "获取 Square 的对象，并调用它的 draw 方法
    DATA(lo_shape3)  = lo_shape_factory->get_shape( 'SQUARE').

    "调用 Square 的 draw 方法
    lo_shape3->draw( ).


    DATA(lo_color_factory) = cl_factory_producer=>get_factory('COLOR').

    "获取 RED 的对象，并调用它的 fill 方法
    DATA(lo_color1) = lo_color_factory->get_color( 'RED' ).

    " 调用 RED 的 fill 方法
    lo_color1->fill( ).

    "获取 BLUE 的对象，并调用它的 fill 方法
    DATA(lo_color2)  = lo_color_factory->get_color( 'BLUE').

    "调用 BLUE 的 fill 方法
    lo_color2->fill( ).

    "获取 GREEN 的对象，并调用它的 fill 方法
    DATA(lo_color3)  = lo_color_factory->get_color( 'GREEN').

    "调用 GREEN 的 fill 方法
    lo_color3->fill( ).
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  cl_application=>run(  ).