FtpWebRequest与FtpWebResponse类用来与特定FTP服务器进行沟通。
FtpWebRequest 与 FtpWebResponse 类分别继承了 WebRequest 与 WebRequest。
FtpWebRequest负责将指令传送至FTP服务器;
FtpWebResponse则封装服务器所返 回的消息。
FtpWebRequest 封装FTP客户端的功能集成;
FtpWebResponse 封装FTP服务器的返回消息,从而取得FTP返回的消息码与文件数据,这些数据内容以数据流的形式返回。
FtpStatusCode列举类表示FTP操作返回的状态代码,它的列举值代表各种FTP操作的状态描述。例如:
AccountNeeded 表示服务器上需要用户账户;
BadCommandSequence 表示命令的顺序不正确;
FileActionOK 指定所要求的文件传输动作成功执行完成等。
一、联机
若要建立FTP联机,进而与FTP服务器沟通之前,需建立FtpWebRequest实体对象。
同样,FTP协议也需调用WebRequest的Create()方法建立FtpWebRequest 实体:
Dim myFtpWebRequest As FtpWebRequest = CType(FtpWebRequest.Create(target),FtpWebRequest)
参数target为FTP配置的网络资源URI。同前面HttpWebRequest一样,FtpWebRequest.Create(target)返回类型是WebRequest,所以需要转类型为FtpWebRequest。
建立FtpWebRequest对象后,即可从FtpWebRequest.GetResponse()取得封装服务器响应消息的FtpWebResponse对象,完成应用程序所要进行的FTP操作。
Using myResponse As FtpWebResponse =CType(myFtpWebRequest.GetResponse, FtpWebResponse)
与FTP服务器联机沟通之前,先确定应用程序要执行的操作,如上传下载文件、 目录增删列举等。
FTP服务器在接收到应用程序引用GetResponse()方法要求返回操作消息的时候,会根据应用程序所指定的方法进行相关操作,故要在此之前预先指定FTP 所要执行的方法。
简单地说:联机发起的同时,也发送操作指令。回应指令的同时也完成客户端的指令。
FTP操作由WebRequestMethods.Ftp类所定义,字段集如下:
1、文件操作
AppendFile FTP APPE通信协议方法,用来将文件附加到FTP服务器上的现有文件DeleteFile FTP DELE通信协议方法,用来删除FTP服务器上的文件
DownloadFile FTP RETR通信协议方法,用来从FTP服务器下栽文件
UploadFile 将文件上传到FTP服务器的FTP STOR通信协议方法
UploadFileWithUniqucName 将文件名唯一的文件上传到FTP服务器的FTP STOU通信协议方法
GetFileSize 表示FTP SIZE通信协议方法,用来获取FTP服务器上文件的大小
2、目录操作
PrintWorkingDirectory 表示FTP PWD通倍协议方法,用来显示当前工作目录的名称
ListDirectory 表示FTP NLIST通信协议方法,用来取得FTP服务器上文件的简短列表
ListDirectoryDetails 表示FTP LIST通信协议方法,用来取得FTP眼务器上文件的详细列表
MakeDirectory 表示FTP MKD通信协议方法,用来在FTP服务器上建立目录
RemoveDirectory 删除目录的FTP RMD通信协议方法
Rename 重新命名目录的FTP RENAME通信协议方法
上面FTP操作方法通过FileWebRequestMethod属性的设置:
myFtpWebRequest.Method = WebRequestMethods.Ftp.DownloadFile
四、FTP认证信息
FTP服务器一般会要求提供登录账号与密码,只有完成验证才能登录FTP服务器,进行FTP操作。
认证信息直接通过FtpWebRequest.Credentials属性进行设置.
Public Overrides Property Credentials As ICredentials
需指定一个实际应用ICredentials接口的对象,用来封装账号与密码等相关信息。
例如NetworkCredential对象,通过FtpWebRequest.Credentials属性随着myFtpWebRequest对象传递到FTP服务器中:
Dim myNetworkCredential = New NetworkCredential(username, uaerpwd)
myFtpWebRequest.Credentials = myNetworkCredential
五、完成FTP功能的操作
完成任意一种FTP操作,应完成以下步骤:
(1)WebRequest.Create()方法建立FtpWebRequest 实体。
(2)指定认证信息FtpWebRequest.Credentials。
(3)指定操作种类WebRequestMethods.Ftp。
(4)取得FtpWebRequest数据流,进行数据传输操作。
(5)FtpWebRequest.GetResponse()方法取得FTP服务器响应信息对象 FtpWebResponse。
(6)取得FtpWebRequest数据流,进一步读取服务器端响应的数据内容。
1-3步是必须的(连接、认证、操作),一些操作如上传与下载还要4-6步。
六、FTP目录操作
即对FTP服务器上目录进行新增、删除、修改,甚至目录列举操作。
1、新建、删除、更名目录
Imports System.Net
Public Class Form1
Private Sub txtOpera_Click(sender As Object, e As EventArgs) Handles txtOpera.Click
DirOperation()
End Sub
Private Sub DirOperation()
Try
Dim frq As FtpWebRequest = CType(FtpWebRequest.Create(txtFTP.Text), FtpWebRequest)
Dim fcr As New NetworkCredential(txtUser.Text, txtPassword.Text)
Dim frp As FtpWebResponse
frq.Credentials = fcr '认证信息
Select Case True
Case rdoMake.Checked
frq.Method = WebRequestMethods.Ftp.MakeDirectory
Case rdoDele.Checked
frq.Method = WebRequestMethods.Ftp.RemoveDirectory
Case rdoReName.Checked
If txtNewFTP.Text <> "" Then
frq.Method = WebRequestMethods.Ftp.Rename
frq.RenameTo = txtNewFTP.Text
End If
Case Else
MsgBox("未选择!")
End Select
frp = CType(frq.GetResponse, FtpWebResponse) '发送、操作、并返回
frp.Close()
Catch ex As Exception
MsgBox(ex.Message)
End Try
End Sub
End Class
2、列举目录
向服务发送列举目录指令,服务器端会将所有指定目录下面的子目录及文件名写入数据流,然后返回到客户端,因此列举目录的时候必须进一步取得响应对象的数据流对象:
Dim myStream As Stream = myResponse.GetResponseStream()
取得服务器FtpWebResponse.GetResponseStream()返回的数据流,对该流进行读写即可得目录列举信息。
要取得目录列举信息,需设置 Method属性为ListDirectory或是ListDirectoryDetails:
ListDirectory 只单纯地列举文件目录名称;
ListDirectoryDetails 进一步列举相关的文件目录特性。
Imports System.Net
Imports System.IO
Imports System.Text
Public Class Form1
Private Sub btnFtpList_Click(sender As Object, e As EventArgs) Handles btnFtpList.Click
Try
Dim frq As FtpWebRequest = CType(FtpWebRequest.Create(txtFTP.Text), FtpWebRequest)
Dim cre As New NetworkCredential(txtUser.Text, txtPassword.Text)
Dim frp As FtpWebResponse
Dim st As Stream
Dim sr As StreamReader
frq.Credentials = cre
If rdoSimple.Checked = True Then
frq.Method = WebRequestMethods.Ftp.ListDirectory
Else
frq.Method = WebRequestMethods.Ftp.ListDirectoryDetails
End If
frp = CType(frq.GetResponse, FtpWebResponse)
st = frp.GetResponseStream
sr = New StreamReader(st, Encoding.UTF8) '对响应流读取
txtListDrectory.Text = sr.ReadToEnd
frp.Close()
Catch ex As Exception
MsgBox(ex.Message)
End Try
End Sub
End Class
七、FTP文件操作
(一)FTP下载
通过FtpWebResponse.GetResponseStream()用取得服务器(要下载的)数据流,再通过文件流FileStream用字节组写入文件,来完成FTP的下载过程。
Imports System.Net
Imports System.IO
Public Class Form1
Private Sub btnDown_Click(sender As Object, e As EventArgs) Handles btnDown.Click
Dim frq As FtpWebRequest, frp As FtpWebResponse, fcr As NetworkCredential
Dim st As Stream, fs As FileStream
Dim byt(1024) As Byte, intCount As Integer
Try
frq = CType(WebRequest.Create(New Uri(txtFtp.Text)), FtpWebRequest)
fcr = New NetworkCredential(txtUser.Text, txtPassword.Text)
frq.Credentials = fcr
frq.Method = WebRequestMethods.Ftp.DownloadFile
frq.UseBinary = True
frp = CType(frq.GetResponse, FtpWebResponse)
st = frp.GetResponseStream
fs = New FileStream(txtSave.Text, FileMode.Create)
Do
intCount = st.Read(byt, 0, 1024)
fs.Write(byt, 0, intCount)
Loop While intCount > 0
fs.Close()
frp.Close()
Catch ex As Exception
MsgBox(ex.Message)
End Try
End Sub
End Class
(二)FTP上载
上传与下载相反,下载时通过FtpWebResponse.GetResponseStream()方法取得数据流,再对该流进行写入本地文件。
上传时,则是在请求流FtpWebRequest.GetRequestStream()加载数据(文件),由此完成上传任务。
请求流格式:
Public Overrides Function GetRequestStream As Stream
此方法返回一个Stream数据流对象,写入此数据流的数据内容,进一步被送到要求链接的服务器,完成上传操作。
Imports System.Net
Imports System.IO
Public Class Form1
Private Sub btnFtp_Click(sender As Object, e As EventArgs) Handles btnFtp.Click
Dim frq As FtpWebRequest, frp As FtpWebResponse
Dim st As Stream, fs As FileStream
Dim byt(1024) As Byte, intCount As Integer
frq = CType(WebRequest.Create(txtFile.Text), FtpWebRequest)
frq.Credentials = New NetworkCredential(txtUser.Text, txtPassword.Text)
frq.Method = WebRequestMethods.Ftp.UploadFileWithUniqueName
st = frq.GetRequestStream
fs = New FileStream(txtFile.Text, FileMode.Open, FileAccess.Read)
Do
intCount = fs.Read(byt, 0, 1024) '将文件流加载到请求流上
st.Write(byt, 0, intCount)
Loop While (intCount > 0)
frp = CType(frq.GetResponse, FtpWebResponse)
frp.Close()
MsgBox("完成!")
End Sub
End Class
八、WebClient替代FTP的上传与下载
WebClient替代FTP单纯的下载与上传,将更简捷。
WebClient的两方法UploadFile()与DownloadFile()提供上传下下载功能:
Public Sub DownloadFile ( address As Uri, fileName As String)
Public Function UploadFile ( address As Uri, fileName As String )As Byte