JZOJ 4211 - 【五校联考1day2】送你一颗圣诞树

题目地址

描述

有$n+1$棵树$T_0,T_1,\dots ,T_n$。$T_0$只有$0$号节点，对于$T_i(i\in [\mathrm{1..}m])$，给出$a_{i,1},a_{i,2},b_{i,1},b_{i,2},le{n}_i$，表示这棵树是由$T_{a_{i,1}}$与$T_{b_{i,1}}$构成，且$T_{a_{i,1}}$的第$a_{i,2}$个点与$T_{b_{i,1}}$的第$b_{i,2}$个点连接一条长度为$le{n}_i$的边。在$T_i$中，保持$T_{a_{i,1}}$中的所有节点编号不变，如果$T_{a_{i,1}}$中有$s$个节点，他会把$T_{b_{i,1}}$中的所有节点的编号加上$s$。

对于$T_i(i\in [\mathrm{1..}n])$，求位于$T_i$中互不相同的两个点的距离之和。

$n\le 10^2$，$0\le ai,bi<i$，$0\le li\le 10^9$

分析

令$An{s}_i$表示$T_i$的答案，$siz{e}_i$表示$\left|T_i\right|$，$to{p}_{v,x}$表示$T_v$中所有节点与$x$的距离之和。则

$$An{s}_i=An{s}_{a_{i,1}}+An{s}_{b_{i,1}}+to{p}_{a_{i,1},a_{i,2}}\times siz{e}_{b_{i,1}}+to{p}_{b_{i,1},b_{i,2}}\times siz{e}_{a_{i,1}}+le{n}_i\times siz{e}_{a_{i,1}}\times siz{e}_{b_{i,1}}$$

定义solve(v,x)求解$to{p}_{v,x}$，设$Di{s}_{v,x,y}$表示在$T_v$中$x\to y$的距离。

考虑将$T_v$分成$T_{a_{v,1}},T_{b_{v,1}}$

• $v=0$。solve(v,x)返回$0$
• $x<siz{e}_{a_{v,1}}$。说明$x$在$T_{a_{v,1}}$中，solve(v,x)返回$to{p}_{a_{v,1},x}+to{p}_{b_{v,1},b_{v,2}}+(le{n}_v+Di{s}_{a_{v,1},a_{v,2},x})\times siz{e}_{b_{v,1}}$
• $x\ge siz{e}_{a_{v,1}}$。同理得到一个类似的返回值。

于是调用solve(v,x)即可得到$to{p}_{v,x}$。问题转化为求解$Di{s}_{v,x,y}$

• $x=y$或$v=0$，返回$0$
• $x,y$在$T_v$中同一棵树中，则继续递归下去。
• 否则，令$x<y$，则$Di{s}_{v,x,y}\leftarrow Di{s}_{a_{v,1},a_{v.2},x}+Di{s}_{b_{v,1},b_{v,2},y}+le{n}_v$

用$Hash$记忆化一下即可。

时间复杂度$O(n^3)$

代码

const
        mo=1000000007; mo1=449363; mo2=447001;
var
        t,n,i:longint;
        a,b:array[0..60,0..2] of int64;
        hash:array[0..500000,1..3] of int64;
        hash2:array[0..500000,1..4] of int64;
        ans,len,size,size1:array[0..60] of int64;
procedure swap(var x,y:int64);
var
        z:int64;
begin
        z:=x; x:=y; y:=z;
end;

procedure put(x:longint;y,z:int64);
var
        k:longint;
begin
        k:=(sqr(x)+sqr(y mod mo1)) mod mo1;

        while hash[k,3]<>0 do inc(k);

        hash[k,1]:=x; hash[k,2]:=y; hash[k,3]:=z;
end;

function find(x:longint;y:int64):longint;
var
        k:longint;
begin
        k:=(sqr(x)+sqr(y mod mo1)) mod mo1;

        while hash[k,3]<>0 do
        begin
                if (hash[k,1]=x) and (hash[k,2]=y) then exit(hash[k,3]);

                inc(k);
        end;

        exit(0);
end;

procedure put2(x:longint;y,z,o:int64);
var
        k:longint;
begin
        k:=(sqr(x)+sqr(y mod mo2)+sqr(z mod mo2)) mod mo2;

        while hash2[k,4]<>0 do inc(k);

        hash2[k,1]:=x; hash2[k,2]:=y; hash2[k,3]:=z; hash2[k,4]:=o;
end;

function find2(x:longint;y,z:int64):longint;
var
        k:longint;
begin
        k:=(sqr(x)+sqr(y mod mo2)+sqr(z mod mo2)) mod mo2;

        while hash2[k,3]<>0 do
        begin
                if (hash2[k,1]=x) and (hash2[k,2]=y) and (hash2[k,3]=z) then exit(hash2[k,4]);

                inc(k);
        end;

        exit(0);
end;

function dis(v:longint;x,y:int64):int64;
var
        now:int64;
begin
        if (v=0) or (x=y) then exit(0);

        now:=find2(v,x,y); if now>0 then exit(now);

        if (x<size[a[v,1]]) and (y<size[a[v,1]]) then
                now:=dis(a[v,1],x,y)
        else
        if (x>=size[a[v,1]]) and (y>=size[a[v,1]]) then
                now:=dis(b[v,1],x-size[a[v,1]],y-size[a[v,1]])
        else
        begin
                if x>y then swap(x,y);

                now:=(dis(a[v,1],a[v,2],x)+dis(b[v,1],b[v,2],y-size[a[v,1]])+len[v]) mod mo;
        end;

        put2(v,x,y,now); exit(now);
end;

function solve(v:longint;x:int64):int64;
var
        now:int64;
begin
        if v=0 then exit(0);

        now:=find(v,x); if now>0 then exit(now);

        if x<size[a[v,1]] then
                now:=solve(a[v,1],x)+solve(b[v,1],b[v,2])+(len[v]+dis(a[v,1],a[v,2],x)) mod mo*size1[b[v,1]] mod mo
        else
                now:=solve(b[v,1],x-size[a[v,1]])+solve(a[v,1],a[v,2])+(len[v]+dis(b[v,1],b[v,2],x-size[a[v,1]])) mod mo*size1[a[v,1]] mod mo;

        now:=now mod mo; put(v,x,now); exit(now);
end;

begin
        readln(t);

        while t>0 do
        begin
                readln(n); dec(t);

                size[0]:=1; size1[0]:=1; fillchar(hash,sizeof(hash),0); fillchar(hash2,sizeof(hash2),0);

                for i:=1 to n do
                begin
                        readln(a[i,1],b[i,1],a[i,2],b[i,2],len[i]); len[i]:=len[i] mod mo; size[i]:=size[a[i,1]]+size[b[i,1]]; size1[i]:=size[i] mod mo;
                end;

                ans[0]:=0;

                for i:=1 to n do
                begin
                        ans[i]:=ans[a[i,1]]+ans[b[i,1]];
                        ans[i]:=ans[i]+solve(a[i,1],a[i,2])*size1[b[i,1]] mod mo;
                        ans[i]:=ans[i]+solve(b[i,1],b[i,2])*size1[a[i,1]] mod mo;
                        ans[i]:=ans[i]+len[i]*size1[a[i,1]] mod mo*size1[b[i,1]] mod mo;
                        ans[i]:=ans[i] mod mo;

                        writeln(ans[i]);
                end;
        end;
end.