洛谷P1280 尼克的任务

洛谷P1280 尼克的任务

---

题目

题目描述

尼克每天上班之前都连接上英特网，接收他的上司发来的邮件，这些邮件包含了尼克主管的部门当天要完成的全部任务，每个任务由一个开始时刻与一个持续时间构成。

尼克的一个工作日为N分钟，从第一分钟开始到第N分钟结束。当尼克到达单位后他就开始干活。如果在同一时刻有多个任务需要完戍，尼克可以任选其中的一个来做，而其余的则由他的同事完成，反之如果只有一个任务，则该任务必需由尼克去完成，假如某些任务开始时刻尼克正在工作，则这些任务也由尼克的同事完成。如果某任务于第P分钟开始，持续时间为T分钟，则该任务将在第P+T-1分钟结束。

写一个程序计算尼克应该如何选取任务，才能获得最大的空暇时间。

输入输出格式

输入格式：
输入数据第一行含两个用空格隔开的整数N和K(1≤N≤10000，1≤K≤10000)，N表示尼克的工作时间，单位为分钟，K表示任务总数。

接下来共有K行，每一行有两个用空格隔开的整数P和T，表示该任务从第P分钟开始，持续时间为T分钟，其中1≤P≤N，1≤P+T-1≤N。

输出格式：
输出文件仅一行，包含一个整数，表示尼克可能获得的最大空暇时间。

输入输出样例

输入样例#1：

15 6
1 2
1 6
4 11
8 5
8 1
11 5

输出样例#1：

4

---

题解

DP题

F[i]表示从时间i到时间n之间的最短工作时间

那么，我们可以想到，当时间i没有任务的时候,那么F[i]=F[i+1],有任务的时候就是所有开始时间为i的任务所做完该任务的时间+做完该任务后所需要工作的时间的最小值

由于,maxn=10000,所以不能直接用二维数组记录任务，这就需要写一个邻接表来完成任务的记录

---

代码（Pascal）

var n,m,tot:longint;
    a,b:array[0..10005]of longint;
    f:array[0..10005] of longint;
    task:array[0..10005]of record
                             t,nxt:longint;
                            end;
    lnk:array[0..10005]of longint;
 procedure add(x,y:longint);
  begin
    inc(tot);task[tot].t:=y;task[tot].nxt:=lnk[x];lnk[x]:=tot;
   end;
 procedure init;
  var i,x,y:longint;
   begin
     readln(n,m);
     tot:=0;
     fillchar(lnk,sizeof(lnk),0);
     for i:=1 to m do
      begin
        readln(x,y);
        add(x,y);
       end;
    end;
 function min(x,y:longint):longint;
  begin
    if x<y then exit(x) else exit(y);
   end;
 procedure main;
  var i,j:longint;
   begin
     fillchar(f,sizeof(f),0);
     for i:=n downto 1 do
      begin
        if lnk[i]<>0 then
         begin
           f[i]:=maxlongint;
           j:=lnk[i];
           while j<>0 do
            begin
              f[i]:=min(f[i],f[task[j].t+i]+task[j].t);
              j:=task[j].nxt;
             end;
          end
        else f[i]:=f[i+1];
       end;
    end;
 procedure print;
  begin
    write(n-f[1]);
   end;
 begin
   init;
   main;
   print;
  end.