小胖办证（Vijos1139）

算法：DP

分析：本题类似于一道经典题目数字三角形，但是由于每行可以左右移动，因此有后效性，所以在做的时候应该分开求，先求从左到右的，再求从右到左的。

      最后用一个伪递归输出路径。

program Vijos1139;

const
 {找了半天错误发现是这里的数据范围写错了……囧……}
 maxn=100;
 maxm=500;
 maxans=50000;
 
type
 atp=record
  x,y:longint;
 end;

var
 n,m:longint;
 a:array [-1..maxn,-1..maxm] of longint;
 f:array [-1..maxn,-1..maxm] of int64;
 ans:array [0..maxans] of longint;
 map:array [0..maxn,0..maxm] of atp;

procedure init;
var
 i,j:longint;
begin
 readln(n,m);
 for i:=1 to n do
  begin
   for j:=1 to m do read(a[i,j]);
   readln;
  end;
end;

procedure main;
var
 i,j:longint;
begin
 for i:=1 to n+1 do for j:=0 to m+1 do f[i,j]:=maxlongint;{可以用一个fillchar，然后把第0行初始化为0。}
 for i:=1 to n do 
  begin
   for j:=1 to m do
    begin
     if f[i-1,j]+a[i,j]<f[i,j] then
      begin
       f[i,j]:=f[i-1,j]+a[i,j];
       map[i,j].x:=i-1;
       map[i,j].y:=j;
      end;
     if f[i,j-1]+a[i,j]<f[i,j] then
      begin
       f[i,j]:=f[i,j-1]+a[i,j];
       map[i,j].x:=i;
       map[i,j].y:=j-1;
      end;
    end;  
   for j:=m downto 1 do
    begin
     if f[i-1,j]+a[i,j]<f[i,j] then
      begin
       f[i,j]:=f[i-1,j]+a[i,j];
       map[i,j].x:=i-1;
       map[i,j].y:=j;
      end;    
     if f[i,j+1]+a[i,j]<f[i,j] then
      begin
       f[i,j]:=f[i,j+1]+a[i,j];
       map[i,j].x:=i;
       map[i,j].y:=j+1;
      end;
    end;
  end;
end;

procedure outit;
var
 i,min,x1,y1,tot,xt,yt:longint;
begin
 fillchar(ans,sizeof(ans),0);
 x1:=n;
 min:=maxlongint;
 for i:=1 to m do 
  begin
   if f[n,i]<min then
    begin
     min:=f[n,i];
     y1:=i;
    end;
  end;
 tot:=1;
 ans[tot]:=y1;
 while x1<>1 do{中止条件。}
  begin
   xt:=map[x1,y1].x;
   yt:=map[x1,y1].y;
   inc(tot);
   ans[tot]:=yt;
   x1:=xt;
   y1:=yt;
  end;
 for i:=tot downto 1 do writeln(ans[i]);{倒着输出。}
end;

begin
 assign(input,'VJ1139.in'); reset(input);
 assign(output,'VJ1139.out'); rewrite(output);
 
 init;
 main;
 outit;
 
 close(input); close(output);
end.