windows批处理php-cgi.bat隐藏运行php

隐藏运行php

配置好路径及exe名称

双击启动，再双击停止

如不能停止请使用任务管理器停止

:php-cgi.bat

@echo off
if "%1"=="h" goto begin
start mshta vbscript:createobject("wscript.shell").run("%~nx0"^&" h",0)^&(window.close) && exit
:begin

echo [%time%]: batch is running.
setlocal
set "processName=php-cgi.exe"
set "common_path=D:\server\php"
set "common_start=php-cgi -b 127.0.0.1:9000 -c php.ini"
set "common_stop=taskkill /f /t /im php-cgi.exe"
cd %common_path%
tasklist | findstr /i "%processName%" >nul
if errorlevel 1 (
    echo %processName% start.
    %common_start%
) else (
    echo %processName% stop.
    %common_stop%
)
endlocal

rem 3秒退出
timeout /t 3

nginx启动停止

:nginx.bat

 

@echo off
setlocal

rem 设置进程名称
set "processName=nginx.exe"

rem 设置进程路径
set "common_path=D:\server\nginx-1.24.0"

rem 设置进程启动命令
set "common_start=start nginx"

rem 设置进程停止命令
set "common_stop=nginx -s stop"

rem 进入进程目录
cd %common_path%

rem 查找进程状态
tasklist | findstr /i "%processName%" >nul

if errorlevel 1 (
    rem 启动
    echo %processName% start.
    %common_start%
) else (
    rem 停止
    echo %processName% stop.
    %common_stop%

)
endlocal

rem 3秒退出
timeout /t 3

参考

https://blog.csdn.net/B11050729/article/details/131711612