2017年8月8日提高组T2 呀！回文串

Description

小B的名字是由前n个小写字母组成的一个长度为m字符串。一天，小B看上了一个金发碧眼的漂亮妹子，但妹子在知道了小B的名字后，就无情地抛弃了小B，而原因竟然是小B的名字不够优美！在小B的追问下，妹子告诉小B，只有回文串是优美的。于是小B决定把自己的名字变得优美，但每加入或删除一个字母都要付出一定的代价。为了小B的人生大事，请你告诉小B他最少需要付出多少代价。

Input

第一行两个数分别表示n和m。
第二行是一个长度为m的字符串，仅由前n个小写字母组成。
接下来n行，每行含有一个字母和两个正整数，表示添加和删除这个字母的费用。

Output

一行一个整数，表示最小费用。

Sample Input

3 4
abbc
a 10 10
b 20 20
c 30 30
Sample Output

40
Hint

【数据规模与约定】
对于前30%的数据，m <= 10
对于前50%的数据，m <=100
对于前100%的数据，n<=26,m<=2000,0<=费用<=10000
做法：dp，设f[i,j]表示把[i,j]这段变成回文串所需要的最小代价。注意到删除和加入并没有本质上的区别，所以我们设cost[x]=min(add[x],del[x])，那么f[i,j]=min(f[i+1,j]+cost[s[i]],f[i,j-1]+cost[s[j]])，如果s[i]==s[j]，则f[i,j]=min(f[i,j],f[i+1,j-1])。
代码如下：

var
  s:ansistring;
  n,m:longint;
  cost:array['a'..'z'] of longint;
  f:array[0..2007,0..2007] of longint;

function min(a,b:longint):longint;
begin
  if a>b then exit(b);
  exit(a);
end;

procedure init;
var
  i:longint;  z:char; x,y:longint;
begin
  readln(n,m);
  readln(s);
  for i:=1 to n do
    begin
      readln(z,x,y);
      cost[z]:=min(x,y);
    end;
end;

procedure work;
var
  i,j:longint;
begin
  for i:=m-1 downto 1 do
    for j:=i+1 to m do
      begin
        f[i,j]:=min(f[i+1,j]+cost[s[i]],f[i,j-1]+cost[s[j]]);
         if s[i]=s[j] then f[i,j]:=min(f[i+1,j-1],f[i,j]);
      end;
  writeln(f[1,m]);
end;

begin
  init;
  work;
end.