VCL类学习之(八) TCustomMemoryStream

TCustomMemoryStream is an abstract base class used as the common ancestor for memory streams.

Unit

Classes

Description

Use TCustomMemoryStream as a base class when defining a stream object that can transfer data that is stored in memory. Memory streams are useful for providing file-like access to data that is stored in a less accessible medium. Data can be moved to an internal memory buffer when the memory stream is created. After manipulating the data in a memory stream, the data can be written out to its actual storage medium when the memory stream is destroyed.

Do not instantiate an instance of TCustomMemoryStream. It is an abstract class that implements behavior common to all memory streams. To work with an instance of a memory stream, use one of the descendants of TCustomMemoryStream, such as TMemoryStream or TResourceStream.

1. { TCustomMemoryStream abstract class }
3.   TCustomMemoryStream = class(TStream)
4.   private
5.     FMemory: Pointer;
6.     FSize, FPosition: Longint;   //大小，当前位置
7.   protected
8.     procedure SetPointer(Ptr: Pointer; Size: Longint);
9.   public
10.     function Read(var Buffer; Count: Longint): Longint; override;
11.     function Seek(Offset: Longint; Origin: Word): Longint; override;
12.     procedure SaveToStream(Stream: TStream);
13.     procedure SaveToFile(const FileName: string);
14.     property Memory: Pointer read FMemory;
15.   end;
17. { TCustomMemoryStream }
19. procedure TCustomMemoryStream.SetPointer(Ptr: Pointer; Size: Longint);
20. begin
21.   FMemory := Ptr;
22.   FSize := Size;
23. end;
25. function TCustomMemoryStream.Read(var Buffer; Count: Longint): Longint;
26. begin
27.   if (FPosition >= 0) and (Count >= 0) then
28.   begin
29.     Result := FSize - FPosition;
30.     if Result > 0 then
31.     begin
32.       if Result > Count then Result := Count;
33.       Move(Pointer(Longint(FMemory) + FPosition)^, Buffer, Result);    //复制内存
34.       Inc(FPosition, Result);
35.       Exit;
36.     end;
37.   end;
38.   Result := 0;
39. end;
41. function TCustomMemoryStream.Seek(Offset: Longint; Origin: Word): Longint;
42. begin
43.   case Origin of
44.     soFromBeginning: FPosition := Offset;
45.     soFromCurrent: Inc(FPosition, Offset);
46.     soFromEnd: FPosition := FSize + Offset;
47.   end;
48.   Result := FPosition;
49. end;
51. procedure TCustomMemoryStream.SaveToStream(Stream: TStream);
52. begin
53.   if FSize <> 0 then Stream.WriteBuffer(FMemory^, FSize);
54. end;
56. procedure TCustomMemoryStream.SaveToFile(const FileName: string);
57. var
58.   Stream: TStream;
59. begin
60.   Stream := TFileStream.Create(FileName, fmCreate);
61.   try
62.     SaveToStream(Stream);
63.   finally
64.     Stream.Free;
65.   end;
66. end;