With 语句
我要讲的最后一种 Pascal 语句是 With 语句,With 语句是 Pascal 编程语言独有的语句,不过最近 JavaScript 和 Visual Basic 也添加了这种语句,它在 Delphi 程序设计中很有用。
With 语句是一种用于简化代码的语句。如你要访问一个记录类型变量(或一个对象),用 With 语句就不必每次重复变量的名字。例如对于以下的记录类型代码:
Type
Date = record
Year: Integer;
Month: Byte;
Day: Byte;
end;
var
BirthDay: Date;
begin
BirthDay.Year := 1997;
BirthDay.Month := 2;
BirthDay.Day := 14;
可以用 with 语句改进后半部分代码,如下:
begin
with BirthDay do
begin
Year := 1995;
Month := 2;
Day := 14;
end;
在 Delphi 程序中,这种方法能用于访问控件和类变量。现在通过 with 语句访问列表框的条目,我们重写上面循环例子的最后部分:
procedure TForm1.WhileButtonClick(Sender: TObject);
var
I: Integer;
begin
with ListBox1.Items do
begin
Clear; // shortcut
Randomize;
I := 0;
while I < 1000 do
begin
I := I + Random (100);
// shortcut:
Add ('Random Number: ' + IntToStr (I));
end;
end;
end;
当你使用控件或类时,with 语句通常能简化你的代码,尤其对嵌套域。例如,你要改变窗体画笔的宽度和颜色,你可以写代码如下:
Form1.Canvas.Pen.Width := 2;
Form1.Canvas.Pen.Color := clRed;
但如果用 With 语句代码会更简单:
with Form1.Canvas.Pen do
begin
Width := 2;
Color := clRed;
end;
当编写的代码很复杂时,with 语句会很有用,也可省去一些临时变量。但是这样做也有缺点,因为这样将使代码的可读性变差,特别对有相似或相同属性的对象。
更严重的是,使用 with 语句可能会在代码中融入微妙的逻辑错误,甚至连编译器都难以发现。例如:
with Button1 do
begin
Width := 200;
Caption := 'New Caption';
Color := clRed;
end;
这段代码改变了按钮的 Caption 和 Width 属性,但也改变了窗体的 Color 属性,而不是按钮的颜色!其原因是 TButton 控件没有 Color 属性, 又由于执行的代码是针对窗体对象的(我们正在写窗体的方法),所以窗体对象即成为默认的访问对象。如果这样写:
Button1.Width := 200;
Button1.Caption := 'New Caption';
Button1.Color := clRed; // error!
编译器会给出一个错误。通常,由于 with 语句在当前的块中定义了新的标识符,省略了原有的标识符,可能引起在同一块内错误地访问另一个标识符(就象上面的这段代码)。即使存在种种缺陷,我还是建议你习惯于使用 with 语句,因为 with 语句确实是非常便利,并且有时也会使代码更容易读懂。
然而,你应该避免使用多个 with 语句,如:
with ListBox1, Button1 do...
这样会使后面的代码非常难读,因为,对该块中定义的每个属性,你都要根据相应的属性以及控件的次序,才能推出所访问的控件。
注意:说到可读性,要知道 Pascal 没有 endif 或 endcase 语句。如果 if 语句有一个 begin-end 块,那么 end 标志语句结束;另外,case 语句也总是以一个end 结束。所有这些 end 语句,常常是一个接一个,使代码难以理解,只有通过缩排跟踪,才能追出一个 end 所对应的语句。解决这个问题的一个通用办法, 也是使代码更可读的办法,是在 end 后面加注释,如下例:
if ... then
...
end; // if